configure.cmd

   1 @echo off
   2
   3 REM This is needed so as to avoid static expansion of environment variables
   4 REM inside if (...) conditionals.
   5 REM See http://stackoverflow.com/questions/305605/weird-scope-issue-in-bat-file
   6 REM for more explanation.
   7 REM Precisely needed for configuring Visual Studio Environment.
   8 setlocal enabledelayedexpansion
   9
  10 REM Does the user need help?
  11 if /I "%1" == "help" goto help
  12 if /I "%1" == "/?" (
  13 :help
  14     echo Help for configure script
  15     echo Syntax: path\to\source\configure.cmd [script-options] [Cmake-options]
  16     echo Available script-options: Codeblocks, Eclipse, Makefiles, clang, VSSolution, RTC
  17     echo Cmake-options: -DVARIABLE:TYPE=VALUE
  18     endlocal
  19     exit /b
  20 )
  21
  22 REM Special case %1 = arm_hosttools %2 = vcvarsall.bat %3 = %CMAKE_GENERATOR%
  23 if /I "%1" == "arm_hosttools" (
  24     echo Configuring x86 host tools for ARM cross build
  25
  26     REM This launches %VSINSTALLDIR%VS\vcvarsall.bat
  27     call %2 x86
  28
  29     REM Configure host tools for x86.
  30     cmake -G %3 -DARCH:STRING=i386 %~dp0
  31     exit
  32 )
  33
  34 REM Get the source root directory
  35 set REACTOS_SOURCE_DIR=%~dp0
  36
  37 REM Set default generator
  38 set CMAKE_GENERATOR="Ninja"
  39 set CMAKE_GENERATOR_HOST=!CMAKE_GENERATOR!
  40
  41 REM Detect presence of cmake
  42 cmd /c cmake --version 2>&1 | find "cmake version" > NUL || goto cmake_notfound
  43
  44 REM Detect build environment (MinGW, VS, WDK, ...)
  45 if defined ROS_ARCH (
  46     echo Detected RosBE for %ROS_ARCH%
  47     set BUILD_ENVIRONMENT=MinGW
  48     set ARCH=%ROS_ARCH%
  49     set MINGW_TOOCHAIN_FILE=toolchain-gcc.cmake
  50
  51 ) else if defined VCINSTALLDIR (
  52     REM VS command prompt does not put this in environment vars
  53     cl 2>&1 | find "x86" > NUL && set ARCH=i386
  54     cl 2>&1 | find "x64" > NUL && set ARCH=amd64
  55     cl 2>&1 | find "ARM" > NUL && set ARCH=arm
  56     cl 2>&1 | find "15.00." > NUL && set VS_VERSION=9
  57     cl 2>&1 | find "16.00." > NUL && set VS_VERSION=10
  58     cl 2>&1 | find "17.00." > NUL && set VS_VERSION=11
  59     cl 2>&1 | find "18.00." > NUL && set VS_VERSION=12
  60     cl 2>&1 | find "19.00." > NUL && set VS_VERSION=14
  61     cl 2>&1 | find "19.10." > NUL && set VS_VERSION=15
  62     cl 2>&1 | find "19.11." > NUL && set VS_VERSION=15
  63     if not defined VS_VERSION (
  64         echo Error: Visual Studio version too old or version detection failed.
  65         endlocal
  66         exit /b
  67     )
  68     set BUILD_ENVIRONMENT=VS
  69     set VS_SOLUTION=0
  70     set VS_RUNTIME_CHECKS=0
  71     echo Detected Visual Studio Environment !BUILD_ENVIRONMENT!!VS_VERSION!-!ARCH!
  72 ) else (
  73     echo Error: Unable to detect build environment. Configure script failure.
  74     endlocal
  75     exit /b
  76 )
  77
  78 REM Checkpoint
  79 if not defined ARCH (
  80     echo Unknown build architecture
  81     endlocal
  82     exit /b
  83 )
  84
  85 set NEW_STYLE_BUILD=1
  86
  87 REM Parse command line parameters
  88 :repeat
  89     if /I "%1%" == "-DNEW_STYLE_BUILD" (
  90         set NEW_STYLE_BUILD=%2
  91     ) else if "%BUILD_ENVIRONMENT%" == "MinGW" (
  92         if /I "%1" == "Codeblocks" (
  93             set CMAKE_GENERATOR="CodeBlocks - MinGW Makefiles"
  94         ) else if /I "%1" == "Eclipse" (
  95             set CMAKE_GENERATOR="Eclipse CDT4 - MinGW Makefiles"
  96         ) else if /I "%1" == "Makefiles" (
  97             set CMAKE_GENERATOR="MinGW Makefiles"
  98         ) else if /I "%1" == "clang" (
  99             set MINGW_TOOCHAIN_FILE=toolchain-clang.cmake
 100         ) else (
 101             goto continue
 102         )
 103     ) else (
 104         if /I "%1" == "CodeBlocks" (
 105             set CMAKE_GENERATOR="CodeBlocks - NMake Makefiles"
 106         ) else if /I "%1" == "Eclipse" (
 107             set CMAKE_GENERATOR="Eclipse CDT4 - NMake Makefiles"
 108         ) else if /I "%1" == "Makefiles" (
 109             set CMAKE_GENERATOR="NMake Makefiles"
 110         ) else if /I "%1" == "VSSolution" (
 111             set VS_SOLUTION=1
 112             REM explicitly set VS version for project generator
 113             if /I "%2" == "-VS_VER" (
 114                 set VS_VERSION=%3
 115                 echo Visual Studio Environment set to !BUILD_ENVIRONMENT!!VS_VERSION!-!ARCH!
 116             )
 117             if "!VS_VERSION!" == "9" (
 118                 if "!ARCH!" == "amd64" (
 119                     set CMAKE_GENERATOR="Visual Studio 9 2008 Win64"
 120                 ) else (
 121                     set CMAKE_GENERATOR="Visual Studio 9 2008"
 122                 )
 123             ) else if "!VS_VERSION!" == "10" (
 124                 if "!ARCH!" == "amd64" (
 125                     set CMAKE_GENERATOR="Visual Studio 10 Win64"
 126                 ) else (
 127                     set CMAKE_GENERATOR="Visual Studio 10"
 128                 )
 129             ) else if "!VS_VERSION!" == "11" (
 130                 if "!ARCH!" == "amd64" (
 131                     set CMAKE_GENERATOR="Visual Studio 11 Win64"
 132                 ) else if "!ARCH!" == "arm" (
 133                     set CMAKE_GENERATOR="Visual Studio 11 ARM"
 134                     set CMAKE_GENERATOR_HOST="Visual Studio 11"
 135                 ) else (
 136                     set CMAKE_GENERATOR="Visual Studio 11"
 137                 )
 138             ) else if "!VS_VERSION!" == "12" (
 139                 if "!ARCH!" == "amd64" (
 140                     set CMAKE_GENERATOR="Visual Studio 12 Win64"
 141                 ) else if "!ARCH!" == "arm" (
 142                     set CMAKE_GENERATOR="Visual Studio 12 ARM"
 143                     set CMAKE_GENERATOR_HOST="Visual Studio 12"
 144                 ) else (
 145                     set CMAKE_GENERATOR="Visual Studio 12"
 146                 )
 147             ) else if "!VS_VERSION!" == "14" (
 148                 if "!ARCH!" == "amd64" (
 149                     set CMAKE_GENERATOR="Visual Studio 14 Win64"
 150                 ) else if "!ARCH!" == "arm" (
 151                     set CMAKE_GENERATOR="Visual Studio 14 ARM"
 152                     set CMAKE_GENERATOR_HOST="Visual Studio 14"
 153                 ) else (
 154                     set CMAKE_GENERATOR="Visual Studio 14"
 155                 )
 156             ) else if "!VS_VERSION!" == "15" (
 157                 if "!ARCH!" == "amd64" (
 158                     set CMAKE_GENERATOR="Visual Studio 15 Win64"
 159                 ) else if "!ARCH!" == "arm" (
 160                     set CMAKE_GENERATOR="Visual Studio 15 ARM"
 161                     set CMAKE_GENERATOR_HOST="Visual Studio 15"
 162                 ) else (
 163                     set CMAKE_GENERATOR="Visual Studio 15"
 164                 )
 165             )
 166         ) else if /I "%1" == "RTC" (
 167             echo Runtime checks enabled
 168             set VS_RUNTIME_CHECKS=1
 169         ) else (
 170             goto continue
 171         )
 172     )
 173
 174     REM Go to next parameter
 175     SHIFT
 176     goto repeat
 177 :continue
 178
 179 REM Inform the user about the default build
 180 if "!CMAKE_GENERATOR!" == "Ninja" (
 181     echo This script defaults to Ninja. Type "configure help" for alternative options.
 182 )
 183
 184 REM Create directories
 185 set REACTOS_OUTPUT_PATH=output-%BUILD_ENVIRONMENT%-%ARCH%
 186 if "%REACTOS_SOURCE_DIR%" == "%CD%\" (
 187     echo Creating directories in %REACTOS_OUTPUT_PATH%
 188
 189     if not exist %REACTOS_OUTPUT_PATH% (
 190         mkdir %REACTOS_OUTPUT_PATH%
 191     )
 192     cd %REACTOS_OUTPUT_PATH%
 193 )
 194
 195 if "%NEW_STYLE_BUILD%"=="0" (
 196
 197     if not exist host-tools (
 198         mkdir host-tools
 199     )
 200
 201     if not exist reactos (
 202         mkdir reactos
 203     )
 204
 205     echo Preparing host tools...
 206     cd host-tools
 207     if EXIST CMakeCache.txt (
 208         del CMakeCache.txt /q
 209     )
 210
 211     set REACTOS_BUILD_TOOLS_DIR=!CD!
 212
 213     REM Use x86 for ARM host tools
 214     if "%ARCH%" == "arm" (
 215         REM Launch new script instance for x86 host tools configuration
 216         start "Preparing host tools for ARM cross build..." /I /B /WAIT %~dp0configure.cmd arm_hosttools "%VSINSTALLDIR%VC\vcvarsall.bat" %CMAKE_GENERATOR_HOST%
 217     ) else (
 218         cmake -G %CMAKE_GENERATOR% -DARCH:STRING=%ARCH% "%REACTOS_SOURCE_DIR%"
 219     )
 220
 221     cd..
 222
 223 )
 224
 225 echo Preparing reactos...
 226
 227 if "%NEW_STYLE_BUILD%"=="0" (
 228     cd reactos
 229 )
 230
 231 if EXIST CMakeCache.txt (
 232     del CMakeCache.txt /q
 233     del host-tools\CMakeCache.txt /q
 234 )
 235
 236 if "%NEW_STYLE_BUILD%"=="0" (
 237     set BUILD_TOOLS_FLAG=-DREACTOS_BUILD_TOOLS_DIR:PATH="%REACTOS_BUILD_TOOLS_DIR%"
 238 )
 239
 240 if "%BUILD_ENVIRONMENT%" == "MinGW" (
 241     cmake -G %CMAKE_GENERATOR% -DENABLE_CCACHE:BOOL=0 -DCMAKE_TOOLCHAIN_FILE:FILEPATH=%MINGW_TOOCHAIN_FILE% -DARCH:STRING=%ARCH% %BUILD_TOOLS_FLAG% %* "%REACTOS_SOURCE_DIR%"
 242 ) else (
 243     cmake -G %CMAKE_GENERATOR% -DCMAKE_TOOLCHAIN_FILE:FILEPATH=toolchain-msvc.cmake -DARCH:STRING=%ARCH% %BUILD_TOOLS_FLAG% -DRUNTIME_CHECKS:BOOL=%VS_RUNTIME_CHECKS% %* "%REACTOS_SOURCE_DIR%"
 244 )
 245
 246 if "%NEW_STYLE_BUILD%"=="0" (
 247     cd..
 248 )
 249
 250 echo Configure script complete^^! Execute appropriate build commands (ex: ninja, make, nmake, etc...).
 251 endlocal
 252 exit /b
 253
 254 :cmake_notfound
 255 echo Unable to find cmake, if it is installed, check your PATH variable.
 256 endlocal
 257 exit /b