reactos/tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "widl.h"
  35 #include "utils.h"
  36 #include "parser.h"
  37 #include "header.h"
  38 #include "typelib.h"
  39
  40 #if defined(YYBYACC)
  41         /* Berkeley yacc (byacc) doesn't seem to know about these */
  42         /* Some *BSD supplied versions do define these though */
  43 # ifndef YYEMPTY
  44 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  45 # endif
  46 # ifndef YYLEX
  47 #  define YYLEX         yylex()
  48 # endif
  49
  50 #elif defined(YYBISON)
  51         /* Bison was used for original development */
  52         /* #define YYEMPTY -2 */
  53         /* #define YYLEX   yylex() */
  54
  55 #else
  56         /* No yacc we know yet */
  57 # if !defined(YYEMPTY) || !defined(YYLEX)
  58 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  59 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  60 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  61   /* #else we just take a chance that it works... */
  62 # endif
  63 #endif
  64
  65 static attr_t *make_attr(enum attr_type type);
  66 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  67 static attr_t *make_attrp(enum attr_type type, void *val);
  68 static expr_t *make_expr(enum expr_type type);
  69 static expr_t *make_exprl(enum expr_type type, long val);
  70 static expr_t *make_exprs(enum expr_type type, char *val);
  71 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  72 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  73 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  74 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  75 static type_t *make_type(unsigned char type, type_t *ref);
  76 static typeref_t *make_tref(char *name, type_t *ref);
  77 static typeref_t *uniq_tref(typeref_t *ref);
  78 static type_t *type_ref(typeref_t *ref);
  79 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  80 static ifref_t *make_ifref(type_t *iface);
  81 static var_t *make_var(char *name);
  82 static func_t *make_func(var_t *def, var_t *args);
  83 static class_t *make_class(char *name);
  84
  85 static type_t *reg_type(type_t *type, char *name, int t);
  86 static type_t *reg_types(type_t *type, var_t *names, int t);
  87 static type_t *find_type(char *name, int t);
  88 static type_t *find_type2(char *name, int t);
  89 static type_t *get_type(unsigned char type, char *name, int t);
  90 static type_t *get_typev(unsigned char type, var_t *name, int t);
  91 static int get_struct_type(var_t *fields);
  92
  93 static var_t *reg_const(var_t *var);
  94 static var_t *find_const(char *name, int f);
  95
  96 #define tsENUM   1
  97 #define tsSTRUCT 2
  98 #define tsUNION  3
  99
 100 static type_t std_bool = { "boolean" };
 101 static type_t std_int = { "int" };
 102 static type_t std_int64 = { "__int64" };
 103 static type_t std_uhyper = { "MIDL_uhyper" };
 104
 105 %}
 106 %union {
 107         attr_t *attr;
 108         expr_t *expr;
 109         type_t *type;
 110         typeref_t *tref;
 111         var_t *var;
 112         func_t *func;
 113         ifref_t *ifref;
 114         class_t *clas;
 115         char *str;
 116         UUID *uuid;
 117         unsigned int num;
 118 }
 119
 120 %token <str> aIDENTIFIER
 121 %token <str> aKNOWNTYPE
 122 %token <num> aNUM aHEXNUM
 123 %token <str> aSTRING
 124 %token <uuid> aUUID
 125 %token aEOF
 126 %token SHL SHR
 127 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 128 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 129 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 130 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 131 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 132 %token tDEFAULT
 133 %token tDEFAULTVALUE
 134 %token tDISPINTERFACE
 135 %token tDLLNAME tDOUBLE tDUAL
 136 %token tENDPOINT
 137 %token tENTRY tENUM tERRORSTATUST
 138 %token tEXPLICITHANDLE tEXTERN
 139 %token tFLOAT
 140 %token tHANDLE
 141 %token tHANDLET
 142 %token tHELPCONTEXT tHELPFILE
 143 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 144 %token tHIDDEN
 145 %token tHYPER tID tIDEMPOTENT
 146 %token tIIDIS
 147 %token tIMPLICITHANDLE
 148 %token tIMPORT tIMPORTLIB
 149 %token tIN tINCLUDE tINLINE
 150 %token tINPUTSYNC
 151 %token tINT tINT64
 152 %token tINTERFACE
 153 %token tLENGTHIS tLIBRARY
 154 %token tLOCAL
 155 %token tLONG
 156 %token tMETHODS
 157 %token tMODULE
 158 %token tNONCREATABLE
 159 %token tOBJECT tODL tOLEAUTOMATION
 160 %token tOPTIONAL
 161 %token tOUT
 162 %token tPOINTERDEFAULT
 163 %token tPROPERTIES
 164 %token tPROPGET tPROPPUT tPROPPUTREF
 165 %token tPTR
 166 %token tPUBLIC
 167 %token tREADONLY tREF
 168 %token tRESTRICTED
 169 %token tRETVAL
 170 %token tSHORT
 171 %token tSIGNED
 172 %token tSIZEIS tSIZEOF
 173 %token tSMALL
 174 %token tSOURCE
 175 %token tSTDCALL
 176 %token tSTRING tSTRUCT
 177 %token tSWITCH tSWITCHIS tSWITCHTYPE
 178 %token tTRANSMITAS
 179 %token tTYPEDEF
 180 %token tUNION
 181 %token tUNIQUE
 182 %token tUNSIGNED
 183 %token tUUID
 184 %token tV1ENUM
 185 %token tVARARG
 186 %token tVERSION
 187 %token tVOID
 188 %token tWCHAR tWIREMARSHAL
 189
 190 /* used in attr_t */
 191 %token tPOINTERTYPE
 192
 193 %type <attr> m_attributes attributes attrib_list attribute
 194 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 195 %type <expr> array array_list
 196 %type <type> inherit interface interfacehdr interfacedef interfacedec
 197 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 198 %type <type> module modulehdr moduledef
 199 %type <type> base_type int_std
 200 %type <type> enumdef structdef typedef uniondef
 201 %type <ifref> gbl_statements coclass_ints coclass_int
 202 %type <tref> type
 203 %type <var> m_args no_args args arg
 204 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 205 %type <var> m_ident t_ident ident p_ident pident pident_list
 206 %type <var> dispint_props
 207 %type <func> funcdef int_statements
 208 %type <func> dispint_meths
 209 %type <clas> coclass coclasshdr coclassdef
 210 %type <num> pointer_type version
 211 %type <str> libraryhdr
 212
 213 %left ','
 214 %right COND
 215 %left '|'
 216 %left '&'
 217 %left '-' '+'
 218 %left '*' '/'
 219 %left SHL SHR
 220 %right '~'
 221 %right CAST
 222 %right PPTR
 223 %right NEG
 224
 225 %%
 226
 227 input:    gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 228         ;
 229
 230 gbl_statements:                                 { $$ = NULL; }
 231         | gbl_statements interfacedec           { $$ = $1; }
 232         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 233         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 234         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 235         | gbl_statements librarydef             { $$ = $1; }
 236         | gbl_statements statement              { $$ = $1; }
 237         ;
 238
 239 imp_statements:                                 {}
 240         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 241         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 242         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 243         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 244         | imp_statements statement              {}
 245         ;
 246
 247 int_statements:                                 { $$ = NULL; }
 248         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 249         | int_statements statement              { $$ = $1; }
 250         ;
 251
 252 statement: ';'                                  {}
 253         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 254         | cppquote                              {}
 255         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 256         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 257         | import                                {}
 258         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 259         | typedef ';'                           {}
 260         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 261         ;
 262
 263 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 264         ;
 265 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 266                                                   if (!do_import($2)) yychar = aEOF; }
 267         ;
 268 import:   import_start imp_statements aEOF      {}
 269         ;
 270
 271 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 272         ;
 273 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 274         ;
 275 librarydef: library_start imp_statements '}'    { end_typelib(); }
 276         ;
 277
 278 m_args:                                         { $$ = NULL; }
 279         | args
 280         ;
 281
 282 no_args:  tVOID                                 { $$ = NULL; }
 283         ;
 284
 285 args:     arg
 286         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 287         | no_args
 288         ;
 289
 290 /* split into two rules to get bison to resolve a tVOID conflict */
 291 arg:      attributes type pident array          { $$ = $3;
 292                                                   set_type($$, $2, $4);
 293                                                   $$->attrs = $1;
 294                                                 }
 295         | type pident array                     { $$ = $2;
 296                                                   set_type($$, $1, $3);
 297                                                 }
 298         | attributes type pident '(' m_args ')' { $$ = $3;
 299                                                   $$->ptr_level--;
 300                                                   set_type($$, $2, NULL);
 301                                                   $$->attrs = $1;
 302                                                   $$->args = $5;
 303                                                 }
 304         | type pident '(' m_args ')'            { $$ = $2;
 305                                                   $$->ptr_level--;
 306                                                   set_type($$, $1, NULL);
 307                                                   $$->args = $4;
 308                                                 }
 309         ;
 310
 311 array:                                          { $$ = NULL; }
 312         | '[' array_list ']'                    { $$ = $2; }
 313         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 314         ;
 315
 316 array_list: m_expr /* size of first dimension is optional */
 317         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 318         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 319         ;
 320
 321 m_attributes:                                   { $$ = NULL; }
 322         | attributes
 323         ;
 324
 325 attributes:
 326           '[' attrib_list ']'                   { $$ = $2; }
 327         ;
 328
 329 attrib_list: attribute
 330         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 331         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 332         ;
 333
 334 attribute:
 335           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 336         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 337         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 338         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 339         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 340         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 341         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 342         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 343         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 344         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 345         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 346         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 347         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 348         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 349         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 350         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 351         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 352         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 353         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 354         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 355         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 356         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 357         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 358         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 359         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 360         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 361         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 362         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 363         | tIN                                   { $$ = make_attr(ATTR_IN); }
 364         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 365         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 366         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 367         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 368         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 369         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 370         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 371         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 372         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 373         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 374         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 375         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 376         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 377         | tPTR                                  { $$ = make_attr(ATTR_PTR); }
 378         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 379         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 380         | tREF                                  { $$ = make_attr(ATTR_REF); }
 381         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 382         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 383         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 384         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 385         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 386         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 387         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 388         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 389         | tUNIQUE                               { $$ = make_attr(ATTR_UNIQUE); }
 390         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 391         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 392         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 393         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 394         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 395         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 396         ;
 397
 398 callconv:
 399         | tSTDCALL
 400         ;
 401
 402 cases:                                          { $$ = NULL; }
 403         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 404                                                   else { $$ = $1; }
 405                                                 }
 406         ;
 407
 408 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 409                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 410                                                   LINK(a, $$->attrs); $$->attrs = a;
 411                                                 }
 412         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 413                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 414                                                   LINK(a, $$->attrs); $$->attrs = a;
 415                                                 }
 416         ;
 417
 418 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 419                                                   set_type($$, $2, NULL);
 420                                                   $$->eval = $5;
 421                                                   $$->lval = $5->cval;
 422                                                 }
 423         ;
 424
 425 enums:                                          { $$ = NULL; }
 426         | enum_list ','                         { $$ = $1; }
 427         | enum_list
 428         ;
 429
 430 enum_list: enum
 431         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 432                                                   if ($1 && !$3->eval)
 433                                                     $3->lval = $1->lval + 1;
 434                                                 }
 435         ;
 436
 437 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 438                                                   $$->eval = $3;
 439                                                   $$->lval = $3->cval;
 440                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 441                                                 }
 442         | ident                                 { $$ = reg_const($1);
 443                                                   $$->lval = 0; /* default for first enum entry */
 444                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 445                                                 }
 446         ;
 447
 448 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 449                                                   $$->fields = $4;
 450                                                   $$->defined = TRUE;
 451                                                   if(in_typelib)
 452                                                       add_enum($$);
 453                                                 }
 454         ;
 455
 456 m_exprs:  m_expr
 457         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 458         ;
 459
 460 /*
 461 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 462         | expr_list
 463         ;
 464
 465 expr_list: expr
 466         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 467         ;
 468 */
 469
 470 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 471         | expr
 472         ;
 473
 474 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 475         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 476         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 477         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 478         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 479         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 480         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 481         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 482         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 483         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 484         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 485         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 486         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 487         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 488         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 489         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 490         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 491         | '(' expr ')'                          { $$ = $2; }
 492         ;
 493
 494 expr_list_const: expr_const
 495         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 496         ;
 497
 498 expr_const: expr                                { $$ = $1;
 499                                                   if (!$$->is_const)
 500                                                       yyerror("expression is not constant\n");
 501                                                 }
 502         ;
 503
 504 externdef: tEXTERN tCONST type ident            { $$ = $4;
 505                                                   set_type($$, $3, NULL);
 506                                                 }
 507         ;
 508
 509 fields:                                         { $$ = NULL; }
 510         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 511                                                   else { $$ = $1; }
 512                                                 }
 513         ;
 514
 515 field:    s_field ';'                           { $$ = $1; }
 516         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 517         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 518         | ';'                                   { $$ = NULL; }
 519         ;
 520
 521 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 522         ;
 523
 524 funcdef:
 525           m_attributes type callconv pident
 526           '(' m_args ')'                        { set_type($4, $2, NULL);
 527                                                   $4->attrs = $1;
 528                                                   $$ = make_func($4, $6);
 529                                                   if (is_attr($4->attrs, ATTR_IN)) {
 530                                                     yyerror("Inapplicable attribute");
 531                                                   }
 532                                                 }
 533         ;
 534
 535 m_ident:                                        { $$ = NULL; }
 536         | ident
 537         ;
 538
 539 t_ident:                                        { $$ = NULL; }
 540         | aIDENTIFIER                           { $$ = make_var($1); }
 541         | aKNOWNTYPE                            { $$ = make_var($1); }
 542         ;
 543
 544 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 545 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 546         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 547         | tID                                   { $$ = make_var($<str>1); }
 548         | tRETVAL                               { $$ = make_var($<str>1); }
 549         | tVERSION                              { $$ = make_var($<str>1); }
 550         ;
 551
 552 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 553         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 554         | int_std
 555         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 556         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 557                                                   switch ($$->type) {
 558                                                   case RPC_FC_CHAR: break;
 559                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 560                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 561                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 562                                                   case RPC_FC_HYPER:
 563                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 564                                                     break;
 565                                                   default: break;
 566                                                   }
 567                                                 }
 568         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int);
 569                                                   $$->sign = -1; }
 570         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 571         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 572         | tBOOLEAN                              { $$ = make_type(RPC_FC_SMALL, &std_bool); }
 573         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 574         | tHANDLET                              { $$ = make_type(RPC_FC_IGNORE, NULL); }
 575         ;
 576
 577 m_int:
 578         | tINT
 579         ;
 580
 581 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 582         | tSMALL m_int                          { $$ = make_type(RPC_FC_SMALL, NULL); }
 583         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 584         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 585         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 586         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 587         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 588         ;
 589
 590 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 591         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 592         ;
 593
 594 coclasshdr: attributes coclass                  { $$ = $2;
 595                                                   $$->attrs = $1;
 596                                                   if (!parse_only && do_header)
 597                                                     write_coclass($$);
 598                                                 }
 599         ;
 600
 601 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 602                                                   $$->ifaces = $3;
 603                                                 }
 604         ;
 605
 606 coclass_ints:                                   { $$ = NULL; }
 607         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 608         ;
 609
 610 coclass_int:
 611           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 612         ;
 613
 614 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 615         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 616         ;
 617
 618 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 619                                                   if ($$->defined) yyerror("multiple definition error\n");
 620                                                   $$->attrs = $1;
 621                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 622                                                   LINK($$->attrs, $1);
 623                                                   $$->ref = find_type("IDispatch", 0);
 624                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 625                                                   $$->defined = TRUE;
 626                                                   if (!parse_only && do_header) write_forward($$);
 627                                                 }
 628         ;
 629
 630 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 631         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 632         ;
 633
 634 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 635         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 636         ;
 637
 638 dispinterfacedef: dispinterfacehdr '{'
 639           dispint_props
 640           dispint_meths
 641           '}'                                   { $$ = $1;
 642                                                   $$->fields = $3;
 643                                                   $$->funcs = $4;
 644                                                   if (!parse_only && do_header) write_dispinterface($$);
 645                                                 }
 646 /* FIXME: not sure how to handle this yet
 647         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 648                                                   if (!parse_only && do_header) write_interface($$);
 649                                                 }
 650 */
 651         ;
 652
 653 inherit:                                        { $$ = NULL; }
 654         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 655         ;
 656
 657 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 658         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 659         ;
 660
 661 interfacehdr: attributes interface              { $$ = $2;
 662                                                   if ($$->defined) yyerror("multiple definition error\n");
 663                                                   $$->attrs = $1;
 664                                                   $$->defined = TRUE;
 665                                                   if (!parse_only && do_header) write_forward($$);
 666                                                 }
 667         ;
 668
 669 interfacedef: interfacehdr inherit
 670           '{' int_statements '}'                { $$ = $1;
 671                                                   $$->ref = $2;
 672                                                   $$->funcs = $4;
 673                                                   if (!parse_only && do_header) write_interface($$);
 674                                                 }
 675 /* MIDL is able to import the definition of a base class from inside the
 676  * definition of a derived class, I'll try to support it with this rule */
 677         | interfacehdr ':' aIDENTIFIER
 678           '{' import int_statements '}'         { $$ = $1;
 679                                                   $$->ref = find_type2($3, 0);
 680                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 681                                                   $$->funcs = $6;
 682                                                   if (!parse_only && do_header) write_interface($$);
 683                                                 }
 684         | dispinterfacedef                      { $$ = $1; }
 685         ;
 686
 687 interfacedec:
 688           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 689         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 690         ;
 691
 692 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 693         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 694         ;
 695
 696 modulehdr: attributes module                    { $$ = $2;
 697                                                   $$->attrs = $1;
 698                                                 }
 699         ;
 700
 701 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 702                                                   $$->funcs = $3;
 703                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 704                                                 }
 705         ;
 706
 707 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 708         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 709         ;
 710
 711 pident:   ident
 712         | p_ident
 713         | '(' pident ')'                        { $$ = $2; }
 714         ;
 715
 716 pident_list:
 717           pident
 718         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 719         ;
 720
 721 pointer_type:
 722           tREF                                  { $$ = RPC_FC_RP; }
 723         | tUNIQUE                               { $$ = RPC_FC_UP; }
 724         ;
 725
 726 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 727                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 728                                                   $$->type = get_struct_type( $4 );
 729                                                   $$->fields = $4;
 730                                                   $$->defined = TRUE;
 731                                                   if(in_typelib)
 732                                                     add_struct($$);
 733                                                 }
 734         ;
 735
 736 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 737         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 738         | base_type                             { $$ = make_tref(NULL, $1); }
 739         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 740         | enumdef                               { $$ = make_tref(NULL, $1); }
 741         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 742         | structdef                             { $$ = make_tref(NULL, $1); }
 743         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 744         | uniondef                              { $$ = make_tref(NULL, $1); }
 745         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 746         ;
 747
 748 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 749                                                   $4->tname = tref->name;
 750                                                   tref->name = NULL;
 751                                                   $$ = type_ref(tref);
 752                                                   $$->attrs = $2;
 753                                                   if (!parse_only && do_header)
 754                                                     write_typedef($$, $4);
 755                                                   if (in_typelib && $$->attrs)
 756                                                     add_typedef($$, $4);
 757                                                   reg_types($$, $4, 0);
 758                                                 }
 759         ;
 760
 761 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 762                                                   $$->fields = $4;
 763                                                   $$->defined = TRUE;
 764                                                 }
 765         | tUNION t_ident
 766           tSWITCH '(' s_field ')'
 767           m_ident '{' cases '}'                 { var_t *u = $7;
 768                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 769                                                   if (!u) u = make_var("tagged_union");
 770                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 771                                                   u->type->fields = $9;
 772                                                   u->type->defined = TRUE;
 773                                                   LINK(u, $5); $$->fields = u;
 774                                                   $$->defined = TRUE;
 775                                                 }
 776         ;
 777
 778 version:
 779           aNUM                                  { $$ = MAKELONG($1, 0); }
 780         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 781         ;
 782
 783 %%
 784
 785 static attr_t *make_attr(enum attr_type type)
 786 {
 787   attr_t *a = xmalloc(sizeof(attr_t));
 788   a->type = type;
 789   a->u.ival = 0;
 790   INIT_LINK(a);
 791   return a;
 792 }
 793
 794 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 795 {
 796   attr_t *a = xmalloc(sizeof(attr_t));
 797   a->type = type;
 798   a->u.ival = val;
 799   INIT_LINK(a);
 800   return a;
 801 }
 802
 803 static attr_t *make_attrp(enum attr_type type, void *val)
 804 {
 805   attr_t *a = xmalloc(sizeof(attr_t));
 806   a->type = type;
 807   a->u.pval = val;
 808   INIT_LINK(a);
 809   return a;
 810 }
 811
 812 static expr_t *make_expr(enum expr_type type)
 813 {
 814   expr_t *e = xmalloc(sizeof(expr_t));
 815   e->type = type;
 816   e->ref = NULL;
 817   e->u.lval = 0;
 818   e->is_const = FALSE;
 819   INIT_LINK(e);
 820   return e;
 821 }
 822
 823 static expr_t *make_exprl(enum expr_type type, long val)
 824 {
 825   expr_t *e = xmalloc(sizeof(expr_t));
 826   e->type = type;
 827   e->ref = NULL;
 828   e->u.lval = val;
 829   e->is_const = FALSE;
 830   INIT_LINK(e);
 831   /* check for numeric constant */
 832   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 833     e->is_const = TRUE;
 834     e->cval = val;
 835   }
 836   return e;
 837 }
 838
 839 static expr_t *make_exprs(enum expr_type type, char *val)
 840 {
 841   expr_t *e;
 842   e = xmalloc(sizeof(expr_t));
 843   e->type = type;
 844   e->ref = NULL;
 845   e->u.sval = val;
 846   e->is_const = FALSE;
 847   INIT_LINK(e);
 848   /* check for predefined constants */
 849   if (type == EXPR_IDENTIFIER) {
 850     var_t *c = find_const(val, 0);
 851     if (c) {
 852       e->u.sval = c->name;
 853       free(val);
 854       e->is_const = TRUE;
 855       e->cval = c->lval;
 856     }
 857   }
 858   return e;
 859 }
 860
 861 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 862 {
 863   expr_t *e;
 864   e = xmalloc(sizeof(expr_t));
 865   e->type = type;
 866   e->ref = expr;
 867   e->u.tref = tref;
 868   e->is_const = FALSE;
 869   INIT_LINK(e);
 870   /* check for cast of constant expression */
 871   if (type == EXPR_CAST && expr->is_const) {
 872     e->is_const = TRUE;
 873     e->cval = expr->cval;
 874   }
 875   return e;
 876 }
 877
 878 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 879 {
 880   expr_t *e;
 881   e = xmalloc(sizeof(expr_t));
 882   e->type = type;
 883   e->ref = expr;
 884   e->u.lval = 0;
 885   e->is_const = FALSE;
 886   INIT_LINK(e);
 887   /* check for compile-time optimization */
 888   if (expr->is_const) {
 889     e->is_const = TRUE;
 890     switch (type) {
 891     case EXPR_NEG:
 892       e->cval = -expr->cval;
 893       break;
 894     case EXPR_NOT:
 895       e->cval = ~expr->cval;
 896       break;
 897     default:
 898       e->is_const = FALSE;
 899       break;
 900     }
 901   }
 902   return e;
 903 }
 904
 905 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 906 {
 907   expr_t *e;
 908   e = xmalloc(sizeof(expr_t));
 909   e->type = type;
 910   e->ref = expr1;
 911   e->u.ext = expr2;
 912   e->is_const = FALSE;
 913   INIT_LINK(e);
 914   /* check for compile-time optimization */
 915   if (expr1->is_const && expr2->is_const) {
 916     e->is_const = TRUE;
 917     switch (type) {
 918     case EXPR_ADD:
 919       e->cval = expr1->cval + expr2->cval;
 920       break;
 921     case EXPR_SUB:
 922       e->cval = expr1->cval - expr2->cval;
 923       break;
 924     case EXPR_MUL:
 925       e->cval = expr1->cval * expr2->cval;
 926       break;
 927     case EXPR_DIV:
 928       e->cval = expr1->cval / expr2->cval;
 929       break;
 930     case EXPR_OR:
 931       e->cval = expr1->cval | expr2->cval;
 932       break;
 933     case EXPR_AND:
 934       e->cval = expr1->cval & expr2->cval;
 935       break;
 936     case EXPR_SHL:
 937       e->cval = expr1->cval << expr2->cval;
 938       break;
 939     case EXPR_SHR:
 940       e->cval = expr1->cval >> expr2->cval;
 941       break;
 942     default:
 943       e->is_const = FALSE;
 944       break;
 945     }
 946   }
 947   return e;
 948 }
 949
 950 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 951 {
 952   expr_t *e;
 953   e = xmalloc(sizeof(expr_t));
 954   e->type = type;
 955   e->ref = expr1;
 956   e->u.ext = expr2;
 957   e->ext2 = expr3;
 958   e->is_const = FALSE;
 959   INIT_LINK(e);
 960   /* check for compile-time optimization */
 961   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 962     e->is_const = TRUE;
 963     switch (type) {
 964     case EXPR_COND:
 965       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 966       break;
 967     default:
 968       e->is_const = FALSE;
 969       break;
 970     }
 971   }
 972   return e;
 973 }
 974
 975 static type_t *make_type(unsigned char type, type_t *ref)
 976 {
 977   type_t *t = xmalloc(sizeof(type_t));
 978   t->name = NULL;
 979   t->type = type;
 980   t->ref = ref;
 981   t->rname = NULL;
 982   t->attrs = NULL;
 983   t->funcs = NULL;
 984   t->fields = NULL;
 985   t->ignore = parse_only;
 986   t->is_const = FALSE;
 987   t->sign = 0;
 988   t->defined = FALSE;
 989   t->written = FALSE;
 990   t->typelib_idx = -1;
 991   INIT_LINK(t);
 992   return t;
 993 }
 994
 995 static typeref_t *make_tref(char *name, type_t *ref)
 996 {
 997   typeref_t *t = xmalloc(sizeof(typeref_t));
 998   t->name = name;
 999   t->ref = ref;
1000   t->uniq = ref ? 0 : 1;
1001   return t;
1002 }
1003
1004 static typeref_t *uniq_tref(typeref_t *ref)
1005 {
1006   typeref_t *t = ref;
1007   type_t *tp;
1008   if (t->uniq) return t;
1009   tp = make_type(0, t->ref);
1010   tp->name = t->name;
1011   t->name = NULL;
1012   t->ref = tp;
1013   t->uniq = 1;
1014   return t;
1015 }
1016
1017 static type_t *type_ref(typeref_t *ref)
1018 {
1019   type_t *t = ref->ref;
1020   if (ref->name) free(ref->name);
1021   free(ref);
1022   return t;
1023 }
1024
1025 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1026 {
1027   v->type = ref->ref;
1028   v->tname = ref->name;
1029   ref->name = NULL;
1030   free(ref);
1031   v->array = arr;
1032 }
1033
1034 static ifref_t *make_ifref(type_t *iface)
1035 {
1036   ifref_t *l = xmalloc(sizeof(ifref_t));
1037   l->iface = iface;
1038   l->attrs = NULL;
1039   INIT_LINK(l);
1040   return l;
1041 }
1042
1043 static var_t *make_var(char *name)
1044 {
1045   var_t *v = xmalloc(sizeof(var_t));
1046   v->name = name;
1047   v->ptr_level = 0;
1048   v->type = NULL;
1049   v->tname = NULL;
1050   v->attrs = NULL;
1051   v->array = NULL;
1052   v->eval = NULL;
1053   v->lval = 0;
1054   INIT_LINK(v);
1055   return v;
1056 }
1057
1058 static func_t *make_func(var_t *def, var_t *args)
1059 {
1060   func_t *f = xmalloc(sizeof(func_t));
1061   f->def = def;
1062   f->args = args;
1063   f->ignore = parse_only;
1064   f->idx = -1;
1065   INIT_LINK(f);
1066   return f;
1067 }
1068
1069 static class_t *make_class(char *name)
1070 {
1071   class_t *c = xmalloc(sizeof(class_t));
1072   c->name = name;
1073   c->attrs = NULL;
1074   c->ifaces = NULL;
1075   INIT_LINK(c);
1076   return c;
1077 }
1078
1079 #define HASHMAX 64
1080
1081 static int hash_ident(const char *name)
1082 {
1083   const char *p = name;
1084   int sum = 0;
1085   /* a simple sum hash is probably good enough */
1086   while (*p) {
1087     sum += *p;
1088     p++;
1089   }
1090   return sum & (HASHMAX-1);
1091 }
1092
1093 /***** type repository *****/
1094
1095 struct rtype {
1096   char *name;
1097   type_t *type;
1098   int t;
1099   struct rtype *next;
1100 };
1101
1102 struct rtype *type_hash[HASHMAX];
1103
1104 static type_t *reg_type(type_t *type, char *name, int t)
1105 {
1106   struct rtype *nt;
1107   int hash;
1108   if (!name) {
1109     yyerror("registering named type without name\n");
1110     return type;
1111   }
1112   hash = hash_ident(name);
1113   nt = xmalloc(sizeof(struct rtype));
1114   nt->name = name;
1115   nt->type = type;
1116   nt->t = t;
1117   nt->next = type_hash[hash];
1118   type_hash[hash] = nt;
1119   type->name = name;
1120   return type;
1121 }
1122
1123 /* determine pointer type from attrs */
1124 static unsigned char get_pointer_type( type_t *type )
1125 {
1126   int t;
1127   if (is_attr( type->attrs, ATTR_STRING ))
1128   {
1129     type_t *t = type;
1130     while( t->type == 0 && t->ref )
1131       t = t->ref;
1132     switch( t->type )
1133     {
1134     case RPC_FC_CHAR:
1135       return RPC_FC_C_CSTRING;
1136     case RPC_FC_WCHAR:
1137       return RPC_FC_C_WSTRING;
1138     }
1139   }
1140   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1141   if (t) return t;
1142
1143   if(is_attr( type->attrs, ATTR_PTR ))
1144     return RPC_FC_FP;
1145
1146   if(is_attr( type->attrs, ATTR_UNIQUE ))
1147     return RPC_FC_UP;
1148
1149   return RPC_FC_RP;
1150 }
1151
1152 static type_t *reg_types(type_t *type, var_t *names, int t)
1153 {
1154   type_t *ptr = type;
1155   int ptrc = 0;
1156
1157   while (names) {
1158     var_t *next = NEXT_LINK(names);
1159     if (names->name) {
1160       type_t *cur = ptr;
1161       int cptr = names->ptr_level;
1162       if (cptr > ptrc) {
1163         while (cptr > ptrc) {
1164           int t = get_pointer_type( cur );
1165           cur = ptr = make_type(t, cur);
1166           ptrc++;
1167         }
1168       } else {
1169         while (cptr < ptrc) {
1170           cur = cur->ref;
1171           cptr++;
1172         }
1173       }
1174       reg_type(cur, names->name, t);
1175     }
1176     free(names);
1177     names = next;
1178   }
1179   return type;
1180 }
1181
1182 static type_t *find_type(char *name, int t)
1183 {
1184   struct rtype *cur = type_hash[hash_ident(name)];
1185   while (cur && (cur->t != t || strcmp(cur->name, name)))
1186     cur = cur->next;
1187   if (!cur) {
1188     yyerror("type %s not found\n", name);
1189     return NULL;
1190   }
1191   return cur->type;
1192 }
1193
1194 static type_t *find_type2(char *name, int t)
1195 {
1196   type_t *tp = find_type(name, t);
1197   free(name);
1198   return tp;
1199 }
1200
1201 int is_type(const char *name)
1202 {
1203   struct rtype *cur = type_hash[hash_ident(name)];
1204   while (cur && (cur->t || strcmp(cur->name, name)))
1205     cur = cur->next;
1206   if (cur) return TRUE;
1207   return FALSE;
1208 }
1209
1210 static type_t *get_type(unsigned char type, char *name, int t)
1211 {
1212   struct rtype *cur = NULL;
1213   type_t *tp;
1214   if (name) {
1215     cur = type_hash[hash_ident(name)];
1216     while (cur && (cur->t != t || strcmp(cur->name, name)))
1217       cur = cur->next;
1218   }
1219   if (cur) {
1220     free(name);
1221     return cur->type;
1222   }
1223   tp = make_type(type, NULL);
1224   tp->name = name;
1225   if (!name) return tp;
1226   return reg_type(tp, name, t);
1227 }
1228
1229 static type_t *get_typev(unsigned char type, var_t *name, int t)
1230 {
1231   char *sname = NULL;
1232   if (name) {
1233     sname = name->name;
1234     free(name);
1235   }
1236   return get_type(type, sname, t);
1237 }
1238
1239 static int get_struct_type(var_t *field)
1240 {
1241   int has_pointer = 0;
1242   int has_conformant_array = 0;
1243   int has_conformant_string = 0;
1244
1245   while (field)
1246   {
1247     type_t *t = field->type;
1248
1249     /* get the base type */
1250     while( (t->type == 0) && t->ref )
1251       t = t->ref;
1252
1253     switch (t->type)
1254     {
1255     /*
1256      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1257      *  Simple types don't effect the type of struct.
1258      *  A struct containing a simple struct is still a simple struct.
1259      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1260      */
1261     case 0: /* void pointer */
1262     case RPC_FC_BYTE:
1263     case RPC_FC_CHAR:
1264     case RPC_FC_SMALL:
1265     case RPC_FC_USMALL:
1266     case RPC_FC_WCHAR:
1267     case RPC_FC_SHORT:
1268     case RPC_FC_USHORT:
1269     case RPC_FC_LONG:
1270     case RPC_FC_ULONG:
1271     case RPC_FC_INT3264:
1272     case RPC_FC_UINT3264:
1273     case RPC_FC_HYPER:
1274     case RPC_FC_FLOAT:
1275     case RPC_FC_DOUBLE:
1276     case RPC_FC_STRUCT:
1277     case RPC_FC_ENUM16:
1278     case RPC_FC_ENUM32:
1279       break;
1280
1281     case RPC_FC_UP:
1282     case RPC_FC_FP:
1283       has_pointer = 1;
1284       break;
1285     case RPC_FC_CARRAY:
1286       has_conformant_array = 1;
1287       break;
1288     case RPC_FC_C_CSTRING:
1289     case RPC_FC_C_WSTRING:
1290       has_conformant_string = 1;
1291       break;
1292
1293     /*
1294      * Propagate member attributes
1295      *  a struct should be at least as complex as its member
1296      */
1297     case RPC_FC_CVSTRUCT:
1298       has_conformant_string = 1;
1299       has_pointer = 1;
1300       break;
1301
1302     case RPC_FC_CPSTRUCT:
1303       has_conformant_array = 1;
1304       has_pointer = 1;
1305       break;
1306
1307     case RPC_FC_CSTRUCT:
1308       has_conformant_array = 1;
1309       break;
1310
1311     case RPC_FC_PSTRUCT:
1312       has_pointer = 1;
1313       break;
1314
1315     default:
1316       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1317               field->name, t->type);
1318       /* fallthru - treat it as complex */
1319
1320     /* as soon as we see one of these these members, it's bogus... */
1321     case RPC_FC_IP:
1322     case RPC_FC_ENCAPSULATED_UNION:
1323     case RPC_FC_NON_ENCAPSULATED_UNION:
1324     case RPC_FC_TRANSMIT_AS:
1325     case RPC_FC_REPRESENT_AS:
1326     case RPC_FC_PAD:
1327     case RPC_FC_EMBEDDED_COMPLEX:
1328     case RPC_FC_BOGUS_STRUCT:
1329       return RPC_FC_BOGUS_STRUCT;
1330     }
1331     field = NEXT_LINK(field);
1332   }
1333
1334   if( has_conformant_string && has_pointer )
1335     return RPC_FC_CVSTRUCT;
1336   if( has_conformant_array && has_pointer )
1337     return RPC_FC_CPSTRUCT;
1338   if( has_conformant_array )
1339     return RPC_FC_CSTRUCT;
1340   if( has_pointer )
1341     return RPC_FC_PSTRUCT;
1342   return RPC_FC_STRUCT;
1343 }
1344
1345 /***** constant repository *****/
1346
1347 struct rconst {
1348   char *name;
1349   var_t *var;
1350   struct rconst *next;
1351 };
1352
1353 struct rconst *const_hash[HASHMAX];
1354
1355 static var_t *reg_const(var_t *var)
1356 {
1357   struct rconst *nc;
1358   int hash;
1359   if (!var->name) {
1360     yyerror("registering constant without name\n");
1361     return var;
1362   }
1363   hash = hash_ident(var->name);
1364   nc = xmalloc(sizeof(struct rconst));
1365   nc->name = var->name;
1366   nc->var = var;
1367   nc->next = const_hash[hash];
1368   const_hash[hash] = nc;
1369   return var;
1370 }
1371
1372 static var_t *find_const(char *name, int f)
1373 {
1374   struct rconst *cur = const_hash[hash_ident(name)];
1375   while (cur && strcmp(cur->name, name))
1376     cur = cur->next;
1377   if (!cur) {
1378     if (f) yyerror("constant %s not found\n", name);
1379     return NULL;
1380   }
1381   return cur->var;
1382 }