projects / reactos.git / blob
? search:


80b781559779fa064693227e7f0dd223ba0dfeab
[reactos.git] / reactos / tools / widl / parser.y
1 %{
2 /*
3 * IDL Compiler
4 *
5 * Copyright 2002 Ove Kaaven
6 *
7 * This library is free software; you can redistribute it and/or
8 * modify it under the terms of the GNU Lesser General Public
9 * License as published by the Free Software Foundation; either
10 * version 2.1 of the License, or (at your option) any later version.
11 *
12 * This library is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 * Lesser General Public License for more details.
16 *
17 * You should have received a copy of the GNU Lesser General Public
18 * License along with this library; if not, write to the Free Software
19 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
20 */
21
22 #include "config.h"
23
24 #include <stdio.h>
25 #include <stdlib.h>
26 #include <stdarg.h>
27 #include <assert.h>
28 #include <ctype.h>
29 #include <string.h>
30 #ifdef HAVE_ALLOCA_H
31 #include <alloca.h>
32 #endif
33
34 #include "windef.h"
35
36 #include "widl.h"
37 #include "utils.h"
38 #include "parser.h"
39 #include "header.h"
40 #include "proxy.h"
41 #include "typelib.h"
42
43 #if defined(YYBYACC)
44 /* Berkeley yacc (byacc) doesn't seem to know about these */
45 /* Some *BSD supplied versions do define these though */
46 # ifndef YYEMPTY
47 # define YYEMPTY (-1) /* Empty lookahead value of yychar */
48 # endif
49 # ifndef YYLEX
50 # define YYLEX yylex()
51 # endif
52
53 #elif defined(YYBISON)
54 /* Bison was used for original development */
55 /* #define YYEMPTY -2 */
56 /* #define YYLEX yylex() */
57
58 #else
59 /* No yacc we know yet */
60 # if !defined(YYEMPTY) || !defined(YYLEX)
61 # error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
62 # elif defined(__GNUC__) /* gcc defines the #warning directive */
63 # warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
64 /* #else we just take a chance that it works... */
65 # endif
66 #endif
67
68 static attr_t *make_attr(enum attr_type type);
69 static attr_t *make_attrv(enum attr_type type, unsigned long val);
70 static attr_t *make_attrp(enum attr_type type, void *val);
71 static expr_t *make_expr(enum expr_type type);
72 static expr_t *make_exprl(enum expr_type type, long val);
73 static expr_t *make_exprs(enum expr_type type, char *val);
74 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
75 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
76 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
77 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
78 static type_t *make_type(unsigned char type, type_t *ref);
79 static typeref_t *make_tref(char *name, type_t *ref);
80 static typeref_t *uniq_tref(typeref_t *ref);
81 static type_t *type_ref(typeref_t *ref);
82 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
83 static ifref_t *make_ifref(type_t *iface);
84 static var_t *make_var(char *name);
85 static func_t *make_func(var_t *def, var_t *args);
86 static class_t *make_class(char *name);
87
88 static type_t *reg_type(type_t *type, char *name, int t);
89 static type_t *reg_types(type_t *type, var_t *names, int t);
90 static type_t *find_type(char *name, int t);
91 static type_t *find_type2(char *name, int t);
92 static type_t *get_type(unsigned char type, char *name, int t);
93 static type_t *get_typev(unsigned char type, var_t *name, int t);
94 static int get_struct_type(var_t *fields);
95
96 static var_t *reg_const(var_t *var);
97 static var_t *find_const(char *name, int f);
98
99 #define tsENUM 1
100 #define tsSTRUCT 2
101 #define tsUNION 3
102
103 static type_t std_bool = { "boolean" };
104 static type_t std_int = { "int" };
105 static type_t std_int64 = { "__int64" };
106 static type_t std_uhyper = { "MIDL_uhyper" };
107
108 %}
109 %union {
110 attr_t *attr;
111 expr_t *expr;
112 type_t *type;
113 typeref_t *tref;
114 var_t *var;
115 func_t *func;
116 ifref_t *ifref;
117 class_t *clas;
118 char *str;
119 UUID *uuid;
120 unsigned int num;
121 }
122
123 %token <str> aIDENTIFIER
124 %token <str> aKNOWNTYPE
125 %token <num> aNUM aHEXNUM
126 %token <str> aSTRING
127 %token <uuid> aUUID
128 %token aEOF
129 %token SHL SHR
130 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
131 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
132 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
133 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
134 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
135 %token tDEFAULT
136 %token tDEFAULTVALUE
137 %token tDISPINTERFACE
138 %token tDLLNAME tDOUBLE tDUAL
139 %token tENDPOINT
140 %token tENTRY tENUM tERRORSTATUST
141 %token tEXTERN
142 %token tFLOAT
143 %token tHANDLE
144 %token tHANDLET
145 %token tHELPCONTEXT tHELPFILE
146 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
147 %token tHIDDEN
148 %token tHYPER tID tIDEMPOTENT
149 %token tIIDIS
150 %token tIMPORT tIMPORTLIB
151 %token tIN tINCLUDE tINLINE
152 %token tINPUTSYNC
153 %token tINT tINT64
154 %token tINTERFACE
155 %token tLENGTHIS tLIBRARY
156 %token tLOCAL
157 %token tLONG
158 %token tMETHODS
159 %token tMODULE
160 %token tNONCREATABLE
161 %token tOBJECT tODL tOLEAUTOMATION
162 %token tOPTIONAL
163 %token tOUT
164 %token tPOINTERDEFAULT
165 %token tPROPERTIES
166 %token tPROPGET tPROPPUT tPROPPUTREF
167 %token tPUBLIC
168 %token tREADONLY tREF
169 %token tRESTRICTED
170 %token tRETVAL
171 %token tSHORT
172 %token tSIGNED
173 %token tSIZEIS tSIZEOF
174 %token tSOURCE
175 %token tSTDCALL
176 %token tSTRING tSTRUCT
177 %token tSWITCH tSWITCHIS tSWITCHTYPE
178 %token tTRANSMITAS
179 %token tTYPEDEF
180 %token tUNION
181 %token tUNIQUE
182 %token tUNSIGNED
183 %token tUUID
184 %token tV1ENUM
185 %token tVARARG
186 %token tVERSION
187 %token tVOID
188 %token tWCHAR tWIREMARSHAL
189
190 /* used in attr_t */
191 %token tPOINTERTYPE
192
193 %type <attr> m_attributes attributes attrib_list attribute
194 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
195 %type <expr> array array_list
196 %type <type> inherit interface interfacehdr interfacedef interfacedec
197 %type <type> dispinterface dispinterfacehdr dispinterfacedef
198 %type <type> module modulehdr moduledef
199 %type <type> base_type int_std
200 %type <type> enumdef structdef typedef uniondef
201 %type <ifref> gbl_statements coclass_ints coclass_int
202 %type <tref> type
203 %type <var> m_args no_args args arg
204 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
205 %type <var> m_ident t_ident ident p_ident pident pident_list
206 %type <var> dispint_props
207 %type <func> funcdef int_statements
208 %type <func> dispint_meths
209 %type <clas> coclass coclasshdr coclassdef
210 %type <num> pointer_type version
211 %type <str> libraryhdr
212
213 %left ','
214 %right COND
215 %left '|'
216 %left '&'
217 %left '-' '+'
218 %left '*' '/'
219 %left SHL SHR
220 %right '~'
221 %right CAST
222 %right PPTR
223 %right NEG
224
225 %%
226
227 input: gbl_statements { write_proxies($1); }
228 ;
229
230 gbl_statements: { $$ = NULL; }
231 | gbl_statements interfacedec { $$ = $1; }
232 | gbl_statements interfacedef { $$ = make_ifref($2); LINK($$, $1); }
233 | gbl_statements coclassdef { $$ = $1; add_coclass($2); }
234 | gbl_statements moduledef { $$ = $1; add_module($2); }
235 | gbl_statements librarydef { $$ = $1; }
236 | gbl_statements statement { $$ = $1; }
237 ;
238
239 imp_statements: {}
240 | imp_statements interfacedec { if (!parse_only) add_interface($2); }
241 | imp_statements interfacedef { if (!parse_only) add_interface($2); }
242 | imp_statements coclassdef { if (!parse_only) add_coclass($2); }
243 | imp_statements moduledef { if (!parse_only) add_module($2); }
244 | imp_statements statement {}
245 ;
246
247 int_statements: { $$ = NULL; }
248 | int_statements funcdef ';' { $$ = $2; LINK($$, $1); }
249 | int_statements statement { $$ = $1; }
250 ;
251
252 statement: ';' {}
253 | constdef ';' { if (!parse_only && do_header) { write_constdef($1); } }
254 | cppquote {}
255 | enumdef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
256 | externdef ';' { if (!parse_only && do_header) { write_externdef($1); } }
257 | import {}
258 | structdef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
259 | typedef ';' {}
260 | uniondef ';' { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
261 ;
262
263 cppquote: tCPPQUOTE '(' aSTRING ')' { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
264 ;
265 import_start: tIMPORT aSTRING ';' { assert(yychar == YYEMPTY);
266 if (!do_import($2)) yychar = aEOF; }
267 ;
268 import: import_start imp_statements aEOF {}
269 ;
270
271 libraryhdr: tLIBRARY aIDENTIFIER { $$ = $2; }
272 ;
273 library_start: attributes libraryhdr '{' { start_typelib($2, $1); }
274 ;
275 librarydef: library_start imp_statements '}' { end_typelib(); }
276 ;
277
278 m_args: { $$ = NULL; }
279 | args
280 ;
281
282 no_args: tVOID { $$ = NULL; }
283 ;
284
285 args: arg
286 | args ',' arg { LINK($3, $1); $$ = $3; }
287 | no_args
288 ;
289
290 /* split into two rules to get bison to resolve a tVOID conflict */
291 arg: attributes type pident array { $$ = $3;
292 set_type($$, $2, $4);
293 $$->attrs = $1;
294 }
295 | type pident array { $$ = $2;
296 set_type($$, $1, $3);
297 }
298 | attributes type pident '(' m_args ')' { $$ = $3;
299 $$->ptr_level--;
300 set_type($$, $2, NULL);
301 $$->attrs = $1;
302 $$->args = $5;
303 }
304 | type pident '(' m_args ')' { $$ = $2;
305 $$->ptr_level--;
306 set_type($$, $1, NULL);
307 $$->args = $4;
308 }
309 ;
310
311 array: { $$ = NULL; }
312 | '[' array_list ']' { $$ = $2; }
313 | '[' '*' ']' { $$ = make_expr(EXPR_VOID); }
314 ;
315
316 array_list: m_expr /* size of first dimension is optional */
317 | array_list ',' expr { LINK($3, $1); $$ = $3; }
318 | array_list ']' '[' expr { LINK($4, $1); $$ = $4; }
319 ;
320
321 m_attributes: { $$ = NULL; }
322 | attributes
323 ;
324
325 attributes:
326 '[' attrib_list ']' { $$ = $2; }
327 ;
328
329 attrib_list: attribute
330 | attrib_list ',' attribute { LINK($3, $1); $$ = $3; }
331 | attrib_list ']' '[' attribute { LINK($4, $1); $$ = $4; }
332 ;
333
334 attribute:
335 tASYNC { $$ = make_attr(ATTR_ASYNC); }
336 | tCALLAS '(' ident ')' { $$ = make_attrp(ATTR_CALLAS, $3); }
337 | tCASE '(' expr_list_const ')' { $$ = make_attrp(ATTR_CASE, $3); }
338 | tCONTEXTHANDLE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
339 | tCONTEXTHANDLENOSERIALIZE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
340 | tCONTEXTHANDLESERIALIZE { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
341 | tCONTROL { $$ = make_attr(ATTR_CONTROL); }
342 | tDEFAULT { $$ = make_attr(ATTR_DEFAULT); }
343 | tDEFAULTVALUE '(' expr_const ')' { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
344 | tDEFAULTVALUE '(' aSTRING ')' { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
345 | tDLLNAME '(' aSTRING ')' { $$ = make_attrp(ATTR_DLLNAME, $3); }
346 | tDUAL { $$ = make_attr(ATTR_DUAL); }
347 | tENDPOINT '(' aSTRING ')' { $$ = make_attrp(ATTR_ENDPOINT, $3); }
348 | tENTRY '(' aSTRING ')' { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
349 | tENTRY '(' expr_const ')' { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
350 | tHANDLE { $$ = make_attr(ATTR_HANDLE); }
351 | tHELPCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
352 | tHELPFILE '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPFILE, $3); }
353 | tHELPSTRING '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPSTRING, $3); }
354 | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
355 | tHELPSTRINGDLL '(' aSTRING ')' { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
356 | tHIDDEN { $$ = make_attr(ATTR_HIDDEN); }
357 | tID '(' expr_const ')' { $$ = make_attrp(ATTR_ID, $3); }
358 | tIDEMPOTENT { $$ = make_attr(ATTR_IDEMPOTENT); }
359 | tIIDIS '(' ident ')' { $$ = make_attrp(ATTR_IIDIS, $3); }
360 | tIN { $$ = make_attr(ATTR_IN); }
361 | tINPUTSYNC { $$ = make_attr(ATTR_INPUTSYNC); }
362 | tLENGTHIS '(' m_exprs ')' { $$ = make_attrp(ATTR_LENGTHIS, $3); }
363 | tLOCAL { $$ = make_attr(ATTR_LOCAL); }
364 | tNONCREATABLE { $$ = make_attr(ATTR_NONCREATABLE); }
365 | tOBJECT { $$ = make_attr(ATTR_OBJECT); }
366 | tODL { $$ = make_attr(ATTR_ODL); }
367 | tOLEAUTOMATION { $$ = make_attr(ATTR_OLEAUTOMATION); }
368 | tOPTIONAL { $$ = make_attr(ATTR_OPTIONAL); }
369 | tOUT { $$ = make_attr(ATTR_OUT); }
370 | tPOINTERDEFAULT '(' pointer_type ')' { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
371 | tPROPGET { $$ = make_attr(ATTR_PROPGET); }
372 | tPROPPUT { $$ = make_attr(ATTR_PROPPUT); }
373 | tPROPPUTREF { $$ = make_attr(ATTR_PROPPUTREF); }
374 | tPUBLIC { $$ = make_attr(ATTR_PUBLIC); }
375 | tREADONLY { $$ = make_attr(ATTR_READONLY); }
376 | tRESTRICTED { $$ = make_attr(ATTR_RESTRICTED); }
377 | tRETVAL { $$ = make_attr(ATTR_RETVAL); }
378 | tSIZEIS '(' m_exprs ')' { $$ = make_attrp(ATTR_SIZEIS, $3); }
379 | tSOURCE { $$ = make_attr(ATTR_SOURCE); }
380 | tSTRING { $$ = make_attr(ATTR_STRING); }
381 | tSWITCHIS '(' expr ')' { $$ = make_attrp(ATTR_SWITCHIS, $3); }
382 | tSWITCHTYPE '(' type ')' { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
383 | tTRANSMITAS '(' type ')' { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
384 | tUUID '(' aUUID ')' { $$ = make_attrp(ATTR_UUID, $3); }
385 | tV1ENUM { $$ = make_attr(ATTR_V1ENUM); }
386 | tVARARG { $$ = make_attr(ATTR_VARARG); }
387 | tVERSION '(' version ')' { $$ = make_attrv(ATTR_VERSION, $3); }
388 | tWIREMARSHAL '(' type ')' { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
389 | pointer_type { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
390 ;
391
392 callconv:
393 | tSTDCALL
394 ;
395
396 cases: { $$ = NULL; }
397 | cases case { if ($2) { LINK($2, $1); $$ = $2; }
398 else { $$ = $1; }
399 }
400 ;
401
402 case: tCASE expr ':' field { attr_t *a = make_attrp(ATTR_CASE, $2);
403 $$ = $4; if (!$$) $$ = make_var(NULL);
404 LINK(a, $$->attrs); $$->attrs = a;
405 }
406 | tDEFAULT ':' field { attr_t *a = make_attr(ATTR_DEFAULT);
407 $$ = $3; if (!$$) $$ = make_var(NULL);
408 LINK(a, $$->attrs); $$->attrs = a;
409 }
410 ;
411
412 constdef: tCONST type ident '=' expr_const { $$ = reg_const($3);
413 set_type($$, $2, NULL);
414 $$->eval = $5;
415 $$->lval = $5->cval;
416 }
417 ;
418
419 enums: { $$ = NULL; }
420 | enum_list ',' { $$ = $1; }
421 | enum_list
422 ;
423
424 enum_list: enum
425 | enum_list ',' enum { LINK($3, $1); $$ = $3;
426 if ($1 && !$3->eval)
427 $3->lval = $1->lval + 1;
428 }
429 ;
430
431 enum: ident '=' expr_const { $$ = reg_const($1);
432 $$->eval = $3;
433 $$->lval = $3->cval;
434 $$->type = make_type(RPC_FC_LONG, &std_int);
435 }
436 | ident { $$ = reg_const($1);
437 $$->lval = 0; /* default for first enum entry */
438 $$->type = make_type(RPC_FC_LONG, &std_int);
439 }
440 ;
441
442 enumdef: tENUM t_ident '{' enums '}' { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
443 $$->fields = $4;
444 $$->defined = TRUE;
445 if(in_typelib)
446 add_enum($$);
447 }
448 ;
449
450 m_exprs: m_expr
451 | m_exprs ',' m_expr { LINK($3, $1); $$ = $3; }
452 ;
453
454 /*
455 exprs: { $$ = make_expr(EXPR_VOID); }
456 | expr_list
457 ;
458
459 expr_list: expr
460 | expr_list ',' expr { LINK($3, $1); $$ = $3; }
461 ;
462 */
463
464 m_expr: { $$ = make_expr(EXPR_VOID); }
465 | expr
466 ;
467
468 expr: aNUM { $$ = make_exprl(EXPR_NUM, $1); }
469 | aHEXNUM { $$ = make_exprl(EXPR_HEXNUM, $1); }
470 | aIDENTIFIER { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
471 | expr '?' expr ':' expr %prec COND { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
472 | expr '|' expr { $$ = make_expr2(EXPR_OR , $1, $3); }
473 | expr '&' expr { $$ = make_expr2(EXPR_AND, $1, $3); }
474 | expr '+' expr { $$ = make_expr2(EXPR_ADD, $1, $3); }
475 | expr '-' expr { $$ = make_expr2(EXPR_SUB, $1, $3); }
476 | expr '*' expr { $$ = make_expr2(EXPR_MUL, $1, $3); }
477 | expr '/' expr { $$ = make_expr2(EXPR_DIV, $1, $3); }
478 | expr SHL expr { $$ = make_expr2(EXPR_SHL, $1, $3); }
479 | expr SHR expr { $$ = make_expr2(EXPR_SHR, $1, $3); }
480 | '~' expr { $$ = make_expr1(EXPR_NOT, $2); }
481 | '-' expr %prec NEG { $$ = make_expr1(EXPR_NEG, $2); }
482 | '*' expr %prec PPTR { $$ = make_expr1(EXPR_PPTR, $2); }
483 | '(' type ')' expr %prec CAST { $$ = make_exprt(EXPR_CAST, $2, $4); }
484 | tSIZEOF '(' type ')' { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
485 | '(' expr ')' { $$ = $2; }
486 ;
487
488 expr_list_const: expr_const
489 | expr_list_const ',' expr_const { LINK($3, $1); $$ = $3; }
490 ;
491
492 expr_const: expr { $$ = $1;
493 if (!$$->is_const) yyerror("expression is not constant\n");
494 }
495 ;
496
497 externdef: tEXTERN tCONST type ident { $$ = $4;
498 set_type($$, $3, NULL);
499 }
500 ;
501
502 fields: { $$ = NULL; }
503 | fields field { if ($2) { LINK($2, $1); $$ = $2; }
504 else { $$ = $1; }
505 }
506 ;
507
508 field: s_field ';' { $$ = $1; }
509 | m_attributes uniondef ';' { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
510 | attributes ';' { $$ = make_var(NULL); $$->attrs = $1; }
511 | ';' { $$ = NULL; }
512 ;
513
514 s_field: m_attributes type pident array { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
515 ;
516
517 funcdef:
518 m_attributes type callconv pident
519 '(' m_args ')' { set_type($4, $2, NULL);
520 $4->attrs = $1;
521 $$ = make_func($4, $6);
522 if (is_attr($4->attrs, ATTR_IN)) {
523 yyerror("Inapplicable attribute");
524 }
525 }
526 ;
527
528 m_ident: { $$ = NULL; }
529 | ident
530 ;
531
532 t_ident: { $$ = NULL; }
533 | aIDENTIFIER { $$ = make_var($1); }
534 | aKNOWNTYPE { $$ = make_var($1); }
535 ;
536
537 ident: aIDENTIFIER { $$ = make_var($1); }
538 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
539 | aKNOWNTYPE { $$ = make_var($<str>1); }
540 | tID { $$ = make_var($<str>1); }
541 | tRETVAL { $$ = make_var($<str>1); }
542 | tVERSION { $$ = make_var($<str>1); }
543 ;
544
545 base_type: tBYTE { $$ = make_type(RPC_FC_BYTE, NULL); }
546 | tWCHAR { $$ = make_type(RPC_FC_WCHAR, NULL); }
547 | int_std
548 | tSIGNED int_std { $$ = $2; $$->sign = 1; }
549 | tUNSIGNED int_std { $$ = $2; $$->sign = -1;
550 switch ($$->type) {
551 case RPC_FC_CHAR: $$->type = RPC_FC_BYTE; $$->sign = 0; break;
552 case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
553 case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
554 case RPC_FC_LONG: $$->type = RPC_FC_ULONG; break;
555 case RPC_FC_HYPER:
556 if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
557 break;
558 default: break;
559 }
560 }
561 | tFLOAT { $$ = make_type(RPC_FC_FLOAT, NULL); }
562 | tDOUBLE { $$ = make_type(RPC_FC_DOUBLE, NULL); }
563 | tBOOLEAN { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
564 | tERRORSTATUST { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
565 | tHANDLET { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
566 ;
567
568 m_int:
569 | tINT
570 ;
571
572 int_std: tINT { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
573 | tSHORT m_int { $$ = make_type(RPC_FC_SHORT, NULL); }
574 | tLONG m_int { $$ = make_type(RPC_FC_LONG, NULL); }
575 | tHYPER m_int { $$ = make_type(RPC_FC_HYPER, NULL); }
576 | tINT64 { $$ = make_type(RPC_FC_HYPER, &std_int64); }
577 | tCHAR { $$ = make_type(RPC_FC_CHAR, NULL); }
578 ;
579
580 coclass: tCOCLASS aIDENTIFIER { $$ = make_class($2); }
581 | tCOCLASS aKNOWNTYPE { $$ = make_class($2); }
582 ;
583
584 coclasshdr: attributes coclass { $$ = $2;
585 $$->attrs = $1;
586 if (!parse_only && do_header) write_coclass($$);
587 }
588 ;
589
590 coclassdef: coclasshdr '{' coclass_ints '}' { $$ = $1;
591 $$->ifaces = $3;
592 }
593 ;
594
595 coclass_ints: { $$ = NULL; }
596 | coclass_ints coclass_int { LINK($2, $1); $$ = $2; }
597 ;
598
599 coclass_int:
600 m_attributes interfacedec { $$ = make_ifref($2); $$->attrs = $1; }
601 ;
602
603 dispinterface: tDISPINTERFACE aIDENTIFIER { $$ = get_type(0, $2, 0); }
604 | tDISPINTERFACE aKNOWNTYPE { $$ = get_type(0, $2, 0); }
605 ;
606
607 dispinterfacehdr: attributes dispinterface { $$ = $2;
608 if ($$->defined) yyerror("multiple definition error\n");
609 $$->attrs = $1;
610 $$->attrs = make_attr(ATTR_DISPINTERFACE);
611 LINK($$->attrs, $1);
612 $$->ref = find_type("IDispatch", 0);
613 if (!$$->ref) yyerror("IDispatch is undefined\n");
614 $$->defined = TRUE;
615 if (!parse_only && do_header) write_forward($$);
616 }
617 ;
618
619 dispint_props: tPROPERTIES ':' { $$ = NULL; }
620 | dispint_props s_field ';' { LINK($2, $1); $$ = $2; }
621 ;
622
623 dispint_meths: tMETHODS ':' { $$ = NULL; }
624 | dispint_meths funcdef ';' { LINK($2, $1); $$ = $2; }
625 ;
626
627 dispinterfacedef: dispinterfacehdr '{'
628 dispint_props
629 dispint_meths
630 '}' { $$ = $1;
631 $$->fields = $3;
632 $$->funcs = $4;
633 if (!parse_only && do_header) write_dispinterface($$);
634 }
635 /* FIXME: not sure how to handle this yet
636 | dispinterfacehdr '{' interface '}' { $$ = $1;
637 if (!parse_only && do_header) write_interface($$);
638 }
639 */
640 ;
641
642 inherit: { $$ = NULL; }
643 | ':' aKNOWNTYPE { $$ = find_type2($2, 0); }
644 ;
645
646 interface: tINTERFACE aIDENTIFIER { $$ = get_type(RPC_FC_IP, $2, 0); }
647 | tINTERFACE aKNOWNTYPE { $$ = get_type(RPC_FC_IP, $2, 0); }
648 ;
649
650 interfacehdr: attributes interface { $$ = $2;
651 if ($$->defined) yyerror("multiple definition error\n");
652 $$->attrs = $1;
653 $$->defined = TRUE;
654 if (!parse_only && do_header) write_forward($$);
655 }
656 ;
657
658 interfacedef: interfacehdr inherit
659 '{' int_statements '}' { $$ = $1;
660 $$->ref = $2;
661 $$->funcs = $4;
662 if (!parse_only && do_header) write_interface($$);
663 }
664 /* MIDL is able to import the definition of a base class from inside the
665 * definition of a derived class, I'll try to support it with this rule */
666 | interfacehdr ':' aIDENTIFIER
667 '{' import int_statements '}' { $$ = $1;
668 $$->ref = find_type2($3, 0);
669 if (!$$->ref) yyerror("base class %s not found in import\n", $3);
670 $$->funcs = $6;
671 if (!parse_only && do_header) write_interface($$);
672 }
673 | dispinterfacedef { $$ = $1; }
674 ;
675
676 interfacedec:
677 interface ';' { $$ = $1; if (!parse_only && do_header) write_forward($$); }
678 | dispinterface ';' { $$ = $1; if (!parse_only && do_header) write_forward($$); }
679 ;
680
681 module: tMODULE aIDENTIFIER { $$ = make_type(0, NULL); $$->name = $2; }
682 | tMODULE aKNOWNTYPE { $$ = make_type(0, NULL); $$->name = $2; }
683 ;
684
685 modulehdr: attributes module { $$ = $2;
686 $$->attrs = $1;
687 }
688 ;
689
690 moduledef: modulehdr '{' int_statements '}' { $$ = $1;
691 $$->funcs = $3;
692 /* FIXME: if (!parse_only && do_header) write_module($$); */
693 }
694 ;
695
696 p_ident: '*' pident %prec PPTR { $$ = $2; $$->ptr_level++; }
697 | tCONST p_ident { $$ = $2; /* FIXME */ }
698 ;
699
700 pident: ident
701 | p_ident
702 | '(' pident ')' { $$ = $2; }
703 ;
704
705 pident_list:
706 pident
707 | pident_list ',' pident { LINK($3, $1); $$ = $3; }
708 ;
709
710 pointer_type:
711 tREF { $$ = RPC_FC_RP; }
712 | tUNIQUE { $$ = RPC_FC_UP; }
713 ;
714
715 structdef: tSTRUCT t_ident '{' fields '}' { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
716 /* overwrite RPC_FC_STRUCT with a more exact type */
717 $$->type = get_struct_type( $4 );
718 $$->fields = $4;
719 $$->defined = TRUE;
720 if(in_typelib)
721 add_struct($$);
722 }
723 ;
724
725 type: tVOID { $$ = make_tref(NULL, make_type(0, NULL)); }
726 | aKNOWNTYPE { $$ = make_tref($1, find_type($1, 0)); }
727 | base_type { $$ = make_tref(NULL, $1); }
728 | tCONST type { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
729 | enumdef { $$ = make_tref(NULL, $1); }
730 | tENUM aIDENTIFIER { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
731 | structdef { $$ = make_tref(NULL, $1); }
732 | tSTRUCT aIDENTIFIER { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
733 | uniondef { $$ = make_tref(NULL, $1); }
734 | tUNION aIDENTIFIER { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
735 ;
736
737 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
738 $4->tname = tref->name;
739 tref->name = NULL;
740 $$ = type_ref(tref);
741 $$->attrs = $2;
742 if (!parse_only && do_header) write_typedef($$, $4);
743 if (in_typelib && $$->attrs)
744 add_typedef($$, $4);
745 reg_types($$, $4, 0);
746 }
747 ;
748
749 uniondef: tUNION t_ident '{' fields '}' { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
750 $$->fields = $4;
751 $$->defined = TRUE;
752 }
753 | tUNION t_ident
754 tSWITCH '(' s_field ')'
755 m_ident '{' cases '}' { var_t *u = $7;
756 $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
757 if (!u) u = make_var("tagged_union");
758 u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
759 u->type->fields = $9;
760 u->type->defined = TRUE;
761 LINK(u, $5); $$->fields = u;
762 $$->defined = TRUE;
763 }
764 ;
765
766 version:
767 aNUM { $$ = MAKELONG($1, 0); }
768 | aNUM '.' aNUM { $$ = MAKELONG($1, $3); }
769 ;
770
771 %%
772
773 static attr_t *make_attr(enum attr_type type)
774 {
775 attr_t *a = xmalloc(sizeof(attr_t));
776 a->type = type;
777 a->u.ival = 0;
778 INIT_LINK(a);
779 return a;
780 }
781
782 static attr_t *make_attrv(enum attr_type type, unsigned long val)
783 {
784 attr_t *a = xmalloc(sizeof(attr_t));
785 a->type = type;
786 a->u.ival = val;
787 INIT_LINK(a);
788 return a;
789 }
790
791 static attr_t *make_attrp(enum attr_type type, void *val)
792 {
793 attr_t *a = xmalloc(sizeof(attr_t));
794 a->type = type;
795 a->u.pval = val;
796 INIT_LINK(a);
797 return a;
798 }
799
800 static expr_t *make_expr(enum expr_type type)
801 {
802 expr_t *e = xmalloc(sizeof(expr_t));
803 e->type = type;
804 e->ref = NULL;
805 e->u.lval = 0;
806 e->is_const = FALSE;
807 INIT_LINK(e);
808 return e;
809 }
810
811 static expr_t *make_exprl(enum expr_type type, long val)
812 {
813 expr_t *e = xmalloc(sizeof(expr_t));
814 e->type = type;
815 e->ref = NULL;
816 e->u.lval = val;
817 e->is_const = FALSE;
818 INIT_LINK(e);
819 /* check for numeric constant */
820 if (type == EXPR_NUM || type == EXPR_HEXNUM) {
821 e->is_const = TRUE;
822 e->cval = val;
823 }
824 return e;
825 }
826
827 static expr_t *make_exprs(enum expr_type type, char *val)
828 {
829 expr_t *e;
830 e = xmalloc(sizeof(expr_t));
831 e->type = type;
832 e->ref = NULL;
833 e->u.sval = val;
834 e->is_const = FALSE;
835 INIT_LINK(e);
836 /* check for predefined constants */
837 if (type == EXPR_IDENTIFIER) {
838 var_t *c = find_const(val, 0);
839 if (c) {
840 e->u.sval = c->name;
841 free(val);
842 e->is_const = TRUE;
843 e->cval = c->lval;
844 }
845 }
846 return e;
847 }
848
849 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
850 {
851 expr_t *e;
852 e = xmalloc(sizeof(expr_t));
853 e->type = type;
854 e->ref = expr;
855 e->u.tref = tref;
856 e->is_const = FALSE;
857 INIT_LINK(e);
858 /* check for cast of constant expression */
859 if (type == EXPR_CAST && expr->is_const) {
860 e->is_const = TRUE;
861 e->cval = expr->cval;
862 }
863 return e;
864 }
865
866 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
867 {
868 expr_t *e;
869 e = xmalloc(sizeof(expr_t));
870 e->type = type;
871 e->ref = expr;
872 e->u.lval = 0;
873 e->is_const = FALSE;
874 INIT_LINK(e);
875 /* check for compile-time optimization */
876 if (expr->is_const) {
877 e->is_const = TRUE;
878 switch (type) {
879 case EXPR_NEG:
880 e->cval = -expr->cval;
881 break;
882 case EXPR_NOT:
883 e->cval = ~expr->cval;
884 break;
885 default:
886 e->is_const = FALSE;
887 break;
888 }
889 }
890 return e;
891 }
892
893 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
894 {
895 expr_t *e;
896 e = xmalloc(sizeof(expr_t));
897 e->type = type;
898 e->ref = expr1;
899 e->u.ext = expr2;
900 e->is_const = FALSE;
901 INIT_LINK(e);
902 /* check for compile-time optimization */
903 if (expr1->is_const && expr2->is_const) {
904 e->is_const = TRUE;
905 switch (type) {
906 case EXPR_ADD:
907 e->cval = expr1->cval + expr2->cval;
908 break;
909 case EXPR_SUB:
910 e->cval = expr1->cval - expr2->cval;
911 break;
912 case EXPR_MUL:
913 e->cval = expr1->cval * expr2->cval;
914 break;
915 case EXPR_DIV:
916 e->cval = expr1->cval / expr2->cval;
917 break;
918 case EXPR_OR:
919 e->cval = expr1->cval | expr2->cval;
920 break;
921 case EXPR_AND:
922 e->cval = expr1->cval & expr2->cval;
923 break;
924 case EXPR_SHL:
925 e->cval = expr1->cval << expr2->cval;
926 break;
927 case EXPR_SHR:
928 e->cval = expr1->cval >> expr2->cval;
929 break;
930 default:
931 e->is_const = FALSE;
932 break;
933 }
934 }
935 return e;
936 }
937
938 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
939 {
940 expr_t *e;
941 e = xmalloc(sizeof(expr_t));
942 e->type = type;
943 e->ref = expr1;
944 e->u.ext = expr2;
945 e->ext2 = expr3;
946 e->is_const = FALSE;
947 INIT_LINK(e);
948 /* check for compile-time optimization */
949 if (expr1->is_const && expr2->is_const && expr3->is_const) {
950 e->is_const = TRUE;
951 switch (type) {
952 case EXPR_COND:
953 e->cval = expr1->cval ? expr2->cval : expr3->cval;
954 break;
955 default:
956 e->is_const = FALSE;
957 break;
958 }
959 }
960 return e;
961 }
962
963 static type_t *make_type(unsigned char type, type_t *ref)
964 {
965 type_t *t = xmalloc(sizeof(type_t));
966 t->name = NULL;
967 t->type = type;
968 t->ref = ref;
969 t->rname = NULL;
970 t->attrs = NULL;
971 t->funcs = NULL;
972 t->fields = NULL;
973 t->ignore = parse_only;
974 t->is_const = FALSE;
975 t->sign = 0;
976 t->defined = FALSE;
977 t->written = FALSE;
978 t->typelib_idx = -1;
979 INIT_LINK(t);
980 return t;
981 }
982
983 static typeref_t *make_tref(char *name, type_t *ref)
984 {
985 typeref_t *t = xmalloc(sizeof(typeref_t));
986 t->name = name;
987 t->ref = ref;
988 t->uniq = ref ? 0 : 1;
989 return t;
990 }
991
992 static typeref_t *uniq_tref(typeref_t *ref)
993 {
994 typeref_t *t = ref;
995 type_t *tp;
996 if (t->uniq) return t;
997 tp = make_type(0, t->ref);
998 tp->name = t->name;
999 t->name = NULL;
1000 t->ref = tp;
1001 t->uniq = 1;
1002 return t;
1003 }
1004
1005 static type_t *type_ref(typeref_t *ref)
1006 {
1007 type_t *t = ref->ref;
1008 if (ref->name) free(ref->name);
1009 free(ref);
1010 return t;
1011 }
1012
1013 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1014 {
1015 v->type = ref->ref;
1016 v->tname = ref->name;
1017 ref->name = NULL;
1018 free(ref);
1019 v->array = arr;
1020 }
1021
1022 static ifref_t *make_ifref(type_t *iface)
1023 {
1024 ifref_t *l = xmalloc(sizeof(ifref_t));
1025 l->iface = iface;
1026 l->attrs = NULL;
1027 INIT_LINK(l);
1028 return l;
1029 }
1030
1031 static var_t *make_var(char *name)
1032 {
1033 var_t *v = xmalloc(sizeof(var_t));
1034 v->name = name;
1035 v->ptr_level = 0;
1036 v->type = NULL;
1037 v->tname = NULL;
1038 v->attrs = NULL;
1039 v->array = NULL;
1040 v->eval = NULL;
1041 v->lval = 0;
1042 INIT_LINK(v);
1043 return v;
1044 }
1045
1046 static func_t *make_func(var_t *def, var_t *args)
1047 {
1048 func_t *f = xmalloc(sizeof(func_t));
1049 f->def = def;
1050 f->args = args;
1051 f->ignore = parse_only;
1052 f->idx = -1;
1053 INIT_LINK(f);
1054 return f;
1055 }
1056
1057 static class_t *make_class(char *name)
1058 {
1059 class_t *c = xmalloc(sizeof(class_t));
1060 c->name = name;
1061 c->attrs = NULL;
1062 c->ifaces = NULL;
1063 INIT_LINK(c);
1064 return c;
1065 }
1066
1067 #define HASHMAX 64
1068
1069 static int hash_ident(const char *name)
1070 {
1071 const char *p = name;
1072 int sum = 0;
1073 /* a simple sum hash is probably good enough */
1074 while (*p) {
1075 sum += *p;
1076 p++;
1077 }
1078 return sum & (HASHMAX-1);
1079 }
1080
1081 /***** type repository *****/
1082
1083 struct rtype {
1084 char *name;
1085 type_t *type;
1086 int t;
1087 struct rtype *next;
1088 };
1089
1090 struct rtype *type_hash[HASHMAX];
1091
1092 static type_t *reg_type(type_t *type, char *name, int t)
1093 {
1094 struct rtype *nt;
1095 int hash;
1096 if (!name) {
1097 yyerror("registering named type without name\n");
1098 return type;
1099 }
1100 hash = hash_ident(name);
1101 nt = xmalloc(sizeof(struct rtype));
1102 nt->name = name;
1103 nt->type = type;
1104 nt->t = t;
1105 nt->next = type_hash[hash];
1106 type_hash[hash] = nt;
1107 return type;
1108 }
1109
1110 /* determine pointer type from attrs */
1111 static unsigned char get_pointer_type( type_t *type )
1112 {
1113 int t;
1114 if (is_attr( type->attrs, ATTR_STRING ))
1115 {
1116 type_t *t = type;
1117 while( t->type == 0 && t->ref )
1118 t = t->ref;
1119 switch( t->type )
1120 {
1121 case RPC_FC_CHAR:
1122 return RPC_FC_C_CSTRING;
1123 case RPC_FC_WCHAR:
1124 return RPC_FC_C_WSTRING;
1125 }
1126 }
1127 t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1128 if (t) return t;
1129 return RPC_FC_FP;
1130 }
1131
1132 static type_t *reg_types(type_t *type, var_t *names, int t)
1133 {
1134 type_t *ptr = type;
1135 int ptrc = 0;
1136
1137 while (names) {
1138 var_t *next = NEXT_LINK(names);
1139 if (names->name) {
1140 type_t *cur = ptr;
1141 int cptr = names->ptr_level;
1142 if (cptr > ptrc) {
1143 while (cptr > ptrc) {
1144 int t = get_pointer_type( cur );
1145 cur = ptr = make_type(t, cur);
1146 ptrc++;
1147 }
1148 } else {
1149 while (cptr < ptrc) {
1150 cur = cur->ref;
1151 cptr++;
1152 }
1153 }
1154 reg_type(cur, names->name, t);
1155 }
1156 free(names);
1157 names = next;
1158 }
1159 return type;
1160 }
1161
1162 static type_t *find_type(char *name, int t)
1163 {
1164 struct rtype *cur = type_hash[hash_ident(name)];
1165 while (cur && (cur->t != t || strcmp(cur->name, name)))
1166 cur = cur->next;
1167 if (!cur) {
1168 yyerror("type %s not found\n", name);
1169 return NULL;
1170 }
1171 return cur->type;
1172 }
1173
1174 static type_t *find_type2(char *name, int t)
1175 {
1176 type_t *tp = find_type(name, t);
1177 free(name);
1178 return tp;
1179 }
1180
1181 int is_type(const char *name)
1182 {
1183 struct rtype *cur = type_hash[hash_ident(name)];
1184 while (cur && (cur->t || strcmp(cur->name, name)))
1185 cur = cur->next;
1186 if (cur) return TRUE;
1187 return FALSE;
1188 }
1189
1190 static type_t *get_type(unsigned char type, char *name, int t)
1191 {
1192 struct rtype *cur = NULL;
1193 type_t *tp;
1194 if (name) {
1195 cur = type_hash[hash_ident(name)];
1196 while (cur && (cur->t != t || strcmp(cur->name, name)))
1197 cur = cur->next;
1198 }
1199 if (cur) {
1200 free(name);
1201 return cur->type;
1202 }
1203 tp = make_type(type, NULL);
1204 tp->name = name;
1205 if (!name) return tp;
1206 return reg_type(tp, name, t);
1207 }
1208
1209 static type_t *get_typev(unsigned char type, var_t *name, int t)
1210 {
1211 char *sname = NULL;
1212 if (name) {
1213 sname = name->name;
1214 free(name);
1215 }
1216 return get_type(type, sname, t);
1217 }
1218
1219 static int get_struct_type(var_t *field)
1220 {
1221 int has_pointer = 0;
1222 int has_conformant_array = 0;
1223 int has_conformant_string = 0;
1224
1225 while (field)
1226 {
1227 type_t *t = field->type;
1228
1229 /* get the base type */
1230 while( (t->type == 0) && t->ref )
1231 t = t->ref;
1232
1233 switch (t->type)
1234 {
1235 /*
1236 * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1237 * Simple types don't effect the type of struct.
1238 * A struct containing a simple struct is still a simple struct.
1239 * So long as we can block copy the data, we return RPC_FC_STRUCT.
1240 */
1241 case 0: /* void pointer */
1242 case RPC_FC_BYTE:
1243 case RPC_FC_CHAR:
1244 case RPC_FC_SMALL:
1245 case RPC_FC_USMALL:
1246 case RPC_FC_WCHAR:
1247 case RPC_FC_SHORT:
1248 case RPC_FC_USHORT:
1249 case RPC_FC_LONG:
1250 case RPC_FC_ULONG:
1251 case RPC_FC_INT3264:
1252 case RPC_FC_UINT3264:
1253 case RPC_FC_HYPER:
1254 case RPC_FC_FLOAT:
1255 case RPC_FC_DOUBLE:
1256 case RPC_FC_STRUCT:
1257 case RPC_FC_ENUM16:
1258 case RPC_FC_ENUM32:
1259 break;
1260
1261 case RPC_FC_UP:
1262 case RPC_FC_FP:
1263 has_pointer = 1;
1264 break;
1265 case RPC_FC_CARRAY:
1266 has_conformant_array = 1;
1267 break;
1268 case RPC_FC_C_CSTRING:
1269 case RPC_FC_C_WSTRING:
1270 has_conformant_string = 1;
1271 break;
1272
1273 /*
1274 * Propagate member attributes
1275 * a struct should be at least as complex as its member
1276 */
1277 case RPC_FC_CVSTRUCT:
1278 has_conformant_string = 1;
1279 has_pointer = 1;
1280 break;
1281
1282 case RPC_FC_CPSTRUCT:
1283 has_conformant_array = 1;
1284 has_pointer = 1;
1285 break;
1286
1287 case RPC_FC_CSTRUCT:
1288 has_conformant_array = 1;
1289 break;
1290
1291 case RPC_FC_PSTRUCT:
1292 has_pointer = 1;
1293 break;
1294
1295 default:
1296 fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1297 field->name, t->type);
1298 /* fallthru - treat it as complex */
1299
1300 /* as soon as we see one of these these members, it's bogus... */
1301 case RPC_FC_IP:
1302 case RPC_FC_ENCAPSULATED_UNION:
1303 case RPC_FC_NON_ENCAPSULATED_UNION:
1304 case RPC_FC_TRANSMIT_AS:
1305 case RPC_FC_REPRESENT_AS:
1306 case RPC_FC_PAD:
1307 case RPC_FC_EMBEDDED_COMPLEX:
1308 case RPC_FC_BOGUS_STRUCT:
1309 return RPC_FC_BOGUS_STRUCT;
1310 }
1311 field = NEXT_LINK(field);
1312 }
1313
1314 if( has_conformant_string && has_pointer )
1315 return RPC_FC_CVSTRUCT;
1316 if( has_conformant_array && has_pointer )
1317 return RPC_FC_CPSTRUCT;
1318 if( has_conformant_array )
1319 return RPC_FC_CSTRUCT;
1320 if( has_pointer )
1321 return RPC_FC_PSTRUCT;
1322 return RPC_FC_STRUCT;
1323 }
1324
1325 /***** constant repository *****/
1326
1327 struct rconst {
1328 char *name;
1329 var_t *var;
1330 struct rconst *next;
1331 };
1332
1333 struct rconst *const_hash[HASHMAX];
1334
1335 static var_t *reg_const(var_t *var)
1336 {
1337 struct rconst *nc;
1338 int hash;
1339 if (!var->name) {
1340 yyerror("registering constant without name\n");
1341 return var;
1342 }
1343 hash = hash_ident(var->name);
1344 nc = xmalloc(sizeof(struct rconst));
1345 nc->name = var->name;
1346 nc->var = var;
1347 nc->next = const_hash[hash];
1348 const_hash[hash] = nc;
1349 return var;
1350 }
1351
1352 static var_t *find_const(char *name, int f)
1353 {
1354 struct rconst *cur = const_hash[hash_ident(name)];
1355 while (cur && strcmp(cur->name, name))
1356 cur = cur->next;
1357 if (!cur) {
1358 if (f) yyerror("constant %s not found\n", name);
1359 return NULL;
1360 }
1361 return cur->var;
1362 }
A free Windows-compatible Operating System