reactos/tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "widl.h"
  35 #include "utils.h"
  36 #include "parser.h"
  37 #include "header.h"
  38 #include "typelib.h"
  39
  40 #if defined(YYBYACC)
  41         /* Berkeley yacc (byacc) doesn't seem to know about these */
  42         /* Some *BSD supplied versions do define these though */
  43 # ifndef YYEMPTY
  44 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  45 # endif
  46 # ifndef YYLEX
  47 #  define YYLEX         yylex()
  48 # endif
  49
  50 #elif defined(YYBISON)
  51         /* Bison was used for original development */
  52         /* #define YYEMPTY -2 */
  53         /* #define YYLEX   yylex() */
  54
  55 #else
  56         /* No yacc we know yet */
  57 # if !defined(YYEMPTY) || !defined(YYLEX)
  58 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  59 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  60 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  61   /* #else we just take a chance that it works... */
  62 # endif
  63 #endif
  64
  65 static attr_t *make_attr(enum attr_type type);
  66 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  67 static attr_t *make_attrp(enum attr_type type, void *val);
  68 static expr_t *make_expr(enum expr_type type);
  69 static expr_t *make_exprl(enum expr_type type, long val);
  70 static expr_t *make_exprs(enum expr_type type, char *val);
  71 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  72 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  73 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  74 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  75 static type_t *make_type(unsigned char type, type_t *ref);
  76 static typeref_t *make_tref(char *name, type_t *ref);
  77 static typeref_t *uniq_tref(typeref_t *ref);
  78 static type_t *type_ref(typeref_t *ref);
  79 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  80 static ifref_t *make_ifref(type_t *iface);
  81 static var_t *make_var(char *name);
  82 static func_t *make_func(var_t *def, var_t *args);
  83 static class_t *make_class(char *name);
  84
  85 static type_t *reg_type(type_t *type, char *name, int t);
  86 static type_t *reg_types(type_t *type, var_t *names, int t);
  87 static type_t *find_type(char *name, int t);
  88 static type_t *find_type2(char *name, int t);
  89 static type_t *get_type(unsigned char type, char *name, int t);
  90 static type_t *get_typev(unsigned char type, var_t *name, int t);
  91 static int get_struct_type(var_t *fields);
  92
  93 static var_t *reg_const(var_t *var);
  94 static var_t *find_const(char *name, int f);
  95
  96 #define tsENUM   1
  97 #define tsSTRUCT 2
  98 #define tsUNION  3
  99
 100 static type_t std_bool = { "boolean" };
 101 static type_t std_int = { "int" };
 102 static type_t std_int64 = { "__int64" };
 103 static type_t std_uhyper = { "MIDL_uhyper" };
 104
 105 %}
 106 %union {
 107         attr_t *attr;
 108         expr_t *expr;
 109         type_t *type;
 110         typeref_t *tref;
 111         var_t *var;
 112         func_t *func;
 113         ifref_t *ifref;
 114         class_t *clas;
 115         char *str;
 116         UUID *uuid;
 117         unsigned int num;
 118 }
 119
 120 %token <str> aIDENTIFIER
 121 %token <str> aKNOWNTYPE
 122 %token <num> aNUM aHEXNUM
 123 %token <str> aSTRING
 124 %token <uuid> aUUID
 125 %token aEOF
 126 %token SHL SHR
 127 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 128 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 129 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 130 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 131 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 132 %token tDEFAULT
 133 %token tDEFAULTVALUE
 134 %token tDISPINTERFACE
 135 %token tDLLNAME tDOUBLE tDUAL
 136 %token tENDPOINT
 137 %token tENTRY tENUM tERRORSTATUST
 138 %token tEXPLICITHANDLE tEXTERN
 139 %token tFLOAT
 140 %token tHANDLE
 141 %token tHANDLET
 142 %token tHELPCONTEXT tHELPFILE
 143 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 144 %token tHIDDEN
 145 %token tHYPER tID tIDEMPOTENT
 146 %token tIIDIS
 147 %token tIMPLICITHANDLE
 148 %token tIMPORT tIMPORTLIB
 149 %token tIN tINCLUDE tINLINE
 150 %token tINPUTSYNC
 151 %token tINT tINT64
 152 %token tINTERFACE
 153 %token tLENGTHIS tLIBRARY
 154 %token tLOCAL
 155 %token tLONG
 156 %token tMETHODS
 157 %token tMODULE
 158 %token tNONCREATABLE
 159 %token tOBJECT tODL tOLEAUTOMATION
 160 %token tOPTIONAL
 161 %token tOUT
 162 %token tPOINTERDEFAULT
 163 %token tPROPERTIES
 164 %token tPROPGET tPROPPUT tPROPPUTREF
 165 %token tPUBLIC
 166 %token tREADONLY tREF
 167 %token tRESTRICTED
 168 %token tRETVAL
 169 %token tSHORT
 170 %token tSIGNED
 171 %token tSIZEIS tSIZEOF
 172 %token tSMALL
 173 %token tSOURCE
 174 %token tSTDCALL
 175 %token tSTRING tSTRUCT
 176 %token tSWITCH tSWITCHIS tSWITCHTYPE
 177 %token tTRANSMITAS
 178 %token tTYPEDEF
 179 %token tUNION
 180 %token tUNIQUE
 181 %token tUNSIGNED
 182 %token tUUID
 183 %token tV1ENUM
 184 %token tVARARG
 185 %token tVERSION
 186 %token tVOID
 187 %token tWCHAR tWIREMARSHAL
 188
 189 /* used in attr_t */
 190 %token tPOINTERTYPE
 191
 192 %type <attr> m_attributes attributes attrib_list attribute
 193 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 194 %type <expr> array array_list
 195 %type <type> inherit interface interfacehdr interfacedef interfacedec
 196 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 197 %type <type> module modulehdr moduledef
 198 %type <type> base_type int_std
 199 %type <type> enumdef structdef typedef uniondef
 200 %type <ifref> gbl_statements coclass_ints coclass_int
 201 %type <tref> type
 202 %type <var> m_args no_args args arg
 203 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 204 %type <var> m_ident t_ident ident p_ident pident pident_list
 205 %type <var> dispint_props
 206 %type <func> funcdef int_statements
 207 %type <func> dispint_meths
 208 %type <clas> coclass coclasshdr coclassdef
 209 %type <num> pointer_type version
 210 %type <str> libraryhdr
 211
 212 %left ','
 213 %right COND
 214 %left '|'
 215 %left '&'
 216 %left '-' '+'
 217 %left '*' '/'
 218 %left SHL SHR
 219 %right '~'
 220 %right CAST
 221 %right PPTR
 222 %right NEG
 223
 224 %%
 225
 226 input:    gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 227         ;
 228
 229 gbl_statements:                                 { $$ = NULL; }
 230         | gbl_statements interfacedec           { $$ = $1; }
 231         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 232         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 233         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 234         | gbl_statements librarydef             { $$ = $1; }
 235         | gbl_statements statement              { $$ = $1; }
 236         ;
 237
 238 imp_statements:                                 {}
 239         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 240         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 241         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 242         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 243         | imp_statements statement              {}
 244         ;
 245
 246 int_statements:                                 { $$ = NULL; }
 247         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 248         | int_statements statement              { $$ = $1; }
 249         ;
 250
 251 statement: ';'                                  {}
 252         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 253         | cppquote                              {}
 254         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 255         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 256         | import                                {}
 257         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 258         | typedef ';'                           {}
 259         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         ;
 261
 262 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 263         ;
 264 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 265                                                   if (!do_import($2)) yychar = aEOF; }
 266         ;
 267 import:   import_start imp_statements aEOF      {}
 268         ;
 269
 270 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 271         ;
 272 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 273         ;
 274 librarydef: library_start imp_statements '}'    { end_typelib(); }
 275         ;
 276
 277 m_args:                                         { $$ = NULL; }
 278         | args
 279         ;
 280
 281 no_args:  tVOID                                 { $$ = NULL; }
 282         ;
 283
 284 args:     arg
 285         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 286         | no_args
 287         ;
 288
 289 /* split into two rules to get bison to resolve a tVOID conflict */
 290 arg:      attributes type pident array          { $$ = $3;
 291                                                   set_type($$, $2, $4);
 292                                                   $$->attrs = $1;
 293                                                 }
 294         | type pident array                     { $$ = $2;
 295                                                   set_type($$, $1, $3);
 296                                                 }
 297         | attributes type pident '(' m_args ')' { $$ = $3;
 298                                                   $$->ptr_level--;
 299                                                   set_type($$, $2, NULL);
 300                                                   $$->attrs = $1;
 301                                                   $$->args = $5;
 302                                                 }
 303         | type pident '(' m_args ')'            { $$ = $2;
 304                                                   $$->ptr_level--;
 305                                                   set_type($$, $1, NULL);
 306                                                   $$->args = $4;
 307                                                 }
 308         ;
 309
 310 array:                                          { $$ = NULL; }
 311         | '[' array_list ']'                    { $$ = $2; }
 312         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 313         ;
 314
 315 array_list: m_expr /* size of first dimension is optional */
 316         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 317         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 318         ;
 319
 320 m_attributes:                                   { $$ = NULL; }
 321         | attributes
 322         ;
 323
 324 attributes:
 325           '[' attrib_list ']'                   { $$ = $2; }
 326         ;
 327
 328 attrib_list: attribute
 329         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 330         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 331         ;
 332
 333 attribute:
 334           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 335         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 336         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 337         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 338         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 339         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 340         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 341         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 342         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 343         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 344         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 345         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 346         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 347         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 348         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 349         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 350         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 351         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 352         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 353         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 354         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 355         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 356         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 357         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 358         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 359         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 360         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 361         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 362         | tIN                                   { $$ = make_attr(ATTR_IN); }
 363         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 364         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 365         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 366         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 367         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 368         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 369         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 370         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 371         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 372         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 373         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 374         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 375         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 376         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 377         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 378         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 379         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 380         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 381         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 382         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 383         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 384         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 385         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 386         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 387         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 388         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 389         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 390         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 391         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 392         ;
 393
 394 callconv:
 395         | tSTDCALL
 396         ;
 397
 398 cases:                                          { $$ = NULL; }
 399         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 400                                                   else { $$ = $1; }
 401                                                 }
 402         ;
 403
 404 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 405                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 406                                                   LINK(a, $$->attrs); $$->attrs = a;
 407                                                 }
 408         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 409                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 410                                                   LINK(a, $$->attrs); $$->attrs = a;
 411                                                 }
 412         ;
 413
 414 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 415                                                   set_type($$, $2, NULL);
 416                                                   $$->eval = $5;
 417                                                   $$->lval = $5->cval;
 418                                                 }
 419         ;
 420
 421 enums:                                          { $$ = NULL; }
 422         | enum_list ','                         { $$ = $1; }
 423         | enum_list
 424         ;
 425
 426 enum_list: enum
 427         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 428                                                   if ($1 && !$3->eval)
 429                                                     $3->lval = $1->lval + 1;
 430                                                 }
 431         ;
 432
 433 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 434                                                   $$->eval = $3;
 435                                                   $$->lval = $3->cval;
 436                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 437                                                 }
 438         | ident                                 { $$ = reg_const($1);
 439                                                   $$->lval = 0; /* default for first enum entry */
 440                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 441                                                 }
 442         ;
 443
 444 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 445                                                   $$->fields = $4;
 446                                                   $$->defined = TRUE;
 447                                                   if(in_typelib)
 448                                                       add_enum($$);
 449                                                 }
 450         ;
 451
 452 m_exprs:  m_expr
 453         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 454         ;
 455
 456 /*
 457 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 458         | expr_list
 459         ;
 460
 461 expr_list: expr
 462         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 463         ;
 464 */
 465
 466 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 467         | expr
 468         ;
 469
 470 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 471         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 472         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 473         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 474         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 475         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 476         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 477         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 478         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 479         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 480         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 481         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 482         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 483         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 484         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 485         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 486         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 487         | '(' expr ')'                          { $$ = $2; }
 488         ;
 489
 490 expr_list_const: expr_const
 491         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 492         ;
 493
 494 expr_const: expr                                { $$ = $1;
 495                                                   if (!$$->is_const)
 496                                                       yyerror("expression is not constant\n");
 497                                                 }
 498         ;
 499
 500 externdef: tEXTERN tCONST type ident            { $$ = $4;
 501                                                   set_type($$, $3, NULL);
 502                                                 }
 503         ;
 504
 505 fields:                                         { $$ = NULL; }
 506         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 507                                                   else { $$ = $1; }
 508                                                 }
 509         ;
 510
 511 field:    s_field ';'                           { $$ = $1; }
 512         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 513         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 514         | ';'                                   { $$ = NULL; }
 515         ;
 516
 517 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 518         ;
 519
 520 funcdef:
 521           m_attributes type callconv pident
 522           '(' m_args ')'                        { set_type($4, $2, NULL);
 523                                                   $4->attrs = $1;
 524                                                   $$ = make_func($4, $6);
 525                                                   if (is_attr($4->attrs, ATTR_IN)) {
 526                                                     yyerror("Inapplicable attribute");
 527                                                   }
 528                                                 }
 529         ;
 530
 531 m_ident:                                        { $$ = NULL; }
 532         | ident
 533         ;
 534
 535 t_ident:                                        { $$ = NULL; }
 536         | aIDENTIFIER                           { $$ = make_var($1); }
 537         | aKNOWNTYPE                            { $$ = make_var($1); }
 538         ;
 539
 540 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 541 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 542         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 543         | tID                                   { $$ = make_var($<str>1); }
 544         | tRETVAL                               { $$ = make_var($<str>1); }
 545         | tVERSION                              { $$ = make_var($<str>1); }
 546         ;
 547
 548 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 549         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 550         | int_std
 551         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 552         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 553                                                   switch ($$->type) {
 554                                                   case RPC_FC_CHAR: break;
 555                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 556                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 557                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 558                                                   case RPC_FC_HYPER:
 559                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 560                                                     break;
 561                                                   default: break;
 562                                                   }
 563                                                 }
 564         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 565         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 566         | tBOOLEAN                              { $$ = make_type(RPC_FC_SMALL, &std_bool); }
 567         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 568         | tHANDLET                              { $$ = make_type(RPC_FC_IGNORE, NULL); }
 569         ;
 570
 571 m_int:
 572         | tINT
 573         ;
 574
 575 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 576         | tSMALL m_int                          { $$ = make_type(RPC_FC_SMALL, NULL); }
 577         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 578         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 579         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 580         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 581         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 582         ;
 583
 584 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 585         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 586         ;
 587
 588 coclasshdr: attributes coclass                  { $$ = $2;
 589                                                   $$->attrs = $1;
 590                                                   if (!parse_only && do_header) write_coclass($$);
 591                                                 }
 592         ;
 593
 594 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 595                                                   $$->ifaces = $3;
 596                                                 }
 597         ;
 598
 599 coclass_ints:                                   { $$ = NULL; }
 600         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 601         ;
 602
 603 coclass_int:
 604           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 605         ;
 606
 607 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 608         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 609         ;
 610
 611 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 612                                                   if ($$->defined) yyerror("multiple definition error\n");
 613                                                   $$->attrs = $1;
 614                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 615                                                   LINK($$->attrs, $1);
 616                                                   $$->ref = find_type("IDispatch", 0);
 617                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 618                                                   $$->defined = TRUE;
 619                                                   if (!parse_only && do_header) write_forward($$);
 620                                                 }
 621         ;
 622
 623 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 624         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 625         ;
 626
 627 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 628         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 629         ;
 630
 631 dispinterfacedef: dispinterfacehdr '{'
 632           dispint_props
 633           dispint_meths
 634           '}'                                   { $$ = $1;
 635                                                   $$->fields = $3;
 636                                                   $$->funcs = $4;
 637                                                   if (!parse_only && do_header) write_dispinterface($$);
 638                                                 }
 639 /* FIXME: not sure how to handle this yet
 640         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 641                                                   if (!parse_only && do_header) write_interface($$);
 642                                                 }
 643 */
 644         ;
 645
 646 inherit:                                        { $$ = NULL; }
 647         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 648         ;
 649
 650 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 651         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 652         ;
 653
 654 interfacehdr: attributes interface              { $$ = $2;
 655                                                   if ($$->defined) yyerror("multiple definition error\n");
 656                                                   $$->attrs = $1;
 657                                                   $$->defined = TRUE;
 658                                                   if (!parse_only && do_header) write_forward($$);
 659                                                 }
 660         ;
 661
 662 interfacedef: interfacehdr inherit
 663           '{' int_statements '}'                { $$ = $1;
 664                                                   $$->ref = $2;
 665                                                   $$->funcs = $4;
 666                                                   if (!parse_only && do_header) write_interface($$);
 667                                                 }
 668 /* MIDL is able to import the definition of a base class from inside the
 669  * definition of a derived class, I'll try to support it with this rule */
 670         | interfacehdr ':' aIDENTIFIER
 671           '{' import int_statements '}'         { $$ = $1;
 672                                                   $$->ref = find_type2($3, 0);
 673                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 674                                                   $$->funcs = $6;
 675                                                   if (!parse_only && do_header) write_interface($$);
 676                                                 }
 677         | dispinterfacedef                      { $$ = $1; }
 678         ;
 679
 680 interfacedec:
 681           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 682         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 683         ;
 684
 685 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 686         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 687         ;
 688
 689 modulehdr: attributes module                    { $$ = $2;
 690                                                   $$->attrs = $1;
 691                                                 }
 692         ;
 693
 694 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 695                                                   $$->funcs = $3;
 696                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 697                                                 }
 698         ;
 699
 700 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 701         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 702         ;
 703
 704 pident:   ident
 705         | p_ident
 706         | '(' pident ')'                        { $$ = $2; }
 707         ;
 708
 709 pident_list:
 710           pident
 711         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 712         ;
 713
 714 pointer_type:
 715           tREF                                  { $$ = RPC_FC_RP; }
 716         | tUNIQUE                               { $$ = RPC_FC_UP; }
 717         ;
 718
 719 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 720                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 721                                                   $$->type = get_struct_type( $4 );
 722                                                   $$->fields = $4;
 723                                                   $$->defined = TRUE;
 724                                                   if(in_typelib)
 725                                                     add_struct($$);
 726                                                 }
 727         ;
 728
 729 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 730         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 731         | base_type                             { $$ = make_tref(NULL, $1); }
 732         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 733         | enumdef                               { $$ = make_tref(NULL, $1); }
 734         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 735         | structdef                             { $$ = make_tref(NULL, $1); }
 736         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 737         | uniondef                              { $$ = make_tref(NULL, $1); }
 738         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 739         ;
 740
 741 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 742                                                   $4->tname = tref->name;
 743                                                   tref->name = NULL;
 744                                                   $$ = type_ref(tref);
 745                                                   $$->attrs = $2;
 746                                                   if (!parse_only && do_header) write_typedef($$, $4);
 747                                                   if (in_typelib && $$->attrs)
 748                                                       add_typedef($$, $4);
 749                                                   reg_types($$, $4, 0);
 750                                                 }
 751         ;
 752
 753 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 754                                                   $$->fields = $4;
 755                                                   $$->defined = TRUE;
 756                                                 }
 757         | tUNION t_ident
 758           tSWITCH '(' s_field ')'
 759           m_ident '{' cases '}'                 { var_t *u = $7;
 760                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 761                                                   if (!u) u = make_var("tagged_union");
 762                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 763                                                   u->type->fields = $9;
 764                                                   u->type->defined = TRUE;
 765                                                   LINK(u, $5); $$->fields = u;
 766                                                   $$->defined = TRUE;
 767                                                 }
 768         ;
 769
 770 version:
 771           aNUM                                  { $$ = MAKELONG($1, 0); }
 772         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 773         ;
 774
 775 %%
 776
 777 static attr_t *make_attr(enum attr_type type)
 778 {
 779   attr_t *a = xmalloc(sizeof(attr_t));
 780   a->type = type;
 781   a->u.ival = 0;
 782   INIT_LINK(a);
 783   return a;
 784 }
 785
 786 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 787 {
 788   attr_t *a = xmalloc(sizeof(attr_t));
 789   a->type = type;
 790   a->u.ival = val;
 791   INIT_LINK(a);
 792   return a;
 793 }
 794
 795 static attr_t *make_attrp(enum attr_type type, void *val)
 796 {
 797   attr_t *a = xmalloc(sizeof(attr_t));
 798   a->type = type;
 799   a->u.pval = val;
 800   INIT_LINK(a);
 801   return a;
 802 }
 803
 804 static expr_t *make_expr(enum expr_type type)
 805 {
 806   expr_t *e = xmalloc(sizeof(expr_t));
 807   e->type = type;
 808   e->ref = NULL;
 809   e->u.lval = 0;
 810   e->is_const = FALSE;
 811   INIT_LINK(e);
 812   return e;
 813 }
 814
 815 static expr_t *make_exprl(enum expr_type type, long val)
 816 {
 817   expr_t *e = xmalloc(sizeof(expr_t));
 818   e->type = type;
 819   e->ref = NULL;
 820   e->u.lval = val;
 821   e->is_const = FALSE;
 822   INIT_LINK(e);
 823   /* check for numeric constant */
 824   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 825     e->is_const = TRUE;
 826     e->cval = val;
 827   }
 828   return e;
 829 }
 830
 831 static expr_t *make_exprs(enum expr_type type, char *val)
 832 {
 833   expr_t *e;
 834   e = xmalloc(sizeof(expr_t));
 835   e->type = type;
 836   e->ref = NULL;
 837   e->u.sval = val;
 838   e->is_const = FALSE;
 839   INIT_LINK(e);
 840   /* check for predefined constants */
 841   if (type == EXPR_IDENTIFIER) {
 842     var_t *c = find_const(val, 0);
 843     if (c) {
 844       e->u.sval = c->name;
 845       free(val);
 846       e->is_const = TRUE;
 847       e->cval = c->lval;
 848     }
 849   }
 850   return e;
 851 }
 852
 853 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 854 {
 855   expr_t *e;
 856   e = xmalloc(sizeof(expr_t));
 857   e->type = type;
 858   e->ref = expr;
 859   e->u.tref = tref;
 860   e->is_const = FALSE;
 861   INIT_LINK(e);
 862   /* check for cast of constant expression */
 863   if (type == EXPR_CAST && expr->is_const) {
 864     e->is_const = TRUE;
 865     e->cval = expr->cval;
 866   }
 867   return e;
 868 }
 869
 870 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 871 {
 872   expr_t *e;
 873   e = xmalloc(sizeof(expr_t));
 874   e->type = type;
 875   e->ref = expr;
 876   e->u.lval = 0;
 877   e->is_const = FALSE;
 878   INIT_LINK(e);
 879   /* check for compile-time optimization */
 880   if (expr->is_const) {
 881     e->is_const = TRUE;
 882     switch (type) {
 883     case EXPR_NEG:
 884       e->cval = -expr->cval;
 885       break;
 886     case EXPR_NOT:
 887       e->cval = ~expr->cval;
 888       break;
 889     default:
 890       e->is_const = FALSE;
 891       break;
 892     }
 893   }
 894   return e;
 895 }
 896
 897 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 898 {
 899   expr_t *e;
 900   e = xmalloc(sizeof(expr_t));
 901   e->type = type;
 902   e->ref = expr1;
 903   e->u.ext = expr2;
 904   e->is_const = FALSE;
 905   INIT_LINK(e);
 906   /* check for compile-time optimization */
 907   if (expr1->is_const && expr2->is_const) {
 908     e->is_const = TRUE;
 909     switch (type) {
 910     case EXPR_ADD:
 911       e->cval = expr1->cval + expr2->cval;
 912       break;
 913     case EXPR_SUB:
 914       e->cval = expr1->cval - expr2->cval;
 915       break;
 916     case EXPR_MUL:
 917       e->cval = expr1->cval * expr2->cval;
 918       break;
 919     case EXPR_DIV:
 920       e->cval = expr1->cval / expr2->cval;
 921       break;
 922     case EXPR_OR:
 923       e->cval = expr1->cval | expr2->cval;
 924       break;
 925     case EXPR_AND:
 926       e->cval = expr1->cval & expr2->cval;
 927       break;
 928     case EXPR_SHL:
 929       e->cval = expr1->cval << expr2->cval;
 930       break;
 931     case EXPR_SHR:
 932       e->cval = expr1->cval >> expr2->cval;
 933       break;
 934     default:
 935       e->is_const = FALSE;
 936       break;
 937     }
 938   }
 939   return e;
 940 }
 941
 942 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 943 {
 944   expr_t *e;
 945   e = xmalloc(sizeof(expr_t));
 946   e->type = type;
 947   e->ref = expr1;
 948   e->u.ext = expr2;
 949   e->ext2 = expr3;
 950   e->is_const = FALSE;
 951   INIT_LINK(e);
 952   /* check for compile-time optimization */
 953   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 954     e->is_const = TRUE;
 955     switch (type) {
 956     case EXPR_COND:
 957       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 958       break;
 959     default:
 960       e->is_const = FALSE;
 961       break;
 962     }
 963   }
 964   return e;
 965 }
 966
 967 static type_t *make_type(unsigned char type, type_t *ref)
 968 {
 969   type_t *t = xmalloc(sizeof(type_t));
 970   t->name = NULL;
 971   t->type = type;
 972   t->ref = ref;
 973   t->rname = NULL;
 974   t->attrs = NULL;
 975   t->funcs = NULL;
 976   t->fields = NULL;
 977   t->ignore = parse_only;
 978   t->is_const = FALSE;
 979   t->sign = 0;
 980   t->defined = FALSE;
 981   t->written = FALSE;
 982   t->typelib_idx = -1;
 983   INIT_LINK(t);
 984   return t;
 985 }
 986
 987 static typeref_t *make_tref(char *name, type_t *ref)
 988 {
 989   typeref_t *t = xmalloc(sizeof(typeref_t));
 990   t->name = name;
 991   t->ref = ref;
 992   t->uniq = ref ? 0 : 1;
 993   return t;
 994 }
 995
 996 static typeref_t *uniq_tref(typeref_t *ref)
 997 {
 998   typeref_t *t = ref;
 999   type_t *tp;
1000   if (t->uniq) return t;
1001   tp = make_type(0, t->ref);
1002   tp->name = t->name;
1003   t->name = NULL;
1004   t->ref = tp;
1005   t->uniq = 1;
1006   return t;
1007 }
1008
1009 static type_t *type_ref(typeref_t *ref)
1010 {
1011   type_t *t = ref->ref;
1012   if (ref->name) free(ref->name);
1013   free(ref);
1014   return t;
1015 }
1016
1017 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1018 {
1019   v->type = ref->ref;
1020   v->tname = ref->name;
1021   ref->name = NULL;
1022   free(ref);
1023   v->array = arr;
1024 }
1025
1026 static ifref_t *make_ifref(type_t *iface)
1027 {
1028   ifref_t *l = xmalloc(sizeof(ifref_t));
1029   l->iface = iface;
1030   l->attrs = NULL;
1031   INIT_LINK(l);
1032   return l;
1033 }
1034
1035 static var_t *make_var(char *name)
1036 {
1037   var_t *v = xmalloc(sizeof(var_t));
1038   v->name = name;
1039   v->ptr_level = 0;
1040   v->type = NULL;
1041   v->tname = NULL;
1042   v->attrs = NULL;
1043   v->array = NULL;
1044   v->eval = NULL;
1045   v->lval = 0;
1046   INIT_LINK(v);
1047   return v;
1048 }
1049
1050 static func_t *make_func(var_t *def, var_t *args)
1051 {
1052   func_t *f = xmalloc(sizeof(func_t));
1053   f->def = def;
1054   f->args = args;
1055   f->ignore = parse_only;
1056   f->idx = -1;
1057   INIT_LINK(f);
1058   return f;
1059 }
1060
1061 static class_t *make_class(char *name)
1062 {
1063   class_t *c = xmalloc(sizeof(class_t));
1064   c->name = name;
1065   c->attrs = NULL;
1066   c->ifaces = NULL;
1067   INIT_LINK(c);
1068   return c;
1069 }
1070
1071 #define HASHMAX 64
1072
1073 static int hash_ident(const char *name)
1074 {
1075   const char *p = name;
1076   int sum = 0;
1077   /* a simple sum hash is probably good enough */
1078   while (*p) {
1079     sum += *p;
1080     p++;
1081   }
1082   return sum & (HASHMAX-1);
1083 }
1084
1085 /***** type repository *****/
1086
1087 struct rtype {
1088   char *name;
1089   type_t *type;
1090   int t;
1091   struct rtype *next;
1092 };
1093
1094 struct rtype *type_hash[HASHMAX];
1095
1096 static type_t *reg_type(type_t *type, char *name, int t)
1097 {
1098   struct rtype *nt;
1099   int hash;
1100   if (!name) {
1101     yyerror("registering named type without name\n");
1102     return type;
1103   }
1104   hash = hash_ident(name);
1105   nt = xmalloc(sizeof(struct rtype));
1106   nt->name = name;
1107   nt->type = type;
1108   nt->t = t;
1109   nt->next = type_hash[hash];
1110   type_hash[hash] = nt;
1111   return type;
1112 }
1113
1114 /* determine pointer type from attrs */
1115 static unsigned char get_pointer_type( type_t *type )
1116 {
1117   int t;
1118   if (is_attr( type->attrs, ATTR_STRING ))
1119   {
1120     type_t *t = type;
1121     while( t->type == 0 && t->ref )
1122       t = t->ref;
1123     switch( t->type )
1124     {
1125     case RPC_FC_CHAR:
1126       return RPC_FC_C_CSTRING;
1127     case RPC_FC_WCHAR:
1128       return RPC_FC_C_WSTRING;
1129     }
1130   }
1131   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1132   if (t) return t;
1133   return RPC_FC_FP;
1134 }
1135
1136 static type_t *reg_types(type_t *type, var_t *names, int t)
1137 {
1138   type_t *ptr = type;
1139   int ptrc = 0;
1140
1141   while (names) {
1142     var_t *next = NEXT_LINK(names);
1143     if (names->name) {
1144       type_t *cur = ptr;
1145       int cptr = names->ptr_level;
1146       if (cptr > ptrc) {
1147         while (cptr > ptrc) {
1148           int t = get_pointer_type( cur );
1149           cur = ptr = make_type(t, cur);
1150           ptrc++;
1151         }
1152       } else {
1153         while (cptr < ptrc) {
1154           cur = cur->ref;
1155           cptr++;
1156         }
1157       }
1158       reg_type(cur, names->name, t);
1159     }
1160     free(names);
1161     names = next;
1162   }
1163   return type;
1164 }
1165
1166 static type_t *find_type(char *name, int t)
1167 {
1168   struct rtype *cur = type_hash[hash_ident(name)];
1169   while (cur && (cur->t != t || strcmp(cur->name, name)))
1170     cur = cur->next;
1171   if (!cur) {
1172     yyerror("type %s not found\n", name);
1173     return NULL;
1174   }
1175   return cur->type;
1176 }
1177
1178 static type_t *find_type2(char *name, int t)
1179 {
1180   type_t *tp = find_type(name, t);
1181   free(name);
1182   return tp;
1183 }
1184
1185 int is_type(const char *name)
1186 {
1187   struct rtype *cur = type_hash[hash_ident(name)];
1188   while (cur && (cur->t || strcmp(cur->name, name)))
1189     cur = cur->next;
1190   if (cur) return TRUE;
1191   return FALSE;
1192 }
1193
1194 static type_t *get_type(unsigned char type, char *name, int t)
1195 {
1196   struct rtype *cur = NULL;
1197   type_t *tp;
1198   if (name) {
1199     cur = type_hash[hash_ident(name)];
1200     while (cur && (cur->t != t || strcmp(cur->name, name)))
1201       cur = cur->next;
1202   }
1203   if (cur) {
1204     free(name);
1205     return cur->type;
1206   }
1207   tp = make_type(type, NULL);
1208   tp->name = name;
1209   if (!name) return tp;
1210   return reg_type(tp, name, t);
1211 }
1212
1213 static type_t *get_typev(unsigned char type, var_t *name, int t)
1214 {
1215   char *sname = NULL;
1216   if (name) {
1217     sname = name->name;
1218     free(name);
1219   }
1220   return get_type(type, sname, t);
1221 }
1222
1223 static int get_struct_type(var_t *field)
1224 {
1225   int has_pointer = 0;
1226   int has_conformant_array = 0;
1227   int has_conformant_string = 0;
1228
1229   while (field)
1230   {
1231     type_t *t = field->type;
1232
1233     /* get the base type */
1234     while( (t->type == 0) && t->ref )
1235       t = t->ref;
1236
1237     switch (t->type)
1238     {
1239     /*
1240      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1241      *  Simple types don't effect the type of struct.
1242      *  A struct containing a simple struct is still a simple struct.
1243      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1244      */
1245     case 0: /* void pointer */
1246     case RPC_FC_BYTE:
1247     case RPC_FC_CHAR:
1248     case RPC_FC_SMALL:
1249     case RPC_FC_USMALL:
1250     case RPC_FC_WCHAR:
1251     case RPC_FC_SHORT:
1252     case RPC_FC_USHORT:
1253     case RPC_FC_LONG:
1254     case RPC_FC_ULONG:
1255     case RPC_FC_INT3264:
1256     case RPC_FC_UINT3264:
1257     case RPC_FC_HYPER:
1258     case RPC_FC_FLOAT:
1259     case RPC_FC_DOUBLE:
1260     case RPC_FC_STRUCT:
1261     case RPC_FC_ENUM16:
1262     case RPC_FC_ENUM32:
1263       break;
1264
1265     case RPC_FC_UP:
1266     case RPC_FC_FP:
1267       has_pointer = 1;
1268       break;
1269     case RPC_FC_CARRAY:
1270       has_conformant_array = 1;
1271       break;
1272     case RPC_FC_C_CSTRING:
1273     case RPC_FC_C_WSTRING:
1274       has_conformant_string = 1;
1275       break;
1276
1277     /*
1278      * Propagate member attributes
1279      *  a struct should be at least as complex as its member
1280      */
1281     case RPC_FC_CVSTRUCT:
1282       has_conformant_string = 1;
1283       has_pointer = 1;
1284       break;
1285
1286     case RPC_FC_CPSTRUCT:
1287       has_conformant_array = 1;
1288       has_pointer = 1;
1289       break;
1290
1291     case RPC_FC_CSTRUCT:
1292       has_conformant_array = 1;
1293       break;
1294
1295     case RPC_FC_PSTRUCT:
1296       has_pointer = 1;
1297       break;
1298
1299     default:
1300       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1301               field->name, t->type);
1302       /* fallthru - treat it as complex */
1303
1304     /* as soon as we see one of these these members, it's bogus... */
1305     case RPC_FC_IP:
1306     case RPC_FC_ENCAPSULATED_UNION:
1307     case RPC_FC_NON_ENCAPSULATED_UNION:
1308     case RPC_FC_TRANSMIT_AS:
1309     case RPC_FC_REPRESENT_AS:
1310     case RPC_FC_PAD:
1311     case RPC_FC_EMBEDDED_COMPLEX:
1312     case RPC_FC_BOGUS_STRUCT:
1313       return RPC_FC_BOGUS_STRUCT;
1314     }
1315     field = NEXT_LINK(field);
1316   }
1317
1318   if( has_conformant_string && has_pointer )
1319     return RPC_FC_CVSTRUCT;
1320   if( has_conformant_array && has_pointer )
1321     return RPC_FC_CPSTRUCT;
1322   if( has_conformant_array )
1323     return RPC_FC_CSTRUCT;
1324   if( has_pointer )
1325     return RPC_FC_PSTRUCT;
1326   return RPC_FC_STRUCT;
1327 }
1328
1329 /***** constant repository *****/
1330
1331 struct rconst {
1332   char *name;
1333   var_t *var;
1334   struct rconst *next;
1335 };
1336
1337 struct rconst *const_hash[HASHMAX];
1338
1339 static var_t *reg_const(var_t *var)
1340 {
1341   struct rconst *nc;
1342   int hash;
1343   if (!var->name) {
1344     yyerror("registering constant without name\n");
1345     return var;
1346   }
1347   hash = hash_ident(var->name);
1348   nc = xmalloc(sizeof(struct rconst));
1349   nc->name = var->name;
1350   nc->var = var;
1351   nc->next = const_hash[hash];
1352   const_hash[hash] = nc;
1353   return var;
1354 }
1355
1356 static var_t *find_const(char *name, int f)
1357 {
1358   struct rconst *cur = const_hash[hash_ident(name)];
1359   while (cur && strcmp(cur->name, name))
1360     cur = cur->next;
1361   if (!cur) {
1362     if (f) yyerror("constant %s not found\n", name);
1363     return NULL;
1364   }
1365   return cur->var;
1366 }