reactos/tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "widl.h"
  35 #include "utils.h"
  36 #include "parser.h"
  37 #include "header.h"
  38 #include "typelib.h"
  39
  40 #if defined(YYBYACC)
  41         /* Berkeley yacc (byacc) doesn't seem to know about these */
  42         /* Some *BSD supplied versions do define these though */
  43 # ifndef YYEMPTY
  44 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  45 # endif
  46 # ifndef YYLEX
  47 #  define YYLEX         yylex()
  48 # endif
  49
  50 #elif defined(YYBISON)
  51         /* Bison was used for original development */
  52         /* #define YYEMPTY -2 */
  53         /* #define YYLEX   yylex() */
  54
  55 #else
  56         /* No yacc we know yet */
  57 # if !defined(YYEMPTY) || !defined(YYLEX)
  58 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  59 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  60 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  61   /* #else we just take a chance that it works... */
  62 # endif
  63 #endif
  64
  65 static attr_t *make_attr(enum attr_type type);
  66 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  67 static attr_t *make_attrp(enum attr_type type, void *val);
  68 static expr_t *make_expr(enum expr_type type);
  69 static expr_t *make_exprl(enum expr_type type, long val);
  70 static expr_t *make_exprs(enum expr_type type, char *val);
  71 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  72 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  73 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  74 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  75 static type_t *make_type(unsigned char type, type_t *ref);
  76 static typeref_t *make_tref(char *name, type_t *ref);
  77 static typeref_t *uniq_tref(typeref_t *ref);
  78 static type_t *type_ref(typeref_t *ref);
  79 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  80 static ifref_t *make_ifref(type_t *iface);
  81 static var_t *make_var(char *name);
  82 static func_t *make_func(var_t *def, var_t *args);
  83 static class_t *make_class(char *name);
  84
  85 static type_t *reg_type(type_t *type, char *name, int t);
  86 static type_t *reg_types(type_t *type, var_t *names, int t);
  87 static type_t *find_type(char *name, int t);
  88 static type_t *find_type2(char *name, int t);
  89 static type_t *get_type(unsigned char type, char *name, int t);
  90 static type_t *get_typev(unsigned char type, var_t *name, int t);
  91 static int get_struct_type(var_t *fields);
  92
  93 static var_t *reg_const(var_t *var);
  94 static var_t *find_const(char *name, int f);
  95
  96 #define tsENUM   1
  97 #define tsSTRUCT 2
  98 #define tsUNION  3
  99
 100 static type_t std_bool = { "boolean" };
 101 static type_t std_int = { "int" };
 102 static type_t std_int64 = { "__int64" };
 103 static type_t std_uhyper = { "MIDL_uhyper" };
 104
 105 %}
 106 %union {
 107         attr_t *attr;
 108         expr_t *expr;
 109         type_t *type;
 110         typeref_t *tref;
 111         var_t *var;
 112         func_t *func;
 113         ifref_t *ifref;
 114         class_t *clas;
 115         char *str;
 116         UUID *uuid;
 117         unsigned int num;
 118 }
 119
 120 %token <str> aIDENTIFIER
 121 %token <str> aKNOWNTYPE
 122 %token <num> aNUM aHEXNUM
 123 %token <str> aSTRING
 124 %token <uuid> aUUID
 125 %token aEOF
 126 %token SHL SHR
 127 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 128 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 129 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 130 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 131 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 132 %token tDEFAULT
 133 %token tDEFAULTVALUE
 134 %token tDISPINTERFACE
 135 %token tDLLNAME tDOUBLE tDUAL
 136 %token tENDPOINT
 137 %token tENTRY tENUM tERRORSTATUST
 138 %token tEXPLICITHANDLE tEXTERN
 139 %token tFLOAT
 140 %token tHANDLE
 141 %token tHANDLET
 142 %token tHELPCONTEXT tHELPFILE
 143 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 144 %token tHIDDEN
 145 %token tHYPER tID tIDEMPOTENT
 146 %token tIIDIS
 147 %token tIMPLICITHANDLE
 148 %token tIMPORT tIMPORTLIB
 149 %token tIN tINCLUDE tINLINE
 150 %token tINPUTSYNC
 151 %token tINT tINT64
 152 %token tINTERFACE
 153 %token tLENGTHIS tLIBRARY
 154 %token tLOCAL
 155 %token tLONG
 156 %token tMETHODS
 157 %token tMODULE
 158 %token tNONCREATABLE
 159 %token tOBJECT tODL tOLEAUTOMATION
 160 %token tOPTIONAL
 161 %token tOUT
 162 %token tPOINTERDEFAULT
 163 %token tPROPERTIES
 164 %token tPROPGET tPROPPUT tPROPPUTREF
 165 %token tPTR
 166 %token tPUBLIC
 167 %token tREADONLY tREF
 168 %token tRESTRICTED
 169 %token tRETVAL
 170 %token tSHORT
 171 %token tSIGNED
 172 %token tSINGLE
 173 %token tSIZEIS tSIZEOF
 174 %token tSMALL
 175 %token tSOURCE
 176 %token tSTDCALL
 177 %token tSTRING tSTRUCT
 178 %token tSWITCH tSWITCHIS tSWITCHTYPE
 179 %token tTRANSMITAS
 180 %token tTYPEDEF
 181 %token tUNION
 182 %token tUNIQUE
 183 %token tUNSIGNED
 184 %token tUUID
 185 %token tV1ENUM
 186 %token tVARARG
 187 %token tVERSION
 188 %token tVOID
 189 %token tWCHAR tWIREMARSHAL
 190
 191 /* used in attr_t */
 192 %token tPOINTERTYPE
 193
 194 %type <attr> m_attributes attributes attrib_list attribute
 195 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 196 %type <expr> array array_list
 197 %type <type> inherit interface interfacehdr interfacedef interfacedec
 198 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 199 %type <type> module modulehdr moduledef
 200 %type <type> base_type int_std
 201 %type <type> enumdef structdef typedef uniondef
 202 %type <ifref> gbl_statements coclass_ints coclass_int
 203 %type <tref> type
 204 %type <var> m_args no_args args arg
 205 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 206 %type <var> m_ident t_ident ident p_ident pident pident_list
 207 %type <var> dispint_props
 208 %type <func> funcdef int_statements
 209 %type <func> dispint_meths
 210 %type <clas> coclass coclasshdr coclassdef
 211 %type <num> pointer_type version
 212 %type <str> libraryhdr
 213
 214 %left ','
 215 %right COND
 216 %left '|'
 217 %left '&'
 218 %left '-' '+'
 219 %left '*' '/'
 220 %left SHL SHR
 221 %right '~'
 222 %right CAST
 223 %right PPTR
 224 %right NEG
 225
 226 %%
 227
 228 input:    gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 229         ;
 230
 231 gbl_statements:                                 { $$ = NULL; }
 232         | gbl_statements interfacedec           { $$ = $1; }
 233         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 234         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 235         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 236         | gbl_statements librarydef             { $$ = $1; }
 237         | gbl_statements statement              { $$ = $1; }
 238         ;
 239
 240 imp_statements:                                 {}
 241         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 242         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 243         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 244         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 245         | imp_statements statement              {}
 246         ;
 247
 248 int_statements:                                 { $$ = NULL; }
 249         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 250         | int_statements statement              { $$ = $1; }
 251         ;
 252
 253 statement: ';'                                  {}
 254         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 255         | cppquote                              {}
 256         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 257         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 258         | import                                {}
 259         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         | typedef ';'                           {}
 261         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 262         ;
 263
 264 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 265         ;
 266 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 267                                                   if (!do_import($2)) yychar = aEOF; }
 268         ;
 269 import:   import_start imp_statements aEOF      {}
 270         ;
 271
 272 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 273         ;
 274 library_start: attributes libraryhdr '{'        { start_typelib($2, $1); }
 275         ;
 276 librarydef: library_start imp_statements '}'    { end_typelib(); }
 277         ;
 278
 279 m_args:                                         { $$ = NULL; }
 280         | args
 281         ;
 282
 283 no_args:  tVOID                                 { $$ = NULL; }
 284         ;
 285
 286 args:     arg
 287         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 288         | no_args
 289         ;
 290
 291 /* split into two rules to get bison to resolve a tVOID conflict */
 292 arg:      attributes type pident array          { $$ = $3;
 293                                                   set_type($$, $2, $4);
 294                                                   $$->attrs = $1;
 295                                                 }
 296         | type pident array                     { $$ = $2;
 297                                                   set_type($$, $1, $3);
 298                                                 }
 299         | attributes type pident '(' m_args ')' { $$ = $3;
 300                                                   $$->ptr_level--;
 301                                                   set_type($$, $2, NULL);
 302                                                   $$->attrs = $1;
 303                                                   $$->args = $5;
 304                                                 }
 305         | type pident '(' m_args ')'            { $$ = $2;
 306                                                   $$->ptr_level--;
 307                                                   set_type($$, $1, NULL);
 308                                                   $$->args = $4;
 309                                                 }
 310         ;
 311
 312 array:                                          { $$ = NULL; }
 313         | '[' array_list ']'                    { $$ = $2; }
 314         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 315         ;
 316
 317 array_list: m_expr /* size of first dimension is optional */
 318         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 319         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 320         ;
 321
 322 m_attributes:                                   { $$ = NULL; }
 323         | attributes
 324         ;
 325
 326 attributes:
 327           '[' attrib_list ']'                   { $$ = $2; }
 328         ;
 329
 330 attrib_list: attribute
 331         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 332         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 333         ;
 334
 335 attribute:
 336           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 337         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 338         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 339         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 340         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 341         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 342         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 343         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 344         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 345         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 346         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 347         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 348         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 349         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 350         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 351         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 352         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 353         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 354         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 355         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 356         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 357         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 358         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 359         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 360         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 361         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 362         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 363         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 364         | tIN                                   { $$ = make_attr(ATTR_IN); }
 365         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 366         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 367         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 368         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 369         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 370         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 371         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 372         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 373         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 374         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 375         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 376         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 377         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 378         | tPTR                                  { $$ = make_attr(ATTR_PTR); }
 379         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 380         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 381         | tREF                                  { $$ = make_attr(ATTR_REF); }
 382         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 383         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 384         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 385         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 386         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 387         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 388         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 389         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 390         | tUNIQUE                               { $$ = make_attr(ATTR_UNIQUE); }
 391         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 392         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 393         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 394         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 395         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 396         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 397         ;
 398
 399 callconv:
 400         | tSTDCALL
 401         ;
 402
 403 cases:                                          { $$ = NULL; }
 404         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 405                                                   else { $$ = $1; }
 406                                                 }
 407         ;
 408
 409 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 410                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 411                                                   LINK(a, $$->attrs); $$->attrs = a;
 412                                                 }
 413         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 414                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 415                                                   LINK(a, $$->attrs); $$->attrs = a;
 416                                                 }
 417         ;
 418
 419 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 420                                                   set_type($$, $2, NULL);
 421                                                   $$->eval = $5;
 422                                                   $$->lval = $5->cval;
 423                                                 }
 424         ;
 425
 426 enums:                                          { $$ = NULL; }
 427         | enum_list ','                         { $$ = $1; }
 428         | enum_list
 429         ;
 430
 431 enum_list: enum
 432         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 433                                                   if ($1 && !$3->eval)
 434                                                     $3->lval = $1->lval + 1;
 435                                                 }
 436         ;
 437
 438 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 439                                                   $$->eval = $3;
 440                                                   $$->lval = $3->cval;
 441                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 442                                                 }
 443         | ident                                 { $$ = reg_const($1);
 444                                                   $$->lval = 0; /* default for first enum entry */
 445                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 446                                                 }
 447         ;
 448
 449 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 450                                                   $$->fields = $4;
 451                                                   $$->defined = TRUE;
 452                                                   if(in_typelib)
 453                                                       add_enum($$);
 454                                                 }
 455         ;
 456
 457 m_exprs:  m_expr
 458         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 459         ;
 460
 461 /*
 462 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 463         | expr_list
 464         ;
 465
 466 expr_list: expr
 467         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 468         ;
 469 */
 470
 471 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 472         | expr
 473         ;
 474
 475 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 476         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 477         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 478         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 479         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 480         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 481         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 482         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 483         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 484         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 485         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 486         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 487         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 488         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 489         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 490         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 491         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 492         | '(' expr ')'                          { $$ = $2; }
 493         ;
 494
 495 expr_list_const: expr_const
 496         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 497         ;
 498
 499 expr_const: expr                                { $$ = $1;
 500                                                   if (!$$->is_const)
 501                                                       yyerror("expression is not constant\n");
 502                                                 }
 503         ;
 504
 505 externdef: tEXTERN tCONST type ident            { $$ = $4;
 506                                                   set_type($$, $3, NULL);
 507                                                 }
 508         ;
 509
 510 fields:                                         { $$ = NULL; }
 511         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 512                                                   else { $$ = $1; }
 513                                                 }
 514         ;
 515
 516 field:    s_field ';'                           { $$ = $1; }
 517         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 518         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 519         | ';'                                   { $$ = NULL; }
 520         ;
 521
 522 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 523         ;
 524
 525 funcdef:
 526           m_attributes type callconv pident
 527           '(' m_args ')'                        { set_type($4, $2, NULL);
 528                                                   $4->attrs = $1;
 529                                                   $$ = make_func($4, $6);
 530                                                   if (is_attr($4->attrs, ATTR_IN)) {
 531                                                     yyerror("Inapplicable attribute");
 532                                                   }
 533                                                 }
 534         ;
 535
 536 m_ident:                                        { $$ = NULL; }
 537         | ident
 538         ;
 539
 540 t_ident:                                        { $$ = NULL; }
 541         | aIDENTIFIER                           { $$ = make_var($1); }
 542         | aKNOWNTYPE                            { $$ = make_var($1); }
 543         ;
 544
 545 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 546 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 547         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 548         | tID                                   { $$ = make_var($<str>1); }
 549         | tRETVAL                               { $$ = make_var($<str>1); }
 550         | tVERSION                              { $$ = make_var($<str>1); }
 551         ;
 552
 553 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 554         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 555         | int_std
 556         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 557         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 558                                                   switch ($$->type) {
 559                                                   case RPC_FC_CHAR: break;
 560                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 561                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 562                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 563                                                   case RPC_FC_HYPER:
 564                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 565                                                     break;
 566                                                   default: break;
 567                                                   }
 568                                                 }
 569         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 570         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 571         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 572         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 573         | tBOOLEAN                              { $$ = make_type(RPC_FC_SMALL, &std_bool); }
 574         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 575         | tHANDLET                              { $$ = make_type(RPC_FC_IGNORE, NULL); }
 576         ;
 577
 578 m_int:
 579         | tINT
 580         ;
 581
 582 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 583         | tSMALL m_int                          { $$ = make_type(RPC_FC_SMALL, NULL); }
 584         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 585         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 586         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 587         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 588         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 589         ;
 590
 591 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 592         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 593         ;
 594
 595 coclasshdr: attributes coclass                  { $$ = $2;
 596                                                   $$->attrs = $1;
 597                                                   if (!parse_only && do_header)
 598                                                     write_coclass($$);
 599                                                 }
 600         ;
 601
 602 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 603                                                   $$->ifaces = $3;
 604                                                 }
 605         ;
 606
 607 coclass_ints:                                   { $$ = NULL; }
 608         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 609         ;
 610
 611 coclass_int:
 612           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 613         ;
 614
 615 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 616         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 617         ;
 618
 619 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 620                                                   if ($$->defined) yyerror("multiple definition error\n");
 621                                                   $$->attrs = $1;
 622                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 623                                                   LINK($$->attrs, $1);
 624                                                   $$->ref = find_type("IDispatch", 0);
 625                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 626                                                   $$->defined = TRUE;
 627                                                   if (!parse_only && do_header) write_forward($$);
 628                                                 }
 629         ;
 630
 631 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 632         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 633         ;
 634
 635 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 636         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 637         ;
 638
 639 dispinterfacedef: dispinterfacehdr '{'
 640           dispint_props
 641           dispint_meths
 642           '}'                                   { $$ = $1;
 643                                                   $$->fields = $3;
 644                                                   $$->funcs = $4;
 645                                                   if (!parse_only && do_header) write_dispinterface($$);
 646                                                 }
 647 /* FIXME: not sure how to handle this yet
 648         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 649                                                   if (!parse_only && do_header) write_interface($$);
 650                                                 }
 651 */
 652         ;
 653
 654 inherit:                                        { $$ = NULL; }
 655         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 656         ;
 657
 658 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 659         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 660         ;
 661
 662 interfacehdr: attributes interface              { $$ = $2;
 663                                                   if ($$->defined) yyerror("multiple definition error\n");
 664                                                   $$->attrs = $1;
 665                                                   $$->defined = TRUE;
 666                                                   if (!parse_only && do_header) write_forward($$);
 667                                                 }
 668         ;
 669
 670 interfacedef: interfacehdr inherit
 671           '{' int_statements '}'                { $$ = $1;
 672                                                   $$->ref = $2;
 673                                                   $$->funcs = $4;
 674                                                   if (!parse_only && do_header) write_interface($$);
 675                                                 }
 676 /* MIDL is able to import the definition of a base class from inside the
 677  * definition of a derived class, I'll try to support it with this rule */
 678         | interfacehdr ':' aIDENTIFIER
 679           '{' import int_statements '}'         { $$ = $1;
 680                                                   $$->ref = find_type2($3, 0);
 681                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 682                                                   $$->funcs = $6;
 683                                                   if (!parse_only && do_header) write_interface($$);
 684                                                 }
 685         | dispinterfacedef                      { $$ = $1; }
 686         ;
 687
 688 interfacedec:
 689           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 690         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 691         ;
 692
 693 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 694         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 695         ;
 696
 697 modulehdr: attributes module                    { $$ = $2;
 698                                                   $$->attrs = $1;
 699                                                 }
 700         ;
 701
 702 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 703                                                   $$->funcs = $3;
 704                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 705                                                 }
 706         ;
 707
 708 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 709         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 710         ;
 711
 712 pident:   ident
 713         | p_ident
 714         | '(' pident ')'                        { $$ = $2; }
 715         ;
 716
 717 pident_list:
 718           pident
 719         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 720         ;
 721
 722 pointer_type:
 723           tREF                                  { $$ = RPC_FC_RP; }
 724         | tUNIQUE                               { $$ = RPC_FC_UP; }
 725         ;
 726
 727 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 728                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 729                                                   $$->type = get_struct_type( $4 );
 730                                                   $$->fields = $4;
 731                                                   $$->defined = TRUE;
 732                                                   if(in_typelib)
 733                                                     add_struct($$);
 734                                                 }
 735         ;
 736
 737 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 738         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 739         | base_type                             { $$ = make_tref(NULL, $1); }
 740         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 741         | enumdef                               { $$ = make_tref(NULL, $1); }
 742         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 743         | structdef                             { $$ = make_tref(NULL, $1); }
 744         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 745         | uniondef                              { $$ = make_tref(NULL, $1); }
 746         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 747         ;
 748
 749 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 750                                                   $4->tname = tref->name;
 751                                                   tref->name = NULL;
 752                                                   $$ = type_ref(tref);
 753                                                   $$->attrs = $2;
 754                                                   if (!parse_only && do_header)
 755                                                     write_typedef($$, $4);
 756                                                   if (in_typelib && $$->attrs)
 757                                                     add_typedef($$, $4);
 758                                                   reg_types($$, $4, 0);
 759                                                 }
 760         ;
 761
 762 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 763                                                   $$->fields = $4;
 764                                                   $$->defined = TRUE;
 765                                                 }
 766         | tUNION t_ident
 767           tSWITCH '(' s_field ')'
 768           m_ident '{' cases '}'                 { var_t *u = $7;
 769                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 770                                                   if (!u) u = make_var("tagged_union");
 771                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 772                                                   u->type->fields = $9;
 773                                                   u->type->defined = TRUE;
 774                                                   LINK(u, $5); $$->fields = u;
 775                                                   $$->defined = TRUE;
 776                                                 }
 777         ;
 778
 779 version:
 780           aNUM                                  { $$ = MAKELONG($1, 0); }
 781         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 782         ;
 783
 784 %%
 785
 786 static attr_t *make_attr(enum attr_type type)
 787 {
 788   attr_t *a = xmalloc(sizeof(attr_t));
 789   a->type = type;
 790   a->u.ival = 0;
 791   INIT_LINK(a);
 792   return a;
 793 }
 794
 795 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 796 {
 797   attr_t *a = xmalloc(sizeof(attr_t));
 798   a->type = type;
 799   a->u.ival = val;
 800   INIT_LINK(a);
 801   return a;
 802 }
 803
 804 static attr_t *make_attrp(enum attr_type type, void *val)
 805 {
 806   attr_t *a = xmalloc(sizeof(attr_t));
 807   a->type = type;
 808   a->u.pval = val;
 809   INIT_LINK(a);
 810   return a;
 811 }
 812
 813 static expr_t *make_expr(enum expr_type type)
 814 {
 815   expr_t *e = xmalloc(sizeof(expr_t));
 816   e->type = type;
 817   e->ref = NULL;
 818   e->u.lval = 0;
 819   e->is_const = FALSE;
 820   INIT_LINK(e);
 821   return e;
 822 }
 823
 824 static expr_t *make_exprl(enum expr_type type, long val)
 825 {
 826   expr_t *e = xmalloc(sizeof(expr_t));
 827   e->type = type;
 828   e->ref = NULL;
 829   e->u.lval = val;
 830   e->is_const = FALSE;
 831   INIT_LINK(e);
 832   /* check for numeric constant */
 833   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 834     e->is_const = TRUE;
 835     e->cval = val;
 836   }
 837   return e;
 838 }
 839
 840 static expr_t *make_exprs(enum expr_type type, char *val)
 841 {
 842   expr_t *e;
 843   e = xmalloc(sizeof(expr_t));
 844   e->type = type;
 845   e->ref = NULL;
 846   e->u.sval = val;
 847   e->is_const = FALSE;
 848   INIT_LINK(e);
 849   /* check for predefined constants */
 850   if (type == EXPR_IDENTIFIER) {
 851     var_t *c = find_const(val, 0);
 852     if (c) {
 853       e->u.sval = c->name;
 854       free(val);
 855       e->is_const = TRUE;
 856       e->cval = c->lval;
 857     }
 858   }
 859   return e;
 860 }
 861
 862 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 863 {
 864   expr_t *e;
 865   e = xmalloc(sizeof(expr_t));
 866   e->type = type;
 867   e->ref = expr;
 868   e->u.tref = tref;
 869   e->is_const = FALSE;
 870   INIT_LINK(e);
 871   /* check for cast of constant expression */
 872   if (type == EXPR_CAST && expr->is_const) {
 873     e->is_const = TRUE;
 874     e->cval = expr->cval;
 875   }
 876   return e;
 877 }
 878
 879 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 880 {
 881   expr_t *e;
 882   e = xmalloc(sizeof(expr_t));
 883   e->type = type;
 884   e->ref = expr;
 885   e->u.lval = 0;
 886   e->is_const = FALSE;
 887   INIT_LINK(e);
 888   /* check for compile-time optimization */
 889   if (expr->is_const) {
 890     e->is_const = TRUE;
 891     switch (type) {
 892     case EXPR_NEG:
 893       e->cval = -expr->cval;
 894       break;
 895     case EXPR_NOT:
 896       e->cval = ~expr->cval;
 897       break;
 898     default:
 899       e->is_const = FALSE;
 900       break;
 901     }
 902   }
 903   return e;
 904 }
 905
 906 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 907 {
 908   expr_t *e;
 909   e = xmalloc(sizeof(expr_t));
 910   e->type = type;
 911   e->ref = expr1;
 912   e->u.ext = expr2;
 913   e->is_const = FALSE;
 914   INIT_LINK(e);
 915   /* check for compile-time optimization */
 916   if (expr1->is_const && expr2->is_const) {
 917     e->is_const = TRUE;
 918     switch (type) {
 919     case EXPR_ADD:
 920       e->cval = expr1->cval + expr2->cval;
 921       break;
 922     case EXPR_SUB:
 923       e->cval = expr1->cval - expr2->cval;
 924       break;
 925     case EXPR_MUL:
 926       e->cval = expr1->cval * expr2->cval;
 927       break;
 928     case EXPR_DIV:
 929       e->cval = expr1->cval / expr2->cval;
 930       break;
 931     case EXPR_OR:
 932       e->cval = expr1->cval | expr2->cval;
 933       break;
 934     case EXPR_AND:
 935       e->cval = expr1->cval & expr2->cval;
 936       break;
 937     case EXPR_SHL:
 938       e->cval = expr1->cval << expr2->cval;
 939       break;
 940     case EXPR_SHR:
 941       e->cval = expr1->cval >> expr2->cval;
 942       break;
 943     default:
 944       e->is_const = FALSE;
 945       break;
 946     }
 947   }
 948   return e;
 949 }
 950
 951 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 952 {
 953   expr_t *e;
 954   e = xmalloc(sizeof(expr_t));
 955   e->type = type;
 956   e->ref = expr1;
 957   e->u.ext = expr2;
 958   e->ext2 = expr3;
 959   e->is_const = FALSE;
 960   INIT_LINK(e);
 961   /* check for compile-time optimization */
 962   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 963     e->is_const = TRUE;
 964     switch (type) {
 965     case EXPR_COND:
 966       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 967       break;
 968     default:
 969       e->is_const = FALSE;
 970       break;
 971     }
 972   }
 973   return e;
 974 }
 975
 976 static type_t *make_type(unsigned char type, type_t *ref)
 977 {
 978   type_t *t = xmalloc(sizeof(type_t));
 979   t->name = NULL;
 980   t->type = type;
 981   t->ref = ref;
 982   t->rname = NULL;
 983   t->attrs = NULL;
 984   t->funcs = NULL;
 985   t->fields = NULL;
 986   t->ignore = parse_only;
 987   t->is_const = FALSE;
 988   t->sign = 0;
 989   t->defined = FALSE;
 990   t->written = FALSE;
 991   t->typelib_idx = -1;
 992   INIT_LINK(t);
 993   return t;
 994 }
 995
 996 static typeref_t *make_tref(char *name, type_t *ref)
 997 {
 998   typeref_t *t = xmalloc(sizeof(typeref_t));
 999   t->name = name;
1000   t->ref = ref;
1001   t->uniq = ref ? 0 : 1;
1002   return t;
1003 }
1004
1005 static typeref_t *uniq_tref(typeref_t *ref)
1006 {
1007   typeref_t *t = ref;
1008   type_t *tp;
1009   if (t->uniq) return t;
1010   tp = make_type(0, t->ref);
1011   tp->name = t->name;
1012   t->name = NULL;
1013   t->ref = tp;
1014   t->uniq = 1;
1015   return t;
1016 }
1017
1018 static type_t *type_ref(typeref_t *ref)
1019 {
1020   type_t *t = ref->ref;
1021   if (ref->name) free(ref->name);
1022   free(ref);
1023   return t;
1024 }
1025
1026 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1027 {
1028   v->type = ref->ref;
1029   v->tname = ref->name;
1030   ref->name = NULL;
1031   free(ref);
1032   v->array = arr;
1033 }
1034
1035 static ifref_t *make_ifref(type_t *iface)
1036 {
1037   ifref_t *l = xmalloc(sizeof(ifref_t));
1038   l->iface = iface;
1039   l->attrs = NULL;
1040   INIT_LINK(l);
1041   return l;
1042 }
1043
1044 static var_t *make_var(char *name)
1045 {
1046   var_t *v = xmalloc(sizeof(var_t));
1047   v->name = name;
1048   v->ptr_level = 0;
1049   v->type = NULL;
1050   v->tname = NULL;
1051   v->attrs = NULL;
1052   v->array = NULL;
1053   v->eval = NULL;
1054   v->lval = 0;
1055   INIT_LINK(v);
1056   return v;
1057 }
1058
1059 static func_t *make_func(var_t *def, var_t *args)
1060 {
1061   func_t *f = xmalloc(sizeof(func_t));
1062   f->def = def;
1063   f->args = args;
1064   f->ignore = parse_only;
1065   f->idx = -1;
1066   INIT_LINK(f);
1067   return f;
1068 }
1069
1070 static class_t *make_class(char *name)
1071 {
1072   class_t *c = xmalloc(sizeof(class_t));
1073   c->name = name;
1074   c->attrs = NULL;
1075   c->ifaces = NULL;
1076   INIT_LINK(c);
1077   return c;
1078 }
1079
1080 #define HASHMAX 64
1081
1082 static int hash_ident(const char *name)
1083 {
1084   const char *p = name;
1085   int sum = 0;
1086   /* a simple sum hash is probably good enough */
1087   while (*p) {
1088     sum += *p;
1089     p++;
1090   }
1091   return sum & (HASHMAX-1);
1092 }
1093
1094 /***** type repository *****/
1095
1096 struct rtype {
1097   char *name;
1098   type_t *type;
1099   int t;
1100   struct rtype *next;
1101 };
1102
1103 struct rtype *type_hash[HASHMAX];
1104
1105 static type_t *reg_type(type_t *type, char *name, int t)
1106 {
1107   struct rtype *nt;
1108   int hash;
1109   if (!name) {
1110     yyerror("registering named type without name\n");
1111     return type;
1112   }
1113   hash = hash_ident(name);
1114   nt = xmalloc(sizeof(struct rtype));
1115   nt->name = name;
1116   nt->type = type;
1117   nt->t = t;
1118   nt->next = type_hash[hash];
1119   type_hash[hash] = nt;
1120   type->name = name;
1121   return type;
1122 }
1123
1124 /* determine pointer type from attrs */
1125 static unsigned char get_pointer_type( type_t *type )
1126 {
1127   int t;
1128   if (is_attr( type->attrs, ATTR_STRING ))
1129   {
1130     type_t *t = type;
1131     while( t->type == 0 && t->ref )
1132       t = t->ref;
1133     switch( t->type )
1134     {
1135     case RPC_FC_CHAR:
1136       return RPC_FC_C_CSTRING;
1137     case RPC_FC_WCHAR:
1138       return RPC_FC_C_WSTRING;
1139     }
1140   }
1141   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1142   if (t) return t;
1143
1144   if(is_attr( type->attrs, ATTR_PTR ))
1145     return RPC_FC_FP;
1146
1147   if(is_attr( type->attrs, ATTR_UNIQUE ))
1148     return RPC_FC_UP;
1149
1150   return RPC_FC_RP;
1151 }
1152
1153 static type_t *reg_types(type_t *type, var_t *names, int t)
1154 {
1155   type_t *ptr = type;
1156   int ptrc = 0;
1157
1158   while (names) {
1159     var_t *next = NEXT_LINK(names);
1160     if (names->name) {
1161       type_t *cur = ptr;
1162       int cptr = names->ptr_level;
1163       if (cptr > ptrc) {
1164         while (cptr > ptrc) {
1165           int t = get_pointer_type( cur );
1166           cur = ptr = make_type(t, cur);
1167           ptrc++;
1168         }
1169       } else {
1170         while (cptr < ptrc) {
1171           cur = cur->ref;
1172           cptr++;
1173         }
1174       }
1175       reg_type(cur, names->name, t);
1176     }
1177     free(names);
1178     names = next;
1179   }
1180   return type;
1181 }
1182
1183 static type_t *find_type(char *name, int t)
1184 {
1185   struct rtype *cur = type_hash[hash_ident(name)];
1186   while (cur && (cur->t != t || strcmp(cur->name, name)))
1187     cur = cur->next;
1188   if (!cur) {
1189     yyerror("type %s not found\n", name);
1190     return NULL;
1191   }
1192   return cur->type;
1193 }
1194
1195 static type_t *find_type2(char *name, int t)
1196 {
1197   type_t *tp = find_type(name, t);
1198   free(name);
1199   return tp;
1200 }
1201
1202 int is_type(const char *name)
1203 {
1204   struct rtype *cur = type_hash[hash_ident(name)];
1205   while (cur && (cur->t || strcmp(cur->name, name)))
1206     cur = cur->next;
1207   if (cur) return TRUE;
1208   return FALSE;
1209 }
1210
1211 static type_t *get_type(unsigned char type, char *name, int t)
1212 {
1213   struct rtype *cur = NULL;
1214   type_t *tp;
1215   if (name) {
1216     cur = type_hash[hash_ident(name)];
1217     while (cur && (cur->t != t || strcmp(cur->name, name)))
1218       cur = cur->next;
1219   }
1220   if (cur) {
1221     free(name);
1222     return cur->type;
1223   }
1224   tp = make_type(type, NULL);
1225   tp->name = name;
1226   if (!name) return tp;
1227   return reg_type(tp, name, t);
1228 }
1229
1230 static type_t *get_typev(unsigned char type, var_t *name, int t)
1231 {
1232   char *sname = NULL;
1233   if (name) {
1234     sname = name->name;
1235     free(name);
1236   }
1237   return get_type(type, sname, t);
1238 }
1239
1240 static int get_struct_type(var_t *field)
1241 {
1242   int has_pointer = 0;
1243   int has_conformant_array = 0;
1244   int has_conformant_string = 0;
1245
1246   while (field)
1247   {
1248     type_t *t = field->type;
1249
1250     /* get the base type */
1251     while( (t->type == 0) && t->ref )
1252       t = t->ref;
1253
1254     switch (t->type)
1255     {
1256     /*
1257      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1258      *  Simple types don't effect the type of struct.
1259      *  A struct containing a simple struct is still a simple struct.
1260      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1261      */
1262     case 0: /* void pointer */
1263     case RPC_FC_BYTE:
1264     case RPC_FC_CHAR:
1265     case RPC_FC_SMALL:
1266     case RPC_FC_USMALL:
1267     case RPC_FC_WCHAR:
1268     case RPC_FC_SHORT:
1269     case RPC_FC_USHORT:
1270     case RPC_FC_LONG:
1271     case RPC_FC_ULONG:
1272     case RPC_FC_INT3264:
1273     case RPC_FC_UINT3264:
1274     case RPC_FC_HYPER:
1275     case RPC_FC_FLOAT:
1276     case RPC_FC_DOUBLE:
1277     case RPC_FC_STRUCT:
1278     case RPC_FC_ENUM16:
1279     case RPC_FC_ENUM32:
1280       break;
1281
1282     case RPC_FC_UP:
1283     case RPC_FC_FP:
1284       has_pointer = 1;
1285       break;
1286     case RPC_FC_CARRAY:
1287       has_conformant_array = 1;
1288       break;
1289     case RPC_FC_C_CSTRING:
1290     case RPC_FC_C_WSTRING:
1291       has_conformant_string = 1;
1292       break;
1293
1294     /*
1295      * Propagate member attributes
1296      *  a struct should be at least as complex as its member
1297      */
1298     case RPC_FC_CVSTRUCT:
1299       has_conformant_string = 1;
1300       has_pointer = 1;
1301       break;
1302
1303     case RPC_FC_CPSTRUCT:
1304       has_conformant_array = 1;
1305       has_pointer = 1;
1306       break;
1307
1308     case RPC_FC_CSTRUCT:
1309       has_conformant_array = 1;
1310       break;
1311
1312     case RPC_FC_PSTRUCT:
1313       has_pointer = 1;
1314       break;
1315
1316     default:
1317       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1318               field->name, t->type);
1319       /* fallthru - treat it as complex */
1320
1321     /* as soon as we see one of these these members, it's bogus... */
1322     case RPC_FC_IP:
1323     case RPC_FC_ENCAPSULATED_UNION:
1324     case RPC_FC_NON_ENCAPSULATED_UNION:
1325     case RPC_FC_TRANSMIT_AS:
1326     case RPC_FC_REPRESENT_AS:
1327     case RPC_FC_PAD:
1328     case RPC_FC_EMBEDDED_COMPLEX:
1329     case RPC_FC_BOGUS_STRUCT:
1330       return RPC_FC_BOGUS_STRUCT;
1331     }
1332     field = NEXT_LINK(field);
1333   }
1334
1335   if( has_conformant_string && has_pointer )
1336     return RPC_FC_CVSTRUCT;
1337   if( has_conformant_array && has_pointer )
1338     return RPC_FC_CPSTRUCT;
1339   if( has_conformant_array )
1340     return RPC_FC_CSTRUCT;
1341   if( has_pointer )
1342     return RPC_FC_PSTRUCT;
1343   return RPC_FC_STRUCT;
1344 }
1345
1346 /***** constant repository *****/
1347
1348 struct rconst {
1349   char *name;
1350   var_t *var;
1351   struct rconst *next;
1352 };
1353
1354 struct rconst *const_hash[HASHMAX];
1355
1356 static var_t *reg_const(var_t *var)
1357 {
1358   struct rconst *nc;
1359   int hash;
1360   if (!var->name) {
1361     yyerror("registering constant without name\n");
1362     return var;
1363   }
1364   hash = hash_ident(var->name);
1365   nc = xmalloc(sizeof(struct rconst));
1366   nc->name = var->name;
1367   nc->var = var;
1368   nc->next = const_hash[hash];
1369   const_hash[hash] = nc;
1370   return var;
1371 }
1372
1373 static var_t *find_const(char *name, int f)
1374 {
1375   struct rconst *cur = const_hash[hash_ident(name)];
1376   while (cur && strcmp(cur->name, name))
1377     cur = cur->next;
1378   if (!cur) {
1379     if (f) yyerror("constant %s not found\n", name);
1380     return NULL;
1381   }
1382   return cur->var;
1383 }