projects / reactos.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Import Wine Resource Compiler and use it for winedll's
[reactos.git] / reactos / tools / wrc / parser.y
1 %{
2 /*
3 * Copyright 1994 Martin von Loewis
4 * Copyright 1998-2000 Bertho A. Stultiens (BS)
5 * 1999 Juergen Schmied (JS)
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
20 *
21 * History:
22 * 24-Jul-2000 BS - Made a fix for broken Berkeley yacc on
23 * non-terminals (see cjunk rule).
24 * 21-May-2000 BS - Partial implementation of font resources.
25 * - Corrected language propagation for binary
26 * resources such as bitmaps, icons, cursors,
27 * userres and rcdata. The language is now
28 * correct in .res files.
29 * - Fixed reading the resource name as ident,
30 * so that it may overlap keywords.
31 * 20-May-2000 BS - Implemented animated cursors and icons
32 * resource types.
33 * 30-Apr-2000 BS - Reintegration into the wine-tree
34 * 14-Jan-2000 BS - Redid the usertype resources so that they
35 * are compatible.
36 * 02-Jan-2000 BS - Removed the preprocessor from the grammar
37 * except for the # command (line numbers).
38 *
39 * 06-Nov-1999 JS - see CHANGES
40 *
41 * 29-Dec-1998 AdH - Grammar and function extensions.
42 * grammar: TOOLBAR resources, Named ICONs in
43 * DIALOGS
44 * functions: semantic actions for the grammar
45 * changes, resource files can now be anywhere
46 * on the include path instead of just in the
47 * current directory
48 *
49 * 20-Jun-1998 BS - Fixed a bug in load_file() where the name was not
50 * printed out correctly.
51 *
52 * 17-Jun-1998 BS - Fixed a bug in CLASS statement parsing which should
53 * also accept a tSTRING as argument.
54 *
55 * 25-May-1998 BS - Found out that I need to support language, version
56 * and characteristics in inline resources (bitmap,
57 * cursor, etc) but they can also be specified with
58 * a filename. This renders my filename-scanning scheme
59 * worthless. Need to build newline parsing to solve
60 * this one.
61 * It will come with version 1.1.0 (sigh).
62 *
63 * 19-May-1998 BS - Started to build a builtin preprocessor
64 *
65 * 30-Apr-1998 BS - Redid the stringtable parsing/handling. My previous
66 * ideas had some serious flaws.
67 *
68 * 27-Apr-1998 BS - Removed a lot of dead comments and put it in a doc
69 * file.
70 *
71 * 21-Apr-1998 BS - Added correct behavior for cursors and icons.
72 * - This file is growing too big. It is time to strip
73 * things and put it in a support file.
74 *
75 * 19-Apr-1998 BS - Tagged the stringtable resource so that only one
76 * resource will be created. This because the table
77 * has a different layout than other resources. The
78 * table has to be sorted, and divided into smaller
79 * resource entries (see comment in source).
80 *
81 * 17-Apr-1998 BS - Almost all strings, including identifiers, are parsed
82 * as string_t which include unicode strings upon
83 * input.
84 * - Parser now emits a warning when compiling win32
85 * extensions in win16 mode.
86 *
87 * 16-Apr-1998 BS - Raw data elements are now *optionally* separated
88 * by commas. Read the comments in file sq2dq.l.
89 * - FIXME: there are instances in the source that rely
90 * on the fact that int==32bit and pointers are int size.
91 * - Fixed the conflict in menuex by changing a rule
92 * back into right recursion. See note in source.
93 * - UserType resources cannot have an expression as its
94 * typeclass. See note in source.
95 *
96 * 15-Apr-1998 BS - Changed all right recursion into left recursion to
97 * get reduction of the parsestack.
98 * This also helps communication between bison and flex.
99 * Main advantage is that the Empty rule gets reduced
100 * first, which is used to allocate/link things.
101 * It also added a shift/reduce conflict in the menuex
102 * handling, due to expression/option possibility,
103 * although not serious.
104 *
105 * 14-Apr-1998 BS - Redone almost the entire parser. We're not talking
106 * about making it more efficient, but readable (for me)
107 * and slightly easier to expand/change.
108 * This is done primarily by using more reduce states
109 * with many (intuitive) types for the various resource
110 * statements.
111 * - Added expression handling for all resources where a
112 * number is accepted (not only for win32). Also added
113 * multiply and division (not MS compatible, but handy).
114 * Unary minus introduced a shift/reduce conflict, but
115 * it is not serious.
116 *
117 * 13-Apr-1998 BS - Reordered a lot of things
118 * - Made the source more readable
119 * - Added Win32 resource definitions
120 * - Corrected syntax problems with an old yacc (;)
121 * - Added extra comment about grammar
122 */
123 #include "config.h"
124
125 #include <stdio.h>
126 #include <stdlib.h>
127 #include <stdarg.h>
128 #include <assert.h>
129 #include <ctype.h>
130 #include <string.h>
131 #ifdef HAVE_ALLOCA_H
132 #include <alloca.h>
133 #endif
134
135 #include "wrc.h"
136 #include "utils.h"
137 #include "newstruc.h"
138 #include "dumpres.h"
139 #include "wine/wpp.h"
140 #include "wine/unicode.h"
141 #include "parser.h"
142 #include "windef.h"
143 #include "winbase.h"
144 #include "wingdi.h"
145 #include "winuser.h"
146
147 #if defined(YYBYACC)
148 /* Berkeley yacc (byacc) doesn't seem to know about these */
149 /* Some *BSD supplied versions do define these though */
150 # ifndef YYEMPTY
151 # define YYEMPTY (-1) /* Empty lookahead value of yychar */
152 # endif
153 # ifndef YYLEX
154 # define YYLEX yylex()
155 # endif
156
157 #elif defined(YYBISON)
158 /* Bison was used for original development */
159 /* #define YYEMPTY -2 */
160 /* #define YYLEX yylex() */
161
162 #else
163 /* No yacc we know yet */
164 # if !defined(YYEMPTY) || !defined(YYLEX)
165 # error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
166 # elif defined(__GNUC__) /* gcc defines the #warning directive */
167 # warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
168 /* #else we just take a chance that it works... */
169 # endif
170 #endif
171
172 int want_nl = 0; /* Signal flex that we need the next newline */
173 int want_id = 0; /* Signal flex that we need the next identifier */
174 stringtable_t *tagstt; /* Stringtable tag.
175 * It is set while parsing a stringtable to one of
176 * the stringtables in the sttres list or a new one
177 * if the language was not parsed before.
178 */
179 stringtable_t *sttres; /* Stringtable resources. This holds the list of
180 * stringtables with different lanuages
181 */
182 static int dont_want_id = 0; /* See language parsing for details */
183
184 /* Set to the current options of the currently scanning stringtable */
185 static int *tagstt_memopt;
186 static characts_t *tagstt_characts;
187 static version_t *tagstt_version;
188
189 static const char riff[4] = "RIFF"; /* RIFF file magic for animated cursor/icon */
190
191 /* Prototypes of here defined functions */
192 static event_t *get_event_head(event_t *p);
193 static control_t *get_control_head(control_t *p);
194 static ver_value_t *get_ver_value_head(ver_value_t *p);
195 static ver_block_t *get_ver_block_head(ver_block_t *p);
196 static resource_t *get_resource_head(resource_t *p);
197 static menuex_item_t *get_itemex_head(menuex_item_t *p);
198 static menu_item_t *get_item_head(menu_item_t *p);
199 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str);
200 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i);
201 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i);
202 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2);
203 static raw_data_t *str2raw_data(string_t *str);
204 static raw_data_t *int2raw_data(int i);
205 static raw_data_t *long2raw_data(int i);
206 static raw_data_t *load_file(string_t *name, language_t *lang);
207 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid);
208 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev);
209 static event_t *add_event(int key, int id, int flags, event_t *prev);
210 static dialogex_t *dialogex_version(version_t *v, dialogex_t *dlg);
211 static dialogex_t *dialogex_characteristics(characts_t *c, dialogex_t *dlg);
212 static dialogex_t *dialogex_language(language_t *l, dialogex_t *dlg);
213 static dialogex_t *dialogex_menu(name_id_t *m, dialogex_t *dlg);
214 static dialogex_t *dialogex_class(name_id_t *n, dialogex_t *dlg);
215 static dialogex_t *dialogex_font(font_id_t *f, dialogex_t *dlg);
216 static dialogex_t *dialogex_caption(string_t *s, dialogex_t *dlg);
217 static dialogex_t *dialogex_exstyle(style_t *st, dialogex_t *dlg);
218 static dialogex_t *dialogex_style(style_t *st, dialogex_t *dlg);
219 static name_id_t *convert_ctlclass(name_id_t *cls);
220 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev);
221 static dialog_t *dialog_version(version_t *v, dialog_t *dlg);
222 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg);
223 static dialog_t *dialog_language(language_t *l, dialog_t *dlg);
224 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg);
225 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg);
226 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg);
227 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg);
228 static dialog_t *dialog_exstyle(style_t * st, dialog_t *dlg);
229 static dialog_t *dialog_style(style_t * st, dialog_t *dlg);
230 static resource_t *build_stt_resources(stringtable_t *stthead);
231 static stringtable_t *find_stringtable(lvc_t *lvc);
232 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec);
233 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems);
234 static string_t *make_filename(string_t *s);
235 static resource_t *build_fontdirs(resource_t *tail);
236 static resource_t *build_fontdir(resource_t **fnt, int nfnt);
237 static int rsrcid_to_token(int lookahead);
238
239 %}
240 %union{
241 string_t *str;
242 int num;
243 int *iptr;
244 char *cptr;
245 resource_t *res;
246 accelerator_t *acc;
247 bitmap_t *bmp;
248 dialog_t *dlg;
249 dialogex_t *dlgex;
250 font_t *fnt;
251 fontdir_t *fnd;
252 menu_t *men;
253 menuex_t *menex;
254 rcdata_t *rdt;
255 stringtable_t *stt;
256 stt_entry_t *stte;
257 user_t *usr;
258 messagetable_t *msg;
259 versioninfo_t *veri;
260 control_t *ctl;
261 name_id_t *nid;
262 font_id_t *fntid;
263 language_t *lan;
264 version_t *ver;
265 characts_t *chars;
266 event_t *event;
267 menu_item_t *menitm;
268 menuex_item_t *menexitm;
269 itemex_opt_t *exopt;
270 raw_data_t *raw;
271 lvc_t *lvc;
272 ver_value_t *val;
273 ver_block_t *blk;
274 ver_words_t *verw;
275 toolbar_t *tlbar;
276 toolbar_item_t *tlbarItems;
277 dlginit_t *dginit;
278 style_pair_t *styles;
279 style_t *style;
280 ani_any_t *ani;
281 }
282
283 %token tNL
284 %token <num> tNUMBER tLNUMBER
285 %token <str> tSTRING tIDENT tFILENAME
286 %token <raw> tRAWDATA
287 %token tACCELERATORS tBITMAP tCURSOR tDIALOG tDIALOGEX tMENU tMENUEX tMESSAGETABLE
288 %token tRCDATA tVERSIONINFO tSTRINGTABLE tFONT tFONTDIR tICON
289 %token tAUTO3STATE tAUTOCHECKBOX tAUTORADIOBUTTON tCHECKBOX tDEFPUSHBUTTON
290 %token tPUSHBUTTON tRADIOBUTTON tSTATE3 /* PUSHBOX */
291 %token tGROUPBOX tCOMBOBOX tLISTBOX tSCROLLBAR
292 %token tCONTROL tEDITTEXT
293 %token tRTEXT tCTEXT tLTEXT
294 %token tBLOCK tVALUE
295 %token tSHIFT tALT tASCII tVIRTKEY tGRAYED tCHECKED tINACTIVE tNOINVERT
296 %token tPURE tIMPURE tDISCARDABLE tLOADONCALL tPRELOAD tFIXED tMOVEABLE
297 %token tCLASS tCAPTION tCHARACTERISTICS tEXSTYLE tSTYLE tVERSION tLANGUAGE
298 %token tFILEVERSION tPRODUCTVERSION tFILEFLAGSMASK tFILEOS tFILETYPE tFILEFLAGS tFILESUBTYPE
299 %token tMENUBARBREAK tMENUBREAK tMENUITEM tPOPUP tSEPARATOR
300 %token tHELP
301 %token tSTRING tIDENT tRAWDATA
302 %token tTOOLBAR tBUTTON
303 %token tBEGIN tEND
304 %token tDLGINIT
305 %left '|'
306 %left '^'
307 %left '&'
308 %left '+' '-'
309 %left '*' '/'
310 %right '~' tNOT
311 %left pUPM
312
313 %type <res> resource_file resource resources resource_definition
314 %type <stt> stringtable strings
315 %type <fnt> font
316 %type <fnd> fontdir
317 %type <acc> accelerators
318 %type <event> events
319 %type <bmp> bitmap
320 %type <ani> cursor icon
321 %type <dlg> dialog dlg_attributes
322 %type <ctl> ctrls gen_ctrl lab_ctrl ctrl_desc iconinfo
323 %type <iptr> helpid
324 %type <dlgex> dialogex dlgex_attribs
325 %type <ctl> exctrls gen_exctrl lab_exctrl exctrl_desc
326 %type <rdt> rcdata
327 %type <raw> raw_data raw_elements opt_data file_raw
328 %type <veri> versioninfo fix_version
329 %type <verw> ver_words
330 %type <blk> ver_blocks ver_block
331 %type <val> ver_values ver_value
332 %type <men> menu
333 %type <menitm> item_definitions menu_body
334 %type <menex> menuex
335 %type <menexitm> itemex_definitions menuex_body
336 %type <exopt> itemex_p_options itemex_options
337 %type <msg> messagetable
338 %type <usr> userres
339 %type <num> item_options
340 %type <nid> nameid nameid_s ctlclass usertype
341 %type <num> acc_opt acc accs
342 %type <iptr> loadmemopts lamo lama
343 %type <fntid> opt_font opt_exfont opt_expr
344 %type <lvc> opt_lvc
345 %type <lan> opt_language
346 %type <chars> opt_characts
347 %type <ver> opt_version
348 %type <num> expr xpr
349 %type <iptr> e_expr
350 %type <tlbar> toolbar
351 %type <tlbarItems> toolbar_items
352 %type <dginit> dlginit
353 %type <styles> optional_style_pair
354 %type <num> any_num
355 %type <style> optional_style
356 %type <style> style
357 %type <str> filename
358
359 %%
360
361 resource_file
362 : resources {
363 resource_t *rsc;
364 /* First add stringtables to the resource-list */
365 rsc = build_stt_resources(sttres);
366 /* 'build_stt_resources' returns a head and $1 is a tail */
367 if($1)
368 {
369 $1->next = rsc;
370 if(rsc)
371 rsc->prev = $1;
372 }
373 else
374 $1 = rsc;
375 /* Find the tail again */
376 while($1 && $1->next)
377 $1 = $1->next;
378 /* Now add any fontdirecory */
379 rsc = build_fontdirs($1);
380 /* 'build_fontdir' returns a head and $1 is a tail */
381 if($1)
382 {
383 $1->next = rsc;
384 if(rsc)
385 rsc->prev = $1;
386 }
387 else
388 $1 = rsc;
389 /* Final statement before were done */
390 resource_top = get_resource_head($1);
391 }
392 ;
393
394 /* Resources are put into a linked list */
395 resources
396 : /* Empty */ { $$ = NULL; want_id = 1; }
397 | resources resource {
398 if($2)
399 {
400 resource_t *tail = $2;
401 resource_t *head = $2;
402 while(tail->next)
403 tail = tail->next;
404 while(head->prev)
405 head = head->prev;
406 head->prev = $1;
407 if($1)
408 $1->next = head;
409 $$ = tail;
410 /* Check for duplicate identifiers */
411 while($1 && head)
412 {
413 resource_t *rsc = $1;
414 while(rsc)
415 {
416 if(rsc->type == head->type
417 && rsc->lan->id == head->lan->id
418 && rsc->lan->sub == head->lan->sub
419 && !compare_name_id(rsc->name, head->name))
420 {
421 yyerror("Duplicate resource name '%s'", get_nameid_str(rsc->name));
422 }
423 rsc = rsc->prev;
424 }
425 head = head->next;
426 }
427 }
428 else if($1)
429 {
430 resource_t *tail = $1;
431 while(tail->next)
432 tail = tail->next;
433 $$ = tail;
434 }
435 else
436 $$ = NULL;
437
438 if(!dont_want_id) /* See comments in language parsing below */
439 want_id = 1;
440 dont_want_id = 0;
441 }
442 /*
443 * The following newline rule will never get reduced because we never
444 * get the tNL token, unless we explicitely set the 'want_nl'
445 * flag, which we don't.
446 * The *ONLY* reason for this to be here is because Berkeley
447 * yacc (byacc), at least version 1.9, has a bug.
448 * (identified in the generated parser on the second
449 * line with:
450 * static char yysccsid[] = "@(#)yaccpar 1.9 (Berkeley) 02/21/93";
451 * )
452 * This extra rule fixes it.
453 * The problem is that the expression handling rule "expr: xpr"
454 * is not reduced on non-terminal tokens, defined above in the
455 * %token declarations. Token tNL is the only non-terminal that
456 * can occur. The error becomes visible in the language parsing
457 * rule below, which looks at the look-ahead token and tests it
458 * for tNL. However, byacc already generates an error upon reading
459 * the token instead of keeping it as a lookahead. The reason
460 * lies in the lack of a $default transition in the "expr : xpr . "
461 * state (currently state 25). It is probably ommitted because tNL
462 * is a non-terminal and the state contains 2 s/r conflicts. The
463 * state enumerates all possible transitions instead of using a
464 * $default transition.
465 * All in all, it is a bug in byacc. (period)
466 */
467 | resources tNL
468 ;
469
470
471 /* Parse top level resource definitions etc. */
472 resource
473 : expr usrcvt resource_definition {
474 $$ = $3;
475 if($$)
476 {
477 if($1 > 65535 || $1 < -32768)
478 yyerror("Resource's ID out of range (%d)", $1);
479 $$->name = new_name_id();
480 $$->name->type = name_ord;
481 $$->name->name.i_name = $1;
482 chat("Got %s (%d)", get_typename($3), $$->name->name.i_name);
483 }
484 }
485 | tIDENT usrcvt resource_definition {
486 $$ = $3;
487 if($$)
488 {
489 $$->name = new_name_id();
490 $$->name->type = name_str;
491 $$->name->name.s_name = $1;
492 chat("Got %s (%s)", get_typename($3), $$->name->name.s_name->str.cstr);
493 }
494 }
495 | stringtable {
496 /* Don't do anything, stringtables are converted to
497 * resource_t structures when we are finished parsing and
498 * the final rule of the parser is reduced (see above)
499 */
500 $$ = NULL;
501 chat("Got STRINGTABLE");
502 }
503 | tLANGUAGE {want_nl = 1; } expr ',' expr {
504 /* We *NEED* the newline to delimit the expression.
505 * Otherwise, we would not be able to set the next
506 * want_id anymore because of the token-lookahead.
507 *
508 * However, we can test the lookahead-token for
509 * being "non-expression" type, in which case we
510 * continue. Fortunately, tNL is the only token that
511 * will break expression parsing and is implicitely
512 * void, so we just remove it. This scheme makes it
513 * possible to do some (not all) fancy preprocessor
514 * stuff.
515 * BTW, we also need to make sure that the next
516 * reduction of 'resources' above will *not* set
517 * want_id because we already have a lookahead that
518 * cannot be undone.
519 */
520 if(yychar != YYEMPTY && yychar != tNL)
521 dont_want_id = 1;
522
523 if(yychar == tNL)
524 yychar = YYEMPTY; /* Could use 'yyclearin', but we already need the*/
525 /* direct access to yychar in rule 'usrcvt' below. */
526 else if(yychar == tIDENT)
527 yywarning("LANGUAGE statement not delimited with newline; next identifier might be wrong");
528
529 want_nl = 0; /* We don't want it anymore if we didn't get it */
530
531 if(!win32)
532 yywarning("LANGUAGE not supported in 16-bit mode");
533 if(currentlanguage)
534 free(currentlanguage);
535 if (get_language_codepage($3, $5) == -1)
536 yyerror( "Language %04x is not supported", ($5<<10) + $3);
537 currentlanguage = new_language($3, $5);
538 $$ = NULL;
539 chat("Got LANGUAGE %d,%d (0x%04x)", $3, $5, ($5<<10) + $3);
540 }
541 ;
542
543 /*
544 * Remapping of numerical resource types
545 * (see also comment of called function below)
546 */
547 usrcvt : /* Empty */ { yychar = rsrcid_to_token(yychar); }
548 ;
549
550 /*
551 * Get a valid name/id
552 */
553 nameid : expr {
554 if($1 > 65535 || $1 < -32768)
555 yyerror("Resource's ID out of range (%d)", $1);
556 $$ = new_name_id();
557 $$->type = name_ord;
558 $$->name.i_name = $1;
559 }
560 | tIDENT {
561 $$ = new_name_id();
562 $$->type = name_str;
563 $$->name.s_name = $1;
564 }
565 ;
566
567 /*
568 * Extra string recognition for CLASS statement in dialogs
569 */
570 nameid_s: nameid { $$ = $1; }
571 | tSTRING {
572 $$ = new_name_id();
573 $$->type = name_str;
574 $$->name.s_name = $1;
575 }
576 ;
577
578 /* get the value for a single resource*/
579 resource_definition
580 : accelerators { $$ = new_resource(res_acc, $1, $1->memopt, $1->lvc.language); }
581 | bitmap { $$ = new_resource(res_bmp, $1, $1->memopt, $1->data->lvc.language); }
582 | cursor {
583 resource_t *rsc;
584 if($1->type == res_anicur)
585 {
586 $$ = rsc = new_resource(res_anicur, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
587 }
588 else if($1->type == res_curg)
589 {
590 cursor_t *cur;
591 $$ = rsc = new_resource(res_curg, $1->u.curg, $1->u.curg->memopt, $1->u.curg->lvc.language);
592 for(cur = $1->u.curg->cursorlist; cur; cur = cur->next)
593 {
594 rsc->prev = new_resource(res_cur, cur, $1->u.curg->memopt, $1->u.curg->lvc.language);
595 rsc->prev->next = rsc;
596 rsc = rsc->prev;
597 rsc->name = new_name_id();
598 rsc->name->type = name_ord;
599 rsc->name->name.i_name = cur->id;
600 }
601 }
602 else
603 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in cursor resource", $1->type);
604 free($1);
605 }
606 | dialog { $$ = new_resource(res_dlg, $1, $1->memopt, $1->lvc.language); }
607 | dialogex {
608 if(win32)
609 $$ = new_resource(res_dlgex, $1, $1->memopt, $1->lvc.language);
610 else
611 $$ = NULL;
612 }
613 | dlginit { $$ = new_resource(res_dlginit, $1, $1->memopt, $1->data->lvc.language); }
614 | font { $$ = new_resource(res_fnt, $1, $1->memopt, $1->data->lvc.language); }
615 | fontdir { $$ = new_resource(res_fntdir, $1, $1->memopt, $1->data->lvc.language); }
616 | icon {
617 resource_t *rsc;
618 if($1->type == res_aniico)
619 {
620 $$ = rsc = new_resource(res_aniico, $1->u.ani, $1->u.ani->memopt, $1->u.ani->data->lvc.language);
621 }
622 else if($1->type == res_icog)
623 {
624 icon_t *ico;
625 $$ = rsc = new_resource(res_icog, $1->u.icog, $1->u.icog->memopt, $1->u.icog->lvc.language);
626 for(ico = $1->u.icog->iconlist; ico; ico = ico->next)
627 {
628 rsc->prev = new_resource(res_ico, ico, $1->u.icog->memopt, $1->u.icog->lvc.language);
629 rsc->prev->next = rsc;
630 rsc = rsc->prev;
631 rsc->name = new_name_id();
632 rsc->name->type = name_ord;
633 rsc->name->name.i_name = ico->id;
634 }
635 }
636 else
637 internal_error(__FILE__, __LINE__, "Invalid top-level type %d in icon resource", $1->type);
638 free($1);
639 }
640 | menu { $$ = new_resource(res_men, $1, $1->memopt, $1->lvc.language); }
641 | menuex {
642 if(win32)
643 $$ = new_resource(res_menex, $1, $1->memopt, $1->lvc.language);
644 else
645 $$ = NULL;
646 }
647 | messagetable { $$ = new_resource(res_msg, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->data->lvc.language); }
648 | rcdata { $$ = new_resource(res_rdt, $1, $1->memopt, $1->data->lvc.language); }
649 | toolbar { $$ = new_resource(res_toolbar, $1, $1->memopt, $1->lvc.language); }
650 | userres { $$ = new_resource(res_usr, $1, $1->memopt, $1->data->lvc.language); }
651 | versioninfo { $$ = new_resource(res_ver, $1, WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE, $1->lvc.language); }
652 ;
653
654
655 filename: tFILENAME { $$ = make_filename($1); }
656 | tIDENT { $$ = make_filename($1); }
657 | tSTRING { $$ = make_filename($1); }
658 ;
659
660 /* ------------------------------ Bitmap ------------------------------ */
661 bitmap : tBITMAP loadmemopts file_raw { $$ = new_bitmap($3, $2); }
662 ;
663
664 /* ------------------------------ Cursor ------------------------------ */
665 cursor : tCURSOR loadmemopts file_raw {
666 $$ = new_ani_any();
667 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
668 {
669 $$->type = res_anicur;
670 $$->u.ani = new_ani_curico(res_anicur, $3, $2);
671 }
672 else
673 {
674 $$->type = res_curg;
675 $$->u.curg = new_cursor_group($3, $2);
676 }
677 }
678 ;
679
680 /* ------------------------------ Icon ------------------------------ */
681 icon : tICON loadmemopts file_raw {
682 $$ = new_ani_any();
683 if($3->size > 4 && !memcmp($3->data, riff, sizeof(riff)))
684 {
685 $$->type = res_aniico;
686 $$->u.ani = new_ani_curico(res_aniico, $3, $2);
687 }
688 else
689 {
690 $$->type = res_icog;
691 $$->u.icog = new_icon_group($3, $2);
692 }
693 }
694 ;
695
696 /* ------------------------------ Font ------------------------------ */
697 /*
698 * The reading of raw_data for fonts is a Borland BRC
699 * extension. MS generates an error. However, it is
700 * most logical to support this, considering how wine
701 * enters things in CVS (ascii).
702 */
703 font : tFONT loadmemopts file_raw { $$ = new_font($3, $2); }
704 ;
705
706 /*
707 * The fontdir is a Borland BRC extension which only
708 * reads the data as 'raw_data' from the file.
709 * I don't know whether it is interpreted.
710 * The fontdir is generated if it was not present and
711 * fonts are defined in the source.
712 */
713 fontdir : tFONTDIR loadmemopts file_raw { $$ = new_fontdir($3, $2); }
714 ;
715
716 /* ------------------------------ MessageTable ------------------------------ */
717 /* It might be interesting to implement the MS Message compiler here as well
718 * to get everything in one source. Might be a future project.
719 */
720 messagetable
721 : tMESSAGETABLE loadmemopts file_raw {
722 if(!win32)
723 yywarning("MESSAGETABLE not supported in 16-bit mode");
724 $$ = new_messagetable($3, $2);
725 }
726 ;
727
728 /* ------------------------------ RCData ------------------------------ */
729 rcdata : tRCDATA loadmemopts file_raw { $$ = new_rcdata($3, $2); }
730 ;
731
732 /* ------------------------------ DLGINIT ------------------------------ */
733 dlginit : tDLGINIT loadmemopts file_raw { $$ = new_dlginit($3, $2); }
734 ;
735
736 /* ------------------------------ UserType ------------------------------ */
737 userres : usertype loadmemopts file_raw {
738 #ifdef WORDS_BIGENDIAN
739 if(pedantic && byteorder != WRC_BO_LITTLE)
740 #else
741 if(pedantic && byteorder == WRC_BO_BIG)
742 #endif
743 yywarning("Byteordering is not little-endian and type cannot be interpreted");
744 $$ = new_user($1, $3, $2);
745 }
746 ;
747
748 usertype: tNUMBER {
749 $$ = new_name_id();
750 $$->type = name_ord;
751 $$->name.i_name = $1;
752 }
753 | tIDENT {
754 $$ = new_name_id();
755 $$->type = name_str;
756 $$->name.s_name = $1;
757 }
758 ;
759
760 /* ------------------------------ Accelerator ------------------------------ */
761 accelerators
762 : tACCELERATORS loadmemopts opt_lvc tBEGIN events tEND {
763 $$ = new_accelerator();
764 if($2)
765 {
766 $$->memopt = *($2);
767 free($2);
768 }
769 else
770 {
771 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
772 }
773 if(!$5)
774 yyerror("Accelerator table must have at least one entry");
775 $$->events = get_event_head($5);
776 if($3)
777 {
778 $$->lvc = *($3);
779 free($3);
780 }
781 if(!$$->lvc.language)
782 $$->lvc.language = dup_language(currentlanguage);
783 }
784 ;
785
786 events : /* Empty */ { $$=NULL; }
787 | events tSTRING ',' expr acc_opt { $$=add_string_event($2, $4, $5, $1); }
788 | events expr ',' expr acc_opt { $$=add_event($2, $4, $5, $1); }
789 ;
790
791 /*
792 * The empty rule generates a s/r conflict because of {bi,u}nary expr
793 * on - and +. It cannot be solved in any way because it is the same as
794 * the if/then/else problem (LALR(1) problem). The conflict is moved
795 * away by forcing it to be in the expression handling below.
796 */
797 acc_opt : /* Empty */ { $$ = 0; }
798 | ',' accs { $$ = $2; }
799 ;
800
801 accs : acc { $$ = $1; }
802 | accs ',' acc { $$ = $1 | $3; }
803 ;
804
805 acc : tNOINVERT { $$ = WRC_AF_NOINVERT; }
806 | tSHIFT { $$ = WRC_AF_SHIFT; }
807 | tCONTROL { $$ = WRC_AF_CONTROL; }
808 | tALT { $$ = WRC_AF_ALT; }
809 | tASCII { $$ = WRC_AF_ASCII; }
810 | tVIRTKEY { $$ = WRC_AF_VIRTKEY; }
811 ;
812
813 /* ------------------------------ Dialog ------------------------------ */
814 /* FIXME: Support EXSTYLE in the dialog line itself */
815 dialog : tDIALOG loadmemopts expr ',' expr ',' expr ',' expr dlg_attributes
816 tBEGIN ctrls tEND {
817 if($2)
818 {
819 $10->memopt = *($2);
820 free($2);
821 }
822 else
823 $10->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
824 $10->x = $3;
825 $10->y = $5;
826 $10->width = $7;
827 $10->height = $9;
828 $10->controls = get_control_head($12);
829 $$ = $10;
830 if(!$$->gotstyle)
831 {
832 $$->style = new_style(0,0);
833 $$->style->or_mask = WS_POPUP;
834 $$->gotstyle = TRUE;
835 }
836 if($$->title)
837 $$->style->or_mask |= WS_CAPTION;
838 if($$->font)
839 $$->style->or_mask |= DS_SETFONT;
840
841 $$->style->or_mask &= ~($$->style->and_mask);
842 $$->style->and_mask = 0;
843
844 if(!$$->lvc.language)
845 $$->lvc.language = dup_language(currentlanguage);
846 }
847 ;
848
849 dlg_attributes
850 : /* Empty */ { $$=new_dialog(); }
851 | dlg_attributes tSTYLE style { $$=dialog_style($3,$1); }
852 | dlg_attributes tEXSTYLE style { $$=dialog_exstyle($3,$1); }
853 | dlg_attributes tCAPTION tSTRING { $$=dialog_caption($3,$1); }
854 | dlg_attributes opt_font { $$=dialog_font($2,$1); }
855 | dlg_attributes tCLASS nameid_s { $$=dialog_class($3,$1); }
856 | dlg_attributes tMENU nameid { $$=dialog_menu($3,$1); }
857 | dlg_attributes opt_language { $$=dialog_language($2,$1); }
858 | dlg_attributes opt_characts { $$=dialog_characteristics($2,$1); }
859 | dlg_attributes opt_version { $$=dialog_version($2,$1); }
860 ;
861
862 ctrls : /* Empty */ { $$ = NULL; }
863 | ctrls tCONTROL gen_ctrl { $$=ins_ctrl(-1, 0, $3, $1); }
864 | ctrls tEDITTEXT ctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
865 | ctrls tLISTBOX ctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
866 | ctrls tCOMBOBOX ctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
867 | ctrls tSCROLLBAR ctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
868 | ctrls tCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
869 | ctrls tDEFPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
870 | ctrls tGROUPBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
871 | ctrls tPUSHBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
872 /* | ctrls tPUSHBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
873 | ctrls tRADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
874 | ctrls tAUTO3STATE lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
875 | ctrls tSTATE3 lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
876 | ctrls tAUTOCHECKBOX lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
877 | ctrls tAUTORADIOBUTTON lab_ctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
878 | ctrls tLTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
879 | ctrls tCTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
880 | ctrls tRTEXT lab_ctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
881 /* special treatment for icons, as the extent is optional */
882 | ctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
883 $10->title = $3;
884 $10->id = $5;
885 $10->x = $7;
886 $10->y = $9;
887 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
888 }
889 ;
890
891 lab_ctrl
892 : tSTRING opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style {
893 $$=new_control();
894 $$->title = new_name_id();
895 $$->title->type = name_str;
896 $$->title->name.s_name = $1;
897 $$->id = $3;
898 $$->x = $5;
899 $$->y = $7;
900 $$->width = $9;
901 $$->height = $11;
902 if($12)
903 {
904 $$->style = $12;
905 $$->gotstyle = TRUE;
906 }
907 }
908 ;
909
910 ctrl_desc
911 : expr ',' expr ',' expr ',' expr ',' expr optional_style {
912 $$ = new_control();
913 $$->id = $1;
914 $$->x = $3;
915 $$->y = $5;
916 $$->width = $7;
917 $$->height = $9;
918 if($10)
919 {
920 $$->style = $10;
921 $$->gotstyle = TRUE;
922 }
923 }
924 ;
925
926 iconinfo: /* Empty */
927 { $$ = new_control(); }
928
929 | ',' expr ',' expr {
930 $$ = new_control();
931 $$->width = $2;
932 $$->height = $4;
933 }
934 | ',' expr ',' expr ',' style {
935 $$ = new_control();
936 $$->width = $2;
937 $$->height = $4;
938 $$->style = $6;
939 $$->gotstyle = TRUE;
940 }
941 | ',' expr ',' expr ',' style ',' style {
942 $$ = new_control();
943 $$->width = $2;
944 $$->height = $4;
945 $$->style = $6;
946 $$->gotstyle = TRUE;
947 $$->exstyle = $8;
948 $$->gotexstyle = TRUE;
949 }
950 ;
951
952 gen_ctrl: nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr ',' style {
953 $$=new_control();
954 $$->title = $1;
955 $$->id = $3;
956 $$->ctlclass = convert_ctlclass($5);
957 $$->style = $7;
958 $$->gotstyle = TRUE;
959 $$->x = $9;
960 $$->y = $11;
961 $$->width = $13;
962 $$->height = $15;
963 $$->exstyle = $17;
964 $$->gotexstyle = TRUE;
965 }
966 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr {
967 $$=new_control();
968 $$->title = $1;
969 $$->id = $3;
970 $$->ctlclass = convert_ctlclass($5);
971 $$->style = $7;
972 $$->gotstyle = TRUE;
973 $$->x = $9;
974 $$->y = $11;
975 $$->width = $13;
976 $$->height = $15;
977 }
978 ;
979
980 opt_font
981 : tFONT expr ',' tSTRING { $$ = new_font_id($2, $4, 0, 0); }
982 ;
983
984 /* ------------------------------ style flags ------------------------------ */
985 optional_style /* Abbused once to get optional ExStyle */
986 : /* Empty */ { $$ = NULL; }
987 | ',' style { $$ = $2; }
988 ;
989
990 optional_style_pair
991 : /* Empty */ { $$ = NULL; }
992 | ',' style { $$ = new_style_pair($2, 0); }
993 | ',' style ',' style { $$ = new_style_pair($2, $4); }
994 ;
995
996 style
997 : style '|' style { $$ = new_style($1->or_mask | $3->or_mask, $1->and_mask | $3->and_mask); free($1); free($3);}
998 | '(' style ')' { $$ = $2; }
999 | any_num { $$ = new_style($1, 0); }
1000 | tNOT any_num { $$ = new_style(0, $2); }
1001 ;
1002
1003 ctlclass
1004 : expr {
1005 $$ = new_name_id();
1006 $$->type = name_ord;
1007 $$->name.i_name = $1;
1008 }
1009 | tSTRING {
1010 $$ = new_name_id();
1011 $$->type = name_str;
1012 $$->name.s_name = $1;
1013 }
1014 ;
1015
1016 /* ------------------------------ DialogEx ------------------------------ */
1017 dialogex: tDIALOGEX loadmemopts expr ',' expr ',' expr ',' expr helpid dlgex_attribs
1018 tBEGIN exctrls tEND {
1019 if(!win32)
1020 yywarning("DIALOGEX not supported in 16-bit mode");
1021 if($2)
1022 {
1023 $11->memopt = *($2);
1024 free($2);
1025 }
1026 else
1027 $11->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1028 $11->x = $3;
1029 $11->y = $5;
1030 $11->width = $7;
1031 $11->height = $9;
1032 if($10)
1033 {
1034 $11->helpid = *($10);
1035 $11->gothelpid = TRUE;
1036 free($10);
1037 }
1038 $11->controls = get_control_head($13);
1039 $$ = $11;
1040
1041 assert($$->style != NULL);
1042 if(!$$->gotstyle)
1043 {
1044 $$->style->or_mask = WS_POPUP;
1045 $$->gotstyle = TRUE;
1046 }
1047 if($$->title)
1048 $$->style->or_mask |= WS_CAPTION;
1049 if($$->font)
1050 $$->style->or_mask |= DS_SETFONT;
1051
1052 $$->style->or_mask &= ~($$->style->and_mask);
1053 $$->style->and_mask = 0;
1054
1055 if(!$$->lvc.language)
1056 $$->lvc.language = dup_language(currentlanguage);
1057 }
1058 ;
1059
1060 dlgex_attribs
1061 : /* Empty */ { $$=new_dialogex(); }
1062 | dlgex_attribs tSTYLE style { $$=dialogex_style($3,$1); }
1063 | dlgex_attribs tEXSTYLE style { $$=dialogex_exstyle($3,$1); }
1064 | dlgex_attribs tCAPTION tSTRING { $$=dialogex_caption($3,$1); }
1065 | dlgex_attribs opt_font { $$=dialogex_font($2,$1); }
1066 | dlgex_attribs opt_exfont { $$=dialogex_font($2,$1); }
1067 | dlgex_attribs tCLASS nameid_s { $$=dialogex_class($3,$1); }
1068 | dlgex_attribs tMENU nameid { $$=dialogex_menu($3,$1); }
1069 | dlgex_attribs opt_language { $$=dialogex_language($2,$1); }
1070 | dlgex_attribs opt_characts { $$=dialogex_characteristics($2,$1); }
1071 | dlgex_attribs opt_version { $$=dialogex_version($2,$1); }
1072 ;
1073
1074 exctrls : /* Empty */ { $$ = NULL; }
1075 | exctrls tCONTROL gen_exctrl { $$=ins_ctrl(-1, 0, $3, $1); }
1076 | exctrls tEDITTEXT exctrl_desc { $$=ins_ctrl(CT_EDIT, 0, $3, $1); }
1077 | exctrls tLISTBOX exctrl_desc { $$=ins_ctrl(CT_LISTBOX, 0, $3, $1); }
1078 | exctrls tCOMBOBOX exctrl_desc { $$=ins_ctrl(CT_COMBOBOX, 0, $3, $1); }
1079 | exctrls tSCROLLBAR exctrl_desc { $$=ins_ctrl(CT_SCROLLBAR, 0, $3, $1); }
1080 | exctrls tCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_CHECKBOX, $3, $1); }
1081 | exctrls tDEFPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_DEFPUSHBUTTON, $3, $1); }
1082 | exctrls tGROUPBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_GROUPBOX, $3, $1);}
1083 | exctrls tPUSHBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBUTTON, $3, $1); }
1084 /* | exctrls tPUSHBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_PUSHBOX, $3, $1); } */
1085 | exctrls tRADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_RADIOBUTTON, $3, $1); }
1086 | exctrls tAUTO3STATE lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTO3STATE, $3, $1); }
1087 | exctrls tSTATE3 lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_3STATE, $3, $1); }
1088 | exctrls tAUTOCHECKBOX lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTOCHECKBOX, $3, $1); }
1089 | exctrls tAUTORADIOBUTTON lab_exctrl { $$=ins_ctrl(CT_BUTTON, BS_AUTORADIOBUTTON, $3, $1); }
1090 | exctrls tLTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_LEFT, $3, $1); }
1091 | exctrls tCTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_CENTER, $3, $1); }
1092 | exctrls tRTEXT lab_exctrl { $$=ins_ctrl(CT_STATIC, SS_RIGHT, $3, $1); }
1093 /* special treatment for icons, as the extent is optional */
1094 | exctrls tICON nameid_s opt_comma expr ',' expr ',' expr iconinfo {
1095 $10->title = $3;
1096 $10->id = $5;
1097 $10->x = $7;
1098 $10->y = $9;
1099 $$ = ins_ctrl(CT_STATIC, SS_ICON, $10, $1);
1100 }
1101 ;
1102
1103 gen_exctrl
1104 : nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ','
1105 expr ',' style helpid opt_data {
1106 $$=new_control();
1107 $$->title = $1;
1108 $$->id = $3;
1109 $$->ctlclass = convert_ctlclass($5);
1110 $$->style = $7;
1111 $$->gotstyle = TRUE;
1112 $$->x = $9;
1113 $$->y = $11;
1114 $$->width = $13;
1115 $$->height = $15;
1116 if($17)
1117 {
1118 $$->exstyle = $17;
1119 $$->gotexstyle = TRUE;
1120 }
1121 if($18)
1122 {
1123 $$->helpid = *($18);
1124 $$->gothelpid = TRUE;
1125 free($18);
1126 }
1127 $$->extra = $19;
1128 }
1129 | nameid_s opt_comma expr ',' ctlclass ',' style ',' expr ',' expr ',' expr ',' expr opt_data {
1130 $$=new_control();
1131 $$->title = $1;
1132 $$->id = $3;
1133 $$->style = $7;
1134 $$->gotstyle = TRUE;
1135 $$->ctlclass = convert_ctlclass($5);
1136 $$->x = $9;
1137 $$->y = $11;
1138 $$->width = $13;
1139 $$->height = $15;
1140 $$->extra = $16;
1141 }
1142 ;
1143
1144 lab_exctrl
1145 : tSTRING opt_comma expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1146 $$=new_control();
1147 $$->title = new_name_id();
1148 $$->title->type = name_str;
1149 $$->title->name.s_name = $1;
1150 $$->id = $3;
1151 $$->x = $5;
1152 $$->y = $7;
1153 $$->width = $9;
1154 $$->height = $11;
1155 if($12)
1156 {
1157 $$->style = $12->style;
1158 $$->gotstyle = TRUE;
1159
1160 if ($12->exstyle)
1161 {
1162 $$->exstyle = $12->exstyle;
1163 $$->gotexstyle = TRUE;
1164 }
1165 free($12);
1166 }
1167
1168 $$->extra = $14;
1169 }
1170 ;
1171
1172 exctrl_desc
1173 : expr ',' expr ',' expr ',' expr ',' expr optional_style_pair helpid opt_data {
1174 $$ = new_control();
1175 $$->id = $1;
1176 $$->x = $3;
1177 $$->y = $5;
1178 $$->width = $7;
1179 $$->height = $9;
1180 if($10)
1181 {
1182 $$->style = $10->style;
1183 $$->gotstyle = TRUE;
1184
1185 if ($10->exstyle)
1186 {
1187 $$->exstyle = $10->exstyle;
1188 $$->gotexstyle = TRUE;
1189 }
1190 free($10);
1191 }
1192 $$->extra = $12;
1193 }
1194 ;
1195
1196 opt_data: /* Empty */ { $$ = NULL; }
1197 | raw_data { $$ = $1; }
1198 ;
1199
1200 helpid : /* Empty */ { $$ = NULL; }
1201 | ',' expr { $$ = new_int($2); }
1202 ;
1203
1204 opt_exfont
1205 : tFONT expr ',' tSTRING ',' expr ',' expr opt_expr { $$ = new_font_id($2, $4, $6, $8); }
1206 ;
1207
1208 /*
1209 * FIXME: This odd expression is here to nullify an extra token found
1210 * in some appstudio produced resources which appear to do nothing.
1211 */
1212 opt_expr: /* Empty */ { $$ = NULL; }
1213 | ',' expr { $$ = NULL; }
1214 ;
1215
1216 /* ------------------------------ Menu ------------------------------ */
1217 menu : tMENU loadmemopts opt_lvc menu_body {
1218 if(!$4)
1219 yyerror("Menu must contain items");
1220 $$ = new_menu();
1221 if($2)
1222 {
1223 $$->memopt = *($2);
1224 free($2);
1225 }
1226 else
1227 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1228 $$->items = get_item_head($4);
1229 if($3)
1230 {
1231 $$->lvc = *($3);
1232 free($3);
1233 }
1234 if(!$$->lvc.language)
1235 $$->lvc.language = dup_language(currentlanguage);
1236 }
1237 ;
1238
1239 menu_body
1240 : tBEGIN item_definitions tEND { $$ = $2; }
1241 ;
1242
1243 item_definitions
1244 : /* Empty */ {$$ = NULL;}
1245 | item_definitions tMENUITEM tSTRING opt_comma expr item_options {
1246 $$=new_menu_item();
1247 $$->prev = $1;
1248 if($1)
1249 $1->next = $$;
1250 $$->id = $5;
1251 $$->state = $6;
1252 $$->name = $3;
1253 }
1254 | item_definitions tMENUITEM tSEPARATOR {
1255 $$=new_menu_item();
1256 $$->prev = $1;
1257 if($1)
1258 $1->next = $$;
1259 }
1260 | item_definitions tPOPUP tSTRING item_options menu_body {
1261 $$ = new_menu_item();
1262 $$->prev = $1;
1263 if($1)
1264 $1->next = $$;
1265 $$->popup = get_item_head($5);
1266 $$->name = $3;
1267 }
1268 ;
1269
1270 /* NOTE: item_options is right recursive because it would introduce
1271 * a shift/reduce conflict on ',' in itemex_options due to the
1272 * empty rule here. The parser is now forced to look beyond the ','
1273 * before reducing (force shift).
1274 * Right recursion here is not a problem because we cannot expect
1275 * more than 7 parserstack places to be occupied while parsing this
1276 * (who would want to specify a MF_x flag twice?).
1277 */
1278 item_options
1279 : /* Empty */ { $$ = 0; }
1280 | ',' tCHECKED item_options { $$ = $3 | MF_CHECKED; }
1281 | ',' tGRAYED item_options { $$ = $3 | MF_GRAYED; }
1282 | ',' tHELP item_options { $$ = $3 | MF_HELP; }
1283 | ',' tINACTIVE item_options { $$ = $3 | MF_DISABLED; }
1284 | ',' tMENUBARBREAK item_options { $$ = $3 | MF_MENUBARBREAK; }
1285 | ',' tMENUBREAK item_options { $$ = $3 | MF_MENUBREAK; }
1286 ;
1287
1288 /* ------------------------------ MenuEx ------------------------------ */
1289 menuex : tMENUEX loadmemopts opt_lvc menuex_body {
1290 if(!win32)
1291 yywarning("MENUEX not supported in 16-bit mode");
1292 if(!$4)
1293 yyerror("MenuEx must contain items");
1294 $$ = new_menuex();
1295 if($2)
1296 {
1297 $$->memopt = *($2);
1298 free($2);
1299 }
1300 else
1301 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE | WRC_MO_DISCARDABLE;
1302 $$->items = get_itemex_head($4);
1303 if($3)
1304 {
1305 $$->lvc = *($3);
1306 free($3);
1307 }
1308 if(!$$->lvc.language)
1309 $$->lvc.language = dup_language(currentlanguage);
1310 }
1311 ;
1312
1313 menuex_body
1314 : tBEGIN itemex_definitions tEND { $$ = $2; }
1315 ;
1316
1317 itemex_definitions
1318 : /* Empty */ {$$ = NULL; }
1319 | itemex_definitions tMENUITEM tSTRING itemex_options {
1320 $$ = new_menuex_item();
1321 $$->prev = $1;
1322 if($1)
1323 $1->next = $$;
1324 $$->name = $3;
1325 $$->id = $4->id;
1326 $$->type = $4->type;
1327 $$->state = $4->state;
1328 $$->helpid = $4->helpid;
1329 $$->gotid = $4->gotid;
1330 $$->gottype = $4->gottype;
1331 $$->gotstate = $4->gotstate;
1332 $$->gothelpid = $4->gothelpid;
1333 free($4);
1334 }
1335 | itemex_definitions tMENUITEM tSEPARATOR {
1336 $$ = new_menuex_item();
1337 $$->prev = $1;
1338 if($1)
1339 $1->next = $$;
1340 }
1341 | itemex_definitions tPOPUP tSTRING itemex_p_options menuex_body {
1342 $$ = new_menuex_item();
1343 $$->prev = $1;
1344 if($1)
1345 $1->next = $$;
1346 $$->popup = get_itemex_head($5);
1347 $$->name = $3;
1348 $$->id = $4->id;
1349 $$->type = $4->type;
1350 $$->state = $4->state;
1351 $$->helpid = $4->helpid;
1352 $$->gotid = $4->gotid;
1353 $$->gottype = $4->gottype;
1354 $$->gotstate = $4->gotstate;
1355 $$->gothelpid = $4->gothelpid;
1356 free($4);
1357 }
1358 ;
1359
1360 itemex_options
1361 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1362 | ',' expr {
1363 $$ = new_itemex_opt($2, 0, 0, 0);
1364 $$->gotid = TRUE;
1365 }
1366 | ',' e_expr ',' e_expr item_options {
1367 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $5, 0);
1368 $$->gotid = TRUE;
1369 $$->gottype = TRUE;
1370 $$->gotstate = TRUE;
1371 if($2) free($2);
1372 if($4) free($4);
1373 }
1374 | ',' e_expr ',' e_expr ',' expr {
1375 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1376 $$->gotid = TRUE;
1377 $$->gottype = TRUE;
1378 $$->gotstate = TRUE;
1379 if($2) free($2);
1380 if($4) free($4);
1381 }
1382 ;
1383
1384 itemex_p_options
1385 : /* Empty */ { $$ = new_itemex_opt(0, 0, 0, 0); }
1386 | ',' expr {
1387 $$ = new_itemex_opt($2, 0, 0, 0);
1388 $$->gotid = TRUE;
1389 }
1390 | ',' e_expr ',' expr {
1391 $$ = new_itemex_opt($2 ? *($2) : 0, $4, 0, 0);
1392 if($2) free($2);
1393 $$->gotid = TRUE;
1394 $$->gottype = TRUE;
1395 }
1396 | ',' e_expr ',' e_expr ',' expr {
1397 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6, 0);
1398 if($2) free($2);
1399 if($4) free($4);
1400 $$->gotid = TRUE;
1401 $$->gottype = TRUE;
1402 $$->gotstate = TRUE;
1403 }
1404 | ',' e_expr ',' e_expr ',' e_expr ',' expr {
1405 $$ = new_itemex_opt($2 ? *($2) : 0, $4 ? *($4) : 0, $6 ? *($6) : 0, $8);
1406 if($2) free($2);
1407 if($4) free($4);
1408 if($6) free($6);
1409 $$->gotid = TRUE;
1410 $$->gottype = TRUE;
1411 $$->gotstate = TRUE;
1412 $$->gothelpid = TRUE;
1413 }
1414 ;
1415
1416 /* ------------------------------ StringTable ------------------------------ */
1417 /* Stringtables are parsed differently than other resources because their
1418 * layout is substantially different from other resources.
1419 * The table is parsed through a _global_ variable 'tagstt' which holds the
1420 * current stringtable descriptor (stringtable_t *) and 'sttres' that holds a
1421 * list of stringtables of different languages.
1422 */
1423 stringtable
1424 : stt_head tBEGIN strings tEND {
1425 if(!$3)
1426 {
1427 yyerror("Stringtable must have at least one entry");
1428 }
1429 else
1430 {
1431 stringtable_t *stt;
1432 /* Check if we added to a language table or created
1433 * a new one.
1434 */
1435 for(stt = sttres; stt; stt = stt->next)
1436 {
1437 if(stt == tagstt)
1438 break;
1439 }
1440 if(!stt)
1441 {
1442 /* It is a new one */
1443 if(sttres)
1444 {
1445 sttres->prev = tagstt;
1446 tagstt->next = sttres;
1447 sttres = tagstt;
1448 }
1449 else
1450 sttres = tagstt;
1451 }
1452 /* Else were done */
1453 }
1454 if(tagstt_memopt)
1455 {
1456 free(tagstt_memopt);
1457 tagstt_memopt = NULL;
1458 }
1459
1460 $$ = tagstt;
1461 }
1462 ;
1463
1464 /* This is to get the language of the currently parsed stringtable */
1465 stt_head: tSTRINGTABLE loadmemopts opt_lvc {
1466 if((tagstt = find_stringtable($3)) == NULL)
1467 tagstt = new_stringtable($3);
1468 tagstt_memopt = $2;
1469 tagstt_version = $3->version;
1470 tagstt_characts = $3->characts;
1471 if($3)
1472 free($3);
1473 }
1474 ;
1475
1476 strings : /* Empty */ { $$ = NULL; }
1477 | strings expr opt_comma tSTRING {
1478 int i;
1479 assert(tagstt != NULL);
1480 if($2 > 65535 || $2 < -32768)
1481 yyerror("Stringtable entry's ID out of range (%d)", $2);
1482 /* Search for the ID */
1483 for(i = 0; i < tagstt->nentries; i++)
1484 {
1485 if(tagstt->entries[i].id == $2)
1486 yyerror("Stringtable ID %d already in use", $2);
1487 }
1488 /* If we get here, then we have a new unique entry */
1489 tagstt->nentries++;
1490 tagstt->entries = xrealloc(tagstt->entries, sizeof(tagstt->entries[0]) * tagstt->nentries);
1491 tagstt->entries[tagstt->nentries-1].id = $2;
1492 tagstt->entries[tagstt->nentries-1].str = $4;
1493 if(tagstt_memopt)
1494 tagstt->entries[tagstt->nentries-1].memopt = *tagstt_memopt;
1495 else
1496 tagstt->entries[tagstt->nentries-1].memopt = WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1497 tagstt->entries[tagstt->nentries-1].version = tagstt_version;
1498 tagstt->entries[tagstt->nentries-1].characts = tagstt_characts;
1499
1500 if(pedantic && !$4->size)
1501 yywarning("Zero length strings make no sense");
1502 if(!win32 && $4->size > 254)
1503 yyerror("Stringtable entry more than 254 characters");
1504 if(win32 && $4->size > 65534) /* Hmm..., does this happen? */
1505 yyerror("Stringtable entry more than 65534 characters (probably something else that went wrong)");
1506 $$ = tagstt;
1507 }
1508 ;
1509
1510 opt_comma /* There seem to be two ways to specify a stringtable... */
1511 : /* Empty */
1512 | ','
1513 ;
1514
1515 /* ------------------------------ VersionInfo ------------------------------ */
1516 versioninfo
1517 : tVERSIONINFO loadmemopts fix_version tBEGIN ver_blocks tEND {
1518 $$ = $3;
1519 if($2)
1520 {
1521 $$->memopt = *($2);
1522 free($2);
1523 }
1524 else
1525 $$->memopt = WRC_MO_MOVEABLE | (win32 ? WRC_MO_PURE : 0);
1526 $$->blocks = get_ver_block_head($5);
1527 /* Set language; there is no version or characteristics */
1528 $$->lvc.language = dup_language(currentlanguage);
1529 }
1530 ;
1531
1532 fix_version
1533 : /* Empty */ { $$ = new_versioninfo(); }
1534 | fix_version tFILEVERSION expr ',' expr ',' expr ',' expr {
1535 if($1->gotit.fv)
1536 yyerror("FILEVERSION already defined");
1537 $$ = $1;
1538 $$->filever_maj1 = $3;
1539 $$->filever_maj2 = $5;
1540 $$->filever_min1 = $7;
1541 $$->filever_min2 = $9;
1542 $$->gotit.fv = 1;
1543 }
1544 | fix_version tPRODUCTVERSION expr ',' expr ',' expr ',' expr {
1545 if($1->gotit.pv)
1546 yyerror("PRODUCTVERSION already defined");
1547 $$ = $1;
1548 $$->prodver_maj1 = $3;
1549 $$->prodver_maj2 = $5;
1550 $$->prodver_min1 = $7;
1551 $$->prodver_min2 = $9;
1552 $$->gotit.pv = 1;
1553 }
1554 | fix_version tFILEFLAGS expr {
1555 if($1->gotit.ff)
1556 yyerror("FILEFLAGS already defined");
1557 $$ = $1;
1558 $$->fileflags = $3;
1559 $$->gotit.ff = 1;
1560 }
1561 | fix_version tFILEFLAGSMASK expr {
1562 if($1->gotit.ffm)
1563 yyerror("FILEFLAGSMASK already defined");
1564 $$ = $1;
1565 $$->fileflagsmask = $3;
1566 $$->gotit.ffm = 1;
1567 }
1568 | fix_version tFILEOS expr {
1569 if($1->gotit.fo)
1570 yyerror("FILEOS already defined");
1571 $$ = $1;
1572 $$->fileos = $3;
1573 $$->gotit.fo = 1;
1574 }
1575 | fix_version tFILETYPE expr {
1576 if($1->gotit.ft)
1577 yyerror("FILETYPE already defined");
1578 $$ = $1;
1579 $$->filetype = $3;
1580 $$->gotit.ft = 1;
1581 }
1582 | fix_version tFILESUBTYPE expr {
1583 if($1->gotit.fst)
1584 yyerror("FILESUBTYPE already defined");
1585 $$ = $1;
1586 $$->filesubtype = $3;
1587 $$->gotit.fst = 1;
1588 }
1589 ;
1590
1591 ver_blocks
1592 : /* Empty */ { $$ = NULL; }
1593 | ver_blocks ver_block {
1594 $$ = $2;
1595 $$->prev = $1;
1596 if($1)
1597 $1->next = $$;
1598 }
1599 ;
1600
1601 ver_block
1602 : tBLOCK tSTRING tBEGIN ver_values tEND {
1603 $$ = new_ver_block();
1604 $$->name = $2;
1605 $$->values = get_ver_value_head($4);
1606 }
1607 ;
1608
1609 ver_values
1610 : /* Empty */ { $$ = NULL; }
1611 | ver_values ver_value {
1612 $$ = $2;
1613 $$->prev = $1;
1614 if($1)
1615 $1->next = $$;
1616 }
1617 ;
1618
1619 ver_value
1620 : ver_block {
1621 $$ = new_ver_value();
1622 $$->type = val_block;
1623 $$->value.block = $1;
1624 }
1625 | tVALUE tSTRING ',' tSTRING {
1626 $$ = new_ver_value();
1627 $$->type = val_str;
1628 $$->key = $2;
1629 $$->value.str = $4;
1630 }
1631 | tVALUE tSTRING ',' ver_words {
1632 $$ = new_ver_value();
1633 $$->type = val_words;
1634 $$->key = $2;
1635 $$->value.words = $4;
1636 }
1637 ;
1638
1639 ver_words
1640 : expr { $$ = new_ver_words($1); }
1641 | ver_words ',' expr { $$ = add_ver_words($1, $3); }
1642 ;
1643
1644 /* ------------------------------ Toolbar ------------------------------ */
1645 toolbar: tTOOLBAR loadmemopts expr ',' expr opt_lvc tBEGIN toolbar_items tEND {
1646 int nitems;
1647 toolbar_item_t *items = get_tlbr_buttons_head($8, &nitems);
1648 $$ = new_toolbar($3, $5, items, nitems);
1649 if($2)
1650 {
1651 $$->memopt = *($2);
1652 free($2);
1653 }
1654 else
1655 {
1656 $$->memopt = WRC_MO_MOVEABLE | WRC_MO_PURE;
1657 }
1658 if($6)
1659 {
1660 $$->lvc = *($6);
1661 free($6);
1662 }
1663 if(!$$->lvc.language)
1664 {
1665 $$->lvc.language = dup_language(currentlanguage);
1666 }
1667 }
1668 ;
1669
1670 toolbar_items
1671 : /* Empty */ { $$ = NULL; }
1672 | toolbar_items tBUTTON expr {
1673 toolbar_item_t *idrec = new_toolbar_item();
1674 idrec->id = $3;
1675 $$ = ins_tlbr_button($1, idrec);
1676 }
1677 | toolbar_items tSEPARATOR {
1678 toolbar_item_t *idrec = new_toolbar_item();
1679 idrec->id = 0;
1680 $$ = ins_tlbr_button($1, idrec);
1681 }
1682 ;
1683
1684 /* ------------------------------ Memory options ------------------------------ */
1685 loadmemopts
1686 : /* Empty */ { $$ = NULL; }
1687 | loadmemopts lamo {
1688 if($1)
1689 {
1690 *($1) |= *($2);
1691 $$ = $1;
1692 free($2);
1693 }
1694 else
1695 $$ = $2;
1696 }
1697 | loadmemopts lama {
1698 if($1)
1699 {
1700 *($1) &= *($2);
1701 $$ = $1;
1702 free($2);
1703 }
1704 else
1705 {
1706 *$2 &= WRC_MO_MOVEABLE | WRC_MO_DISCARDABLE | WRC_MO_PURE;
1707 $$ = $2;
1708 }
1709 }
1710 ;
1711
1712 lamo : tPRELOAD { $$ = new_int(WRC_MO_PRELOAD); }
1713 | tMOVEABLE { $$ = new_int(WRC_MO_MOVEABLE); }
1714 | tDISCARDABLE { $$ = new_int(WRC_MO_DISCARDABLE); }
1715 | tPURE { $$ = new_int(WRC_MO_PURE); }
1716 ;
1717
1718 lama : tLOADONCALL { $$ = new_int(~WRC_MO_PRELOAD); }
1719 | tFIXED { $$ = new_int(~WRC_MO_MOVEABLE); }
1720 | tIMPURE { $$ = new_int(~WRC_MO_PURE); }
1721 ;
1722
1723 /* ------------------------------ Win32 options ------------------------------ */
1724 opt_lvc : /* Empty */ { $$ = new_lvc(); }
1725 | opt_lvc opt_language {
1726 if(!win32)
1727 yywarning("LANGUAGE not supported in 16-bit mode");
1728 if($1->language)
1729 yyerror("Language already defined");
1730 $$ = $1;
1731 $1->language = $2;
1732 }
1733 | opt_lvc opt_characts {
1734 if(!win32)
1735 yywarning("CHARACTERISTICS not supported in 16-bit mode");
1736 if($1->characts)
1737 yyerror("Characteristics already defined");
1738 $$ = $1;
1739 $1->characts = $2;
1740 }
1741 | opt_lvc opt_version {
1742 if(!win32)
1743 yywarning("VERSION not supported in 16-bit mode");
1744 if($1->version)
1745 yyerror("Version already defined");
1746 $$ = $1;
1747 $1->version = $2;
1748 }
1749 ;
1750
1751 /*
1752 * This here is another s/r conflict on {bi,u}nary + and -.
1753 * It is due to the look-ahead which must determine when the
1754 * rule opt_language ends. It could be solved with adding a
1755 * tNL at the end, but that seems unreasonable to do.
1756 * The conflict is now moved to the expression handling below.
1757 */
1758 opt_language
1759 : tLANGUAGE expr ',' expr { $$ = new_language($2, $4);
1760 if (get_language_codepage($2, $4) == -1)
1761 yyerror( "Language %04x is not supported", ($4<<10) + $2);
1762 }
1763 ;
1764
1765 opt_characts
1766 : tCHARACTERISTICS expr { $$ = new_characts($2); }
1767 ;
1768
1769 opt_version
1770 : tVERSION expr { $$ = new_version($2); }
1771 ;
1772
1773 /* ------------------------------ Raw data handling ------------------------------ */
1774 raw_data: opt_lvc tBEGIN raw_elements tEND {
1775 if($1)
1776 {
1777 $3->lvc = *($1);
1778 free($1);
1779 }
1780
1781 if(!$3->lvc.language)
1782 $3->lvc.language = dup_language(currentlanguage);
1783
1784 $$ = $3;
1785 }
1786 ;
1787
1788 raw_elements
1789 : tRAWDATA { $$ = $1; }
1790 | tNUMBER { $$ = int2raw_data($1); }
1791 | '-' tNUMBER { $$ = int2raw_data(-($2)); }
1792 | tLNUMBER { $$ = long2raw_data($1); }
1793 | '-' tLNUMBER { $$ = long2raw_data(-($2)); }
1794 | tSTRING { $$ = str2raw_data($1); }
1795 | raw_elements opt_comma tRAWDATA { $$ = merge_raw_data($1, $3); free($3->data); free($3); }
1796 | raw_elements opt_comma tNUMBER { $$ = merge_raw_data_int($1, $3); }
1797 | raw_elements opt_comma '-' tNUMBER { $$ = merge_raw_data_int($1, -($4)); }
1798 | raw_elements opt_comma tLNUMBER { $$ = merge_raw_data_long($1, $3); }
1799 | raw_elements opt_comma '-' tLNUMBER { $$ = merge_raw_data_long($1, -($4)); }
1800 | raw_elements opt_comma tSTRING { $$ = merge_raw_data_str($1, $3); }
1801 ;
1802
1803 /* File data or raw data */
1804 file_raw: filename { $$ = load_file($1,dup_language(currentlanguage)); }
1805 | raw_data { $$ = $1; }
1806 ;
1807
1808 /* ------------------------------ Win32 expressions ------------------------------ */
1809 /* All win16 numbers are also handled here. This is inconsistent with MS'
1810 * resource compiler, but what the heck, its just handy to have.
1811 */
1812 e_expr : /* Empty */ { $$ = 0; }
1813 | expr { $$ = new_int($1); }
1814 ;
1815
1816 /* This rule moves ALL s/r conflicts on {bi,u}nary - and + to here */
1817 expr : xpr { $$ = ($1); }
1818 ;
1819
1820 xpr : xpr '+' xpr { $$ = ($1) + ($3); }
1821 | xpr '-' xpr { $$ = ($1) - ($3); }
1822 | xpr '|' xpr { $$ = ($1) | ($3); }
1823 | xpr '&' xpr { $$ = ($1) & ($3); }
1824 | xpr '*' xpr { $$ = ($1) * ($3); }
1825 | xpr '/' xpr { $$ = ($1) / ($3); }
1826 | xpr '^' xpr { $$ = ($1) ^ ($3); }
1827 | '~' xpr { $$ = ~($2); }
1828 | '-' xpr %prec pUPM { $$ = -($2); }
1829 | '+' xpr %prec pUPM { $$ = $2; }
1830 | '(' xpr ')' { $$ = $2; }
1831 | any_num { $$ = $1; }
1832 | tNOT any_num { $$ = ~($2); }
1833 ;
1834
1835 any_num : tNUMBER { $$ = $1; }
1836 | tLNUMBER { $$ = $1; }
1837 ;
1838
1839 %%
1840 /* Dialog specific functions */
1841 static dialog_t *dialog_style(style_t * st, dialog_t *dlg)
1842 {
1843 assert(dlg != NULL);
1844 if(dlg->style == NULL)
1845 {
1846 dlg->style = new_style(0,0);
1847 }
1848
1849 if(dlg->gotstyle)
1850 {
1851 yywarning("Style already defined, or-ing together");
1852 }
1853 else
1854 {
1855 dlg->style->or_mask = 0;
1856 dlg->style->and_mask = 0;
1857 }
1858 dlg->style->or_mask |= st->or_mask;
1859 dlg->style->and_mask |= st->and_mask;
1860 dlg->gotstyle = TRUE;
1861 free(st);
1862 return dlg;
1863 }
1864
1865 static dialog_t *dialog_exstyle(style_t *st, dialog_t *dlg)
1866 {
1867 assert(dlg != NULL);
1868 if(dlg->exstyle == NULL)
1869 {
1870 dlg->exstyle = new_style(0,0);
1871 }
1872
1873 if(dlg->gotexstyle)
1874 {
1875 yywarning("ExStyle already defined, or-ing together");
1876 }
1877 else
1878 {
1879 dlg->exstyle->or_mask = 0;
1880 dlg->exstyle->and_mask = 0;
1881 }
1882 dlg->exstyle->or_mask |= st->or_mask;
1883 dlg->exstyle->and_mask |= st->and_mask;
1884 dlg->gotexstyle = TRUE;
1885 free(st);
1886 return dlg;
1887 }
1888
1889 static dialog_t *dialog_caption(string_t *s, dialog_t *dlg)
1890 {
1891 assert(dlg != NULL);
1892 if(dlg->title)
1893 yyerror("Caption already defined");
1894 dlg->title = s;
1895 return dlg;
1896 }
1897
1898 static dialog_t *dialog_font(font_id_t *f, dialog_t *dlg)
1899 {
1900 assert(dlg != NULL);
1901 if(dlg->font)
1902 yyerror("Font already defined");
1903 dlg->font = f;
1904 return dlg;
1905 }
1906
1907 static dialog_t *dialog_class(name_id_t *n, dialog_t *dlg)
1908 {
1909 assert(dlg != NULL);
1910 if(dlg->dlgclass)
1911 yyerror("Class already defined");
1912 dlg->dlgclass = n;
1913 return dlg;
1914 }
1915
1916 static dialog_t *dialog_menu(name_id_t *m, dialog_t *dlg)
1917 {
1918 assert(dlg != NULL);
1919 if(dlg->menu)
1920 yyerror("Menu already defined");
1921 dlg->menu = m;
1922 return dlg;
1923 }
1924
1925 static dialog_t *dialog_language(language_t *l, dialog_t *dlg)
1926 {
1927 assert(dlg != NULL);
1928 if(dlg->lvc.language)
1929 yyerror("Language already defined");
1930 dlg->lvc.language = l;
1931 return dlg;
1932 }
1933
1934 static dialog_t *dialog_characteristics(characts_t *c, dialog_t *dlg)
1935 {
1936 assert(dlg != NULL);
1937 if(dlg->lvc.characts)
1938 yyerror("Characteristics already defined");
1939 dlg->lvc.characts = c;
1940 return dlg;
1941 }
1942
1943 static dialog_t *dialog_version(version_t *v, dialog_t *dlg)
1944 {
1945 assert(dlg != NULL);
1946 if(dlg->lvc.version)
1947 yyerror("Version already defined");
1948 dlg->lvc.version = v;
1949 return dlg;
1950 }
1951
1952 /* Controls specific functions */
1953 static control_t *ins_ctrl(int type, int special_style, control_t *ctrl, control_t *prev)
1954 {
1955 /* Hm... this seems to be jammed in at all time... */
1956 int defaultstyle = WS_CHILD | WS_VISIBLE;
1957
1958 assert(ctrl != NULL);
1959 ctrl->prev = prev;
1960
1961 if(prev)
1962 prev->next = ctrl;
1963
1964 if(type != -1)
1965 {
1966 ctrl->ctlclass = new_name_id();
1967 ctrl->ctlclass->type = name_ord;
1968 ctrl->ctlclass->name.i_name = type;
1969 }
1970
1971 switch(type)
1972 {
1973 case CT_BUTTON:
1974 if(special_style != BS_GROUPBOX && special_style != BS_RADIOBUTTON)
1975 defaultstyle |= WS_TABSTOP;
1976 break;
1977 case CT_EDIT:
1978 defaultstyle |= WS_TABSTOP | WS_BORDER;
1979 break;
1980 case CT_LISTBOX:
1981 defaultstyle |= LBS_NOTIFY | WS_BORDER;
1982 break;
1983 case CT_COMBOBOX:
1984 if (!(ctrl->style->or_mask & (CBS_SIMPLE | CBS_DROPDOWN | CBS_DROPDOWNLIST)))
1985 defaultstyle |= CBS_SIMPLE;
1986 break;
1987 case CT_STATIC:
1988 if(special_style == SS_CENTER || special_style == SS_LEFT || special_style == SS_RIGHT)
1989 defaultstyle |= WS_GROUP;
1990 break;
1991 }
1992
1993 if(!ctrl->gotstyle) /* Handle default style setting */
1994 {
1995 switch(type)
1996 {
1997 case CT_EDIT:
1998 defaultstyle |= ES_LEFT;
1999 break;
2000 case CT_LISTBOX:
2001 defaultstyle |= LBS_NOTIFY;
2002 break;
2003 case CT_COMBOBOX:
2004 defaultstyle |= CBS_SIMPLE | WS_TABSTOP;
2005 break;
2006 case CT_SCROLLBAR:
2007 defaultstyle |= SBS_HORZ;
2008 break;
2009 case CT_BUTTON:
2010 switch(special_style)
2011 {
2012 case BS_CHECKBOX:
2013 case BS_DEFPUSHBUTTON:
2014 case BS_PUSHBUTTON:
2015 /* case BS_PUSHBOX: */
2016 case BS_AUTORADIOBUTTON:
2017 case BS_AUTO3STATE:
2018 case BS_3STATE:
2019 case BS_AUTOCHECKBOX:
2020 defaultstyle |= WS_TABSTOP;
2021 break;
2022 default:
2023 yywarning("Unknown default button control-style 0x%08x", special_style);
2024 case BS_GROUPBOX:
2025 case BS_RADIOBUTTON:
2026 break;
2027 }
2028 break;
2029
2030 case CT_STATIC:
2031 switch(special_style)
2032 {
2033 case SS_LEFT:
2034 case SS_RIGHT:
2035 case SS_CENTER:
2036 defaultstyle |= WS_GROUP;
2037 break;
2038 case SS_ICON: /* Special case */
2039 break;
2040 default:
2041 yywarning("Unknown default static control-style 0x%08x", special_style);
2042 break;
2043 }
2044 break;
2045 case -1: /* Generic control */
2046 goto byebye;
2047
2048 default:
2049 yyerror("Internal error (report this): Got weird control type 0x%08x", type);
2050 }
2051 }
2052
2053 /* The SS_ICON flag is always forced in for icon controls */
2054 if(type == CT_STATIC && special_style == SS_ICON)
2055 defaultstyle |= SS_ICON;
2056
2057 if (!ctrl->gotstyle)
2058 ctrl->style = new_style(0,0);
2059
2060 /* combine all styles */
2061 ctrl->style->or_mask = ctrl->style->or_mask | defaultstyle | special_style;
2062 ctrl->gotstyle = TRUE;
2063 byebye:
2064 /* combine with NOT mask */
2065 if (ctrl->gotstyle)
2066 {
2067 ctrl->style->or_mask &= ~(ctrl->style->and_mask);
2068 ctrl->style->and_mask = 0;
2069 }
2070 if (ctrl->gotexstyle)
2071 {
2072 ctrl->exstyle->or_mask &= ~(ctrl->exstyle->and_mask);
2073 ctrl->exstyle->and_mask = 0;
2074 }
2075 return ctrl;
2076 }
2077
2078 static name_id_t *convert_ctlclass(name_id_t *cls)
2079 {
2080 char *cc = NULL;
2081 int iclass;
2082
2083 if(cls->type == name_ord)
2084 return cls;
2085 assert(cls->type == name_str);
2086 if(cls->type == str_unicode)
2087 {
2088 yyerror("Don't yet support unicode class comparison");
2089 }
2090 else
2091 cc = cls->name.s_name->str.cstr;
2092
2093 if(!strcasecmp("BUTTON", cc))
2094 iclass = CT_BUTTON;
2095 else if(!strcasecmp("COMBOBOX", cc))
2096 iclass = CT_COMBOBOX;
2097 else if(!strcasecmp("LISTBOX", cc))
2098 iclass = CT_LISTBOX;
2099 else if(!strcasecmp("EDIT", cc))
2100 iclass = CT_EDIT;
2101 else if(!strcasecmp("STATIC", cc))
2102 iclass = CT_STATIC;
2103 else if(!strcasecmp("SCROLLBAR", cc))
2104 iclass = CT_SCROLLBAR;
2105 else
2106 return cls; /* No default, return user controlclass */
2107
2108 free(cls->name.s_name->str.cstr);
2109 free(cls->name.s_name);
2110 cls->type = name_ord;
2111 cls->name.i_name = iclass;
2112 return cls;
2113 }
2114
2115 /* DialogEx specific functions */
2116 static dialogex_t *dialogex_style(style_t * st, dialogex_t *dlg)
2117 {
2118 assert(dlg != NULL);
2119 if(dlg->style == NULL)
2120 {
2121 dlg->style = new_style(0,0);
2122 }
2123
2124 if(dlg->gotstyle)
2125 {
2126 yywarning("Style already defined, or-ing together");
2127 }
2128 else
2129 {
2130 dlg->style->or_mask = 0;
2131 dlg->style->and_mask = 0;
2132 }
2133 dlg->style->or_mask |= st->or_mask;
2134 dlg->style->and_mask |= st->and_mask;
2135 dlg->gotstyle = TRUE;
2136 free(st);
2137 return dlg;
2138 }
2139
2140 static dialogex_t *dialogex_exstyle(style_t * st, dialogex_t *dlg)
2141 {
2142 assert(dlg != NULL);
2143 if(dlg->exstyle == NULL)
2144 {
2145 dlg->exstyle = new_style(0,0);
2146 }
2147
2148 if(dlg->gotexstyle)
2149 {
2150 yywarning("ExStyle already defined, or-ing together");
2151 }
2152 else
2153 {
2154 dlg->exstyle->or_mask = 0;
2155 dlg->exstyle->and_mask = 0;
2156 }
2157 dlg->exstyle->or_mask |= st->or_mask;
2158 dlg->exstyle->and_mask |= st->and_mask;
2159 dlg->gotexstyle = TRUE;
2160 free(st);
2161 return dlg;
2162 }
2163
2164 static dialogex_t *dialogex_caption(string_t *s, dialogex_t *dlg)
2165 {
2166 assert(dlg != NULL);
2167 if(dlg->title)
2168 yyerror("Caption already defined");
2169 dlg->title = s;
2170 return dlg;
2171 }
2172
2173 static dialogex_t *dialogex_font(font_id_t *f, dialogex_t *dlg)
2174 {
2175 assert(dlg != NULL);
2176 if(dlg->font)
2177 yyerror("Font already defined");
2178 dlg->font = f;
2179 return dlg;
2180 }
2181
2182 static dialogex_t *dialogex_class(name_id_t *n, dialogex_t *dlg)
2183 {
2184 assert(dlg != NULL);
2185 if(dlg->dlgclass)
2186 yyerror("Class already defined");
2187 dlg->dlgclass = n;
2188 return dlg;
2189 }
2190
2191 static dialogex_t *dialogex_menu(name_id_t *m, dialogex_t *dlg)
2192 {
2193 assert(dlg != NULL);
2194 if(dlg->menu)
2195 yyerror("Menu already defined");
2196 dlg->menu = m;
2197 return dlg;
2198 }
2199
2200 static dialogex_t *dialogex_language(language_t *l, dialogex_t *dlg)
2201 {
2202 assert(dlg != NULL);
2203 if(dlg->lvc.language)
2204 yyerror("Language already defined");
2205 dlg->lvc.language = l;
2206 return dlg;
2207 }
2208
2209 static dialogex_t *dialogex_characteristics(characts_t *c, dialogex_t *dlg)
2210 {
2211 assert(dlg != NULL);
2212 if(dlg->lvc.characts)
2213 yyerror("Characteristics already defined");
2214 dlg->lvc.characts = c;
2215 return dlg;
2216 }
2217
2218 static dialogex_t *dialogex_version(version_t *v, dialogex_t *dlg)
2219 {
2220 assert(dlg != NULL);
2221 if(dlg->lvc.version)
2222 yyerror("Version already defined");
2223 dlg->lvc.version = v;
2224 return dlg;
2225 }
2226
2227 /* Accelerator specific functions */
2228 static event_t *add_event(int key, int id, int flags, event_t *prev)
2229 {
2230 event_t *ev = new_event();
2231
2232 if((flags & (WRC_AF_VIRTKEY | WRC_AF_ASCII)) == (WRC_AF_VIRTKEY | WRC_AF_ASCII))
2233 yyerror("Cannot use both ASCII and VIRTKEY");
2234
2235 ev->key = key;
2236 ev->id = id;
2237 ev->flags = flags & ~WRC_AF_ASCII;
2238 ev->prev = prev;
2239 if(prev)
2240 prev->next = ev;
2241 return ev;
2242 }
2243
2244 static event_t *add_string_event(string_t *key, int id, int flags, event_t *prev)
2245 {
2246 int keycode = 0;
2247 event_t *ev = new_event();
2248
2249 if(key->type != str_char)
2250 yyerror("Key code must be an ascii string");
2251
2252 if((flags & WRC_AF_VIRTKEY) && (!isupper(key->str.cstr[0] & 0xff) && !isdigit(key->str.cstr[0] & 0xff)))
2253 yyerror("VIRTKEY code is not equal to ascii value");
2254
2255 if(key->str.cstr[0] == '^' && (flags & WRC_AF_CONTROL) != 0)
2256 {
2257 yyerror("Cannot use both '^' and CONTROL modifier");
2258 }
2259 else if(key->str.cstr[0] == '^')
2260 {
2261 keycode = toupper(key->str.cstr[1]) - '@';
2262 if(keycode >= ' ')
2263 yyerror("Control-code out of range");
2264 }
2265 else
2266 keycode = key->str.cstr[0];
2267 ev->key = keycode;
2268 ev->id = id;
2269 ev->flags = flags & ~WRC_AF_ASCII;
2270 ev->prev = prev;
2271 if(prev)
2272 prev->next = ev;
2273 return ev;
2274 }
2275
2276 /* MenuEx specific functions */
2277 static itemex_opt_t *new_itemex_opt(int id, int type, int state, int helpid)
2278 {
2279 itemex_opt_t *opt = (itemex_opt_t *)xmalloc(sizeof(itemex_opt_t));
2280 opt->id = id;
2281 opt->type = type;
2282 opt->state = state;
2283 opt->helpid = helpid;
2284 return opt;
2285 }
2286
2287 /* Raw data functions */
2288 static raw_data_t *load_file(string_t *filename, language_t *lang)
2289 {
2290 FILE *fp = NULL;
2291 char *path;
2292 raw_data_t *rd;
2293 string_t *name;
2294 int codepage = get_language_codepage(lang->id, lang->sub);
2295
2296 /* FIXME: we may want to use utf-8 here */
2297 if (codepage <= 0 && filename->type != str_char)
2298 yyerror("Cannot convert filename to ASCII string");
2299 name = convert_string( filename, str_char, codepage );
2300 if (!(path = wpp_find_include(name->str.cstr, 1)))
2301 yyerror("Cannot open file %s", name->str.cstr);
2302 if (!(fp = fopen( path, "rb" )))
2303 yyerror("Cannot open file %s", name->str.cstr);
2304 free( path );
2305 rd = new_raw_data();
2306 fseek(fp, 0, SEEK_END);
2307 rd->size = ftell(fp);
2308 fseek(fp, 0, SEEK_SET);
2309 if (rd->size)
2310 {
2311 rd->data = (char *)xmalloc(rd->size);
2312 fread(rd->data, rd->size, 1, fp);
2313 }
2314 else rd->data = NULL;
2315 fclose(fp);
2316 rd->lvc.language = lang;
2317 free_string(name);
2318 return rd;
2319 }
2320
2321 static raw_data_t *int2raw_data(int i)
2322 {
2323 raw_data_t *rd;
2324
2325 if( ( i >= 0 && (int)((unsigned short)i) != i) ||
2326 ( i < 0 && (int)((short)i) != i) )
2327 yywarning("Integer constant out of 16bit range (%d), truncated to %d\n", i, (short)i);
2328
2329 rd = new_raw_data();
2330 rd->size = sizeof(short);
2331 rd->data = (char *)xmalloc(rd->size);
2332 switch(byteorder)
2333 {
2334 #ifdef WORDS_BIGENDIAN
2335 default:
2336 #endif
2337 case WRC_BO_BIG:
2338 rd->data[0] = HIBYTE(i);
2339 rd->data[1] = LOBYTE(i);
2340 break;
2341
2342 #ifndef WORDS_BIGENDIAN
2343 default:
2344 #endif
2345 case WRC_BO_LITTLE:
2346 rd->data[1] = HIBYTE(i);
2347 rd->data[0] = LOBYTE(i);
2348 break;
2349 }
2350 return rd;
2351 }
2352
2353 static raw_data_t *long2raw_data(int i)
2354 {
2355 raw_data_t *rd;
2356 rd = new_raw_data();
2357 rd->size = sizeof(int);
2358 rd->data = (char *)xmalloc(rd->size);
2359 switch(byteorder)
2360 {
2361 #ifdef WORDS_BIGENDIAN
2362 default:
2363 #endif
2364 case WRC_BO_BIG:
2365 rd->data[0] = HIBYTE(HIWORD(i));
2366 rd->data[1] = LOBYTE(HIWORD(i));
2367 rd->data[2] = HIBYTE(LOWORD(i));
2368 rd->data[3] = LOBYTE(LOWORD(i));
2369 break;
2370
2371 #ifndef WORDS_BIGENDIAN
2372 default:
2373 #endif
2374 case WRC_BO_LITTLE:
2375 rd->data[3] = HIBYTE(HIWORD(i));
2376 rd->data[2] = LOBYTE(HIWORD(i));
2377 rd->data[1] = HIBYTE(LOWORD(i));
2378 rd->data[0] = LOBYTE(LOWORD(i));
2379 break;
2380 }
2381 return rd;
2382 }
2383
2384 static raw_data_t *str2raw_data(string_t *str)
2385 {
2386 raw_data_t *rd;
2387 rd = new_raw_data();
2388 rd->size = str->size * (str->type == str_char ? 1 : 2);
2389 rd->data = (char *)xmalloc(rd->size);
2390 if(str->type == str_char)
2391 memcpy(rd->data, str->str.cstr, rd->size);
2392 else if(str->type == str_unicode)
2393 {
2394 int i;
2395 switch(byteorder)
2396 {
2397 #ifdef WORDS_BIGENDIAN
2398 default:
2399 #endif
2400 case WRC_BO_BIG:
2401 for(i = 0; i < str->size; i++)
2402 {
2403 rd->data[2*i + 0] = HIBYTE((WORD)str->str.wstr[i]);
2404 rd->data[2*i + 1] = LOBYTE((WORD)str->str.wstr[i]);
2405 }
2406 break;
2407 #ifndef WORDS_BIGENDIAN
2408 default:
2409 #endif
2410 case WRC_BO_LITTLE:
2411 for(i = 0; i < str->size; i++)
2412 {
2413 rd->data[2*i + 1] = HIBYTE((WORD)str->str.wstr[i]);
2414 rd->data[2*i + 0] = LOBYTE((WORD)str->str.wstr[i]);
2415 }
2416 break;
2417 }
2418 }
2419 else
2420 internal_error(__FILE__, __LINE__, "Invalid stringtype");
2421 return rd;
2422 }
2423
2424 static raw_data_t *merge_raw_data(raw_data_t *r1, raw_data_t *r2)
2425 {
2426 r1->data = xrealloc(r1->data, r1->size + r2->size);
2427 memcpy(r1->data + r1->size, r2->data, r2->size);
2428 r1->size += r2->size;
2429 return r1;
2430 }
2431
2432 static raw_data_t *merge_raw_data_int(raw_data_t *r1, int i)
2433 {
2434 raw_data_t *t = int2raw_data(i);
2435 merge_raw_data(r1, t);
2436 free(t->data);
2437 free(t);
2438 return r1;
2439 }
2440
2441 static raw_data_t *merge_raw_data_long(raw_data_t *r1, int i)
2442 {
2443 raw_data_t *t = long2raw_data(i);
2444 merge_raw_data(r1, t);
2445 free(t->data);
2446 free(t);
2447 return r1;
2448 }
2449
2450 static raw_data_t *merge_raw_data_str(raw_data_t *r1, string_t *str)
2451 {
2452 raw_data_t *t = str2raw_data(str);
2453 merge_raw_data(r1, t);
2454 free(t->data);
2455 free(t);
2456 return r1;
2457 }
2458
2459 /* Function the go back in a list to get the head */
2460 static menu_item_t *get_item_head(menu_item_t *p)
2461 {
2462 if(!p)
2463 return NULL;
2464 while(p->prev)
2465 p = p->prev;
2466 return p;
2467 }
2468
2469 static menuex_item_t *get_itemex_head(menuex_item_t *p)
2470 {
2471 if(!p)
2472 return NULL;
2473 while(p->prev)
2474 p = p->prev;
2475 return p;
2476 }
2477
2478 static resource_t *get_resource_head(resource_t *p)
2479 {
2480 if(!p)
2481 return NULL;
2482 while(p->prev)
2483 p = p->prev;
2484 return p;
2485 }
2486
2487 static ver_block_t *get_ver_block_head(ver_block_t *p)
2488 {
2489 if(!p)
2490 return NULL;
2491 while(p->prev)
2492 p = p->prev;
2493 return p;
2494 }
2495
2496 static ver_value_t *get_ver_value_head(ver_value_t *p)
2497 {
2498 if(!p)
2499 return NULL;
2500 while(p->prev)
2501 p = p->prev;
2502 return p;
2503 }
2504
2505 static control_t *get_control_head(control_t *p)
2506 {
2507 if(!p)
2508 return NULL;
2509 while(p->prev)
2510 p = p->prev;
2511 return p;
2512 }
2513
2514 static event_t *get_event_head(event_t *p)
2515 {
2516 if(!p)
2517 return NULL;
2518 while(p->prev)
2519 p = p->prev;
2520 return p;
2521 }
2522
2523 /* Find a stringtable with given language */
2524 static stringtable_t *find_stringtable(lvc_t *lvc)
2525 {
2526 stringtable_t *stt;
2527
2528 assert(lvc != NULL);
2529
2530 if(!lvc->language)
2531 lvc->language = dup_language(currentlanguage);
2532
2533 for(stt = sttres; stt; stt = stt->next)
2534 {
2535 if(stt->lvc.language->id == lvc->language->id
2536 && stt->lvc.language->sub == lvc->language->sub)
2537 {
2538 /* Found a table with the same language */
2539 /* The version and characteristics are now handled
2540 * in the generation of the individual stringtables.
2541 * This enables localized analysis.
2542 if((stt->lvc.version && lvc->version && *(stt->lvc.version) != *(lvc->version))
2543 || (!stt->lvc.version && lvc->version)
2544 || (stt->lvc.version && !lvc->version))
2545 yywarning("Stringtable's versions are not the same, using first definition");
2546
2547 if((stt->lvc.characts && lvc->characts && *(stt->lvc.characts) != *(lvc->characts))
2548 || (!stt->lvc.characts && lvc->characts)
2549 || (stt->lvc.characts && !lvc->characts))
2550 yywarning("Stringtable's characteristics are not the same, using first definition");
2551 */
2552 return stt;
2553 }
2554 }
2555 return NULL;
2556 }
2557
2558 /* qsort sorting function for string table entries */
2559 #define STE(p) ((stt_entry_t *)(p))
2560 static int sort_stt_entry(const void *e1, const void *e2)
2561 {
2562 return STE(e1)->id - STE(e2)->id;
2563 }
2564 #undef STE
2565
2566 static resource_t *build_stt_resources(stringtable_t *stthead)
2567 {
2568 stringtable_t *stt;
2569 stringtable_t *newstt;
2570 resource_t *rsc;
2571 resource_t *rsclist = NULL;
2572 resource_t *rsctail = NULL;
2573 int i;
2574 int j;
2575 DWORD andsum;
2576 DWORD orsum;
2577 characts_t *characts;
2578 version_t *version;
2579
2580 if(!stthead)
2581 return NULL;
2582
2583 /* For all languages defined */
2584 for(stt = stthead; stt; stt = stt->next)
2585 {
2586 assert(stt->nentries > 0);
2587
2588 /* Sort the entries */
2589 if(stt->nentries > 1)
2590 qsort(stt->entries, stt->nentries, sizeof(stt->entries[0]), sort_stt_entry);
2591
2592 for(i = 0; i < stt->nentries; )
2593 {
2594 newstt = new_stringtable(&stt->lvc);
2595 newstt->entries = (stt_entry_t *)xmalloc(16 * sizeof(stt_entry_t));
2596 newstt->nentries = 16;
2597 newstt->idbase = stt->entries[i].id & ~0xf;
2598 for(j = 0; j < 16 && i < stt->nentries; j++)
2599 {
2600 if(stt->entries[i].id - newstt->idbase == j)
2601 {
2602 newstt->entries[j] = stt->entries[i];
2603 i++;
2604 }
2605 }
2606 andsum = ~0;
2607 orsum = 0;
2608 characts = NULL;
2609 version = NULL;
2610 /* Check individual memory options and get
2611 * the first characteristics/version
2612 */
2613 for(j = 0; j < 16; j++)
2614 {
2615 if(!newstt->entries[j].str)
2616 continue;
2617 andsum &= newstt->entries[j].memopt;
2618 orsum |= newstt->entries[j].memopt;
2619 if(!characts)
2620 characts = newstt->entries[j].characts;
2621 if(!version)
2622 version = newstt->entries[j].version;
2623 }
2624 if(andsum != orsum)
2625 {
2626 warning("Stringtable's memory options are not equal (idbase: %d)", newstt->idbase);
2627 }
2628 /* Check version and characteristics */
2629 for(j = 0; j < 16; j++)
2630 {
2631 if(characts
2632 && newstt->entries[j].characts
2633 && *newstt->entries[j].characts != *characts)
2634 warning("Stringtable's characteristics are not the same (idbase: %d)", newstt->idbase);
2635 if(version
2636 && newstt->entries[j].version
2637 && *newstt->entries[j].version != *version)
2638 warning("Stringtable's versions are not the same (idbase: %d)", newstt->idbase);
2639 }
2640 rsc = new_resource(res_stt, newstt, newstt->memopt, newstt->lvc.language);
2641 rsc->name = new_name_id();
2642 rsc->name->type = name_ord;
2643 rsc->name->name.i_name = (newstt->idbase >> 4) + 1;
2644 rsc->memopt = andsum; /* Set to least common denominator */
2645 newstt->memopt = andsum;
2646 newstt->lvc.characts = characts;
2647 newstt->lvc.version = version;
2648 if(!rsclist)
2649 {
2650 rsclist = rsc;
2651 rsctail = rsc;
2652 }
2653 else
2654 {
2655 rsctail->next = rsc;
2656 rsc->prev = rsctail;
2657 rsctail = rsc;
2658 }
2659 }
2660 }
2661 return rsclist;
2662 }
2663
2664
2665 static toolbar_item_t *ins_tlbr_button(toolbar_item_t *prev, toolbar_item_t *idrec)
2666 {
2667 idrec->prev = prev;
2668 if(prev)
2669 prev->next = idrec;
2670
2671 return idrec;
2672 }
2673
2674 static toolbar_item_t *get_tlbr_buttons_head(toolbar_item_t *p, int *nitems)
2675 {
2676 if(!p)
2677 {
2678 *nitems = 0;
2679 return NULL;
2680 }
2681
2682 *nitems = 1;
2683
2684 while(p->prev)
2685 {
2686 (*nitems)++;
2687 p = p->prev;
2688 }
2689
2690 return p;
2691 }
2692
2693 static string_t *make_filename(string_t *str)
2694 {
2695 if(str->type == str_char)
2696 {
2697 char *cptr;
2698
2699 /* Remove escaped backslash and convert to forward */
2700 for(cptr = str->str.cstr; (cptr = strchr(cptr, '\\')) != NULL; cptr++)
2701 {
2702 if(cptr[1] == '\\')
2703 {
2704 memmove(cptr, cptr+1, strlen(cptr));
2705 str->size--;
2706 }
2707 *cptr = '/';
2708 }
2709 }
2710 else
2711 {
2712 WCHAR *wptr;
2713
2714 /* Remove escaped backslash and convert to forward */
2715 for(wptr = str->str.wstr; (wptr = strchrW(wptr, '\\')) != NULL; wptr++)
2716 {
2717 if(wptr[1] == '\\')
2718 {
2719 memmove(wptr, wptr+1, strlenW(wptr));
2720 str->size--;
2721 }
2722 *wptr = '/';
2723 }
2724 }
2725 return str;
2726 }
2727
2728 /*
2729 * Process all resources to extract fonts and build
2730 * a fontdir resource.
2731 *
2732 * Note: MS' resource compiler (build 1472) does not
2733 * handle font resources with different languages.
2734 * The fontdir is generated in the last active language
2735 * and font identifiers must be unique across the entire
2736 * source.
2737 * This is not logical considering the localization
2738 * constraints of all other resource types. MS has,
2739 * most probably, never testet localized fonts. However,
2740 * using fontresources is rare, so it might not occur
2741 * in normal applications.
2742 * Wine does require better localization because a lot
2743 * of languages are coded into the same executable.
2744 * Therefore, I will generate fontdirs for *each*
2745 * localized set of fonts.
2746 */
2747 static resource_t *build_fontdir(resource_t **fnt, int nfnt)
2748 {
2749 static int once = 0;
2750 if(!once)
2751 {
2752 warning("Need to parse fonts, not yet implemented (fnt: %p, nfnt: %d)", fnt, nfnt);
2753 once++;
2754 }
2755 return NULL;
2756 }
2757
2758 static resource_t *build_fontdirs(resource_t *tail)
2759 {
2760 resource_t *rsc;
2761 resource_t *lst = NULL;
2762 resource_t **fnt = NULL; /* List of all fonts */
2763 int nfnt = 0;
2764 resource_t **fnd = NULL; /* List of all fontdirs */
2765 int nfnd = 0;
2766 resource_t **lanfnt = NULL;
2767 int nlanfnt = 0;
2768 int i;
2769 name_id_t nid;
2770 string_t str;
2771 int fntleft;
2772
2773 nid.type = name_str;
2774 nid.name.s_name = &str;
2775 str.type = str_char;
2776 str.str.cstr = xstrdup("FONTDIR");
2777 str.size = 7;
2778
2779 /* Extract all fonts and fontdirs */
2780 for(rsc = tail; rsc; rsc = rsc->prev)
2781 {
2782 if(rsc->type == res_fnt)
2783 {
2784 nfnt++;
2785 fnt = xrealloc(fnt, nfnt * sizeof(*fnt));
2786 fnt[nfnt-1] = rsc;
2787 }
2788 else if(rsc->type == res_fntdir)
2789 {
2790 nfnd++;
2791 fnd = xrealloc(fnd, nfnd * sizeof(*fnd));
2792 fnd[nfnd-1] = rsc;
2793 }
2794 }
2795
2796 /* Verify the name of the present fontdirs */
2797 for(i = 0; i < nfnd; i++)
2798 {
2799 if(compare_name_id(&nid, fnd[i]->name))
2800 {
2801 warning("User supplied FONTDIR entry has an invalid name '%s', ignored",
2802 get_nameid_str(fnd[i]->name));
2803 fnd[i] = NULL;
2804 }
2805 }
2806
2807 /* Sanity check */
2808 if(nfnt == 0)
2809 {
2810 if(nfnd != 0)
2811 warning("Found %d FONTDIR entries without any fonts present", nfnd);
2812 goto clean;
2813 }
2814
2815 /* Copy space */
2816 lanfnt = xmalloc(nfnt * sizeof(*lanfnt));
2817
2818 /* Get all fonts covered by fontdirs */
2819 for(i = 0; i < nfnd; i++)
2820 {
2821 int j;
2822 WORD cnt;
2823 int isswapped = 0;
2824
2825 if(!fnd[i])
2826 continue;
2827 for(j = 0; j < nfnt; j++)
2828 {
2829 if(!fnt[j])
2830 continue;
2831 if(fnt[j]->lan->id == fnd[i]->lan->id && fnt[j]->lan->sub == fnd[i]->lan->sub)
2832 {
2833 lanfnt[nlanfnt] = fnt[j];
2834 nlanfnt++;
2835 fnt[j] = NULL;
2836 }
2837 }
2838
2839 cnt = *(WORD *)fnd[i]->res.fnd->data->data;
2840 if(nlanfnt == cnt)
2841 isswapped = 0;
2842 else if(nlanfnt == BYTESWAP_WORD(cnt))
2843 isswapped = 1;
2844 else
2845 error("FONTDIR for language %d,%d has wrong count (%d, expected %d)",
2846 fnd[i]->lan->id, fnd[i]->lan->sub, cnt, nlanfnt);
2847 #ifdef WORDS_BIGENDIAN
2848 if((byteorder == WRC_BO_LITTLE && !isswapped) || (byteorder != WRC_BO_LITTLE && isswapped))
2849 #else
2850 if((byteorder == WRC_BO_BIG && !isswapped) || (byteorder != WRC_BO_BIG && isswapped))
2851 #endif
2852 {
2853 internal_error(__FILE__, __LINE__, "User supplied FONTDIR needs byteswapping");
2854 }
2855 }
2856
2857 /* We now have fonts left where we need to make a fontdir resource */
2858 for(i = fntleft = 0; i < nfnt; i++)
2859 {
2860 if(fnt[i])
2861 fntleft++;
2862 }
2863 while(fntleft)
2864 {
2865 /* Get fonts of same language in lanfnt[] */
2866 for(i = nlanfnt = 0; i < nfnt; i++)
2867 {
2868 if(fnt[i])
2869 {
2870 if(!nlanfnt)
2871 {
2872 addlanfnt:
2873 lanfnt[nlanfnt] = fnt[i];
2874 nlanfnt++;
2875 fnt[i] = NULL;
2876 fntleft--;
2877 }
2878 else if(fnt[i]->lan->id == lanfnt[0]->lan->id && fnt[i]->lan->sub == lanfnt[0]->lan->sub)
2879 goto addlanfnt;
2880 }
2881 }
2882 /* and build a fontdir */
2883 rsc = build_fontdir(lanfnt, nlanfnt);
2884 if(rsc)
2885 {
2886 if(lst)
2887 {
2888 lst->next = rsc;
2889 rsc->prev = lst;
2890 }
2891 lst = rsc;
2892 }
2893 }
2894
2895 free(lanfnt);
2896 clean:
2897 if(fnt)
2898 free(fnt);
2899 if(fnd)
2900 free(fnd);
2901 free(str.str.cstr);
2902 return lst;
2903 }
2904
2905 /*
2906 * This gets invoked to determine whether the next resource
2907 * is to be of a standard-type (e.g. bitmaps etc.), or should
2908 * be a user-type resource. This function is required because
2909 * there is the _possibility_ of a lookahead token in the
2910 * parser, which is generated from the "expr" state in the
2911 * "nameid" parsing.
2912 *
2913 * The general resource format is:
2914 * <identifier> <type> <flags> <resourcebody>
2915 *
2916 * The <identifier> can either be tIDENT or "expr". The latter
2917 * will always generate a lookahead, which is the <type> of the
2918 * resource to parse. Otherwise, we need to get a new token from
2919 * the scanner to determine the next step.
2920 *
2921 * The problem arrises when <type> is numerical. This case should
2922 * map onto default resource-types and be parsed as such instead
2923 * of being mapped onto user-type resources.
2924 *
2925 * The trick lies in the fact that yacc (bison) doesn't care about
2926 * intermediate changes of the lookahead while reducing a rule. We
2927 * simply replace the lookahead with a token that will result in
2928 * a shift to the appropriate rule for the specific resource-type.
2929 */
2930 static int rsrcid_to_token(int lookahead)
2931 {
2932 int token;
2933 const char *type = "?";
2934
2935 /* Get a token if we don't have one yet */
2936 if(lookahead == YYEMPTY)
2937 lookahead = YYLEX;
2938
2939 /* Only numbers are possibly interesting */
2940 switch(lookahead)
2941 {
2942 case tNUMBER:
2943 case tLNUMBER:
2944 break;
2945 default:
2946 return lookahead;
2947 }
2948
2949 token = lookahead;
2950
2951 switch(yylval.num)
2952 {
2953 case WRC_RT_CURSOR:
2954 type = "CURSOR";
2955 token = tCURSOR;
2956 break;
2957 case WRC_RT_ICON:
2958 type = "ICON";
2959 token = tICON;
2960 break;
2961 case WRC_RT_BITMAP:
2962 type = "BITMAP";
2963 token = tBITMAP;
2964 break;
2965 case WRC_RT_FONT:
2966 type = "FONT";
2967 token = tFONT;
2968 break;
2969 case WRC_RT_FONTDIR:
2970 type = "FONTDIR";
2971 token = tFONTDIR;
2972 break;
2973 case WRC_RT_RCDATA:
2974 type = "RCDATA";
2975 token = tRCDATA;
2976 break;
2977 case WRC_RT_MESSAGETABLE:
2978 type = "MESSAGETABLE";
2979 token = tMESSAGETABLE;
2980 break;
2981 case WRC_RT_DLGINIT:
2982 type = "DLGINIT";
2983 token = tDLGINIT;
2984 break;
2985 case WRC_RT_ACCELERATOR:
2986 type = "ACCELERATOR";
2987 token = tACCELERATORS;
2988 break;
2989 case WRC_RT_MENU:
2990 type = "MENU";
2991 token = tMENU;
2992 break;
2993 case WRC_RT_DIALOG:
2994 type = "DIALOG";
2995 token = tDIALOG;
2996 break;
2997 case WRC_RT_VERSION:
2998 type = "VERSION";
2999 token = tVERSIONINFO;
3000 break;
3001 case WRC_RT_TOOLBAR:
3002 type = "TOOLBAR";
3003 token = tTOOLBAR;
3004 break;
3005
3006 case WRC_RT_STRING:
3007 type = "STRINGTABLE";
3008 break;
3009
3010 case WRC_RT_ANICURSOR:
3011 case WRC_RT_ANIICON:
3012 case WRC_RT_GROUP_CURSOR:
3013 case WRC_RT_GROUP_ICON:
3014 yywarning("Usertype uses reserved type ID %d, which is auto-generated", yylval.num);
3015 return lookahead;
3016
3017 case WRC_RT_DLGINCLUDE:
3018 case WRC_RT_PLUGPLAY:
3019 case WRC_RT_VXD:
3020 case WRC_RT_HTML:
3021 yywarning("Usertype uses reserved type ID %d, which is not supported by wrc yet", yylval.num);
3022 default:
3023 return lookahead;
3024 }
3025
3026 return token;
3027 }
A free Windows-compatible Operating System